configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.13)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  23 AC_ARG_WITH(gettext, dnl
  24   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  25             [dnl
  26 case "$with_gettext" in
  27 yes)
  28   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  29 ''|no) ;;
  30 *)
  31   config_vars="$config_vars
  32 gettext-srcdir = $withval" ;;
  33 esac
  34 ])
  35
  36 dnl Arguments to specify presence of other packages/features.
  37 AC_ARG_WITH(fp, dnl
  38 [  --with-fp              if using floating-point hardware [default=yes]],
  39             with_fp=$withval, with_fp=yes)
  40 AC_ARG_WITH(binutils, dnl
  41   --with-binutils=PATH    specify location of binutils (as and ld),
  42             path_binutils=$withval, path_binutils='')
  43 AC_ARG_WITH(elf, dnl
  44   --with-elf              if using the ELF object format,
  45             elf=$withval, elf=no)
  46 AC_ARG_WITH(cvs, dnl
  47 [  --without-cvs          if CVS should not be used],
  48             with_cvs=$withval, with_cvs=yes)
  49 AC_SUBST(with_cvs)
  50
  51 AC_ARG_WITH(headers, dnl
  52 [  --with-headers=PATH     location of system headers to use
  53                           [e.g. /usr/src/linux/include]
  54                           [default=compiler default]],
  55             sysheaders=$withval, sysheaders='')
  56
  57 AC_ARG_ENABLE(libio, dnl
  58 [  --enable-libio          build in GNU libio instead of GNU stdio],
  59               [if test $enableval = yes; then
  60                  stdio=libio
  61                else
  62                  stdio=stdio
  63                fi],
  64               stdio=default)
  65
  66 AC_ARG_ENABLE(sanity-checks, dnl
  67 [  --disable-sanity-checks really do not use threads (should not be used
  68                           except in special situations) [default=yes]],
  69               enable_sanity=$enableval, enable_sanity=yes)
  70
  71 dnl Arguments to enable or disable building the static, shared, profiled,
  72 dnl and -fomit-frame-pointer libraries.
  73 dnl I've disabled this for now since we cannot build glibc without static
  74 dnl libraries built in the moment.
  75 dnl AC_ARG_ENABLE(static, dnl
  76 dnl [  --enable-static         build static library [default=yes]],
  77 dnl           static=$enableval, static=yes)
  78 static=yes
  79 AC_ARG_ENABLE(shared, dnl
  80 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  81               shared=$enableval, shared=default)
  82 AC_ARG_ENABLE(profile, dnl
  83 [  --enable-profile        build profiled library [default=yes]],
  84               profile=$enableval, profile=yes)
  85 AC_ARG_ENABLE(omitfp, dnl
  86 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  87               omitfp=$enableval, omitfp=no)
  88 AC_ARG_ENABLE(bounded, dnl
  89 [  --enable-bounded        build with runtime bounds checking [default=no]],
  90               bounded=$enableval, bounded=no)
  91 AC_ARG_ENABLE(versioning, dnl
  92 [  --disable-versioning    do not include versioning information in the
  93                           library objects [default=yes if supported]],
  94              enable_versioning=$enableval, enable_versioning=yes)
  95
  96 dnl Generic infrastructure for drop-in additions to libc.
  97 AC_ARG_ENABLE(add-ons, dnl
  98 [  --enable-add-ons[=DIR1,DIR2]...
  99                           configure and build add-ons in DIR1,DIR2,...
 100                           search for add-ons if no parameter given],
 101   [case "$enableval" in
 102     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 103          test "$add_ons" = "*" && add_ons= ;;
 104     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 105    esac],
 106   [add_ons=])
 107
 108 AC_CONFIG_SUBDIRS($add_ons)
 109 add_ons_pfx=
 110 if test x"$add_ons" != x; then
 111   for f in $add_ons; do
 112     # Test whether such a subdir really exists.
 113     if test -d $srcdir/$f; then
 114       add_ons_pfx="$add_ons_pfx $f/"
 115     else
 116       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 117     fi
 118   done
 119 fi
 120
 121 dnl On some platforms we cannot use dynamic loading.  We must provide
 122 dnl static NSS modules.
 123 AC_ARG_ENABLE(static-nss, dnl
 124 [  --enable-static-nss     build static NSS modules [default=no]],
 125               static_nss=$enableval, static_nss=no)
 126 if test x"$static_nss" = xyes; then
 127   AC_DEFINE(DO_STATIC_NSS)
 128 fi
 129
 130 AC_ARG_ENABLE(force-install,
 131 [  --disable-force-install don't force installation of files from this package,
 132                           even if they are older than the installed files],
 133               force_install=$enableval, force_install=yes)
 134 AC_SUBST(force_install)
 135
 136 AC_CANONICAL_HOST
 137
 138 # The way shlib-versions is used to generate soversions.mk uses a
 139 # fairly simplistic model for name recognition that can't distinguish
 140 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 141 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 142 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 143 case "$host_os" in
 144 linux*)
 145   ;;
 146 gnu*)
 147   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 148   ;;
 149 esac
 150
 151 # We keep the original values in `$config_*' and never modify them, so we
 152 # can write them unchanged into config.make.  Everything else uses
 153 # $machine, $vendor, and $os, and changes them whenever convenient.
 154 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 155
 156 # Some configurations imply other options.
 157 case "$host_os" in
 158 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 159   # These systems always use GNU tools.
 160   gnu_ld=yes gnu_as=yes ;;
 161 esac
 162 case "$host_os" in
 163 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 164 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 165   ;;
 166 gnu* | linux* | sysv4* | solaris2* | irix6*)
 167   # These systems (almost) always use the ELF format.
 168   elf=yes
 169   ;;
 170 esac
 171
 172 machine=$config_machine
 173 vendor=$config_vendor
 174 os=$config_os
 175
 176 ###
 177 ### I put this here to prevent those annoying emails from people who cannot
 178 ### read and try to compile glibc on unsupported platforms.  --drepper
 179 ###
 180 ### By using the undocumented --enable-hacker-mode option for configure
 181 ### one can skip this test to make the configuration not fail for unsupported
 182 ### platforms.
 183 ###
 184 if test -z "$enable_hacker_mode"; then
 185   case "$machine-$host_os" in
 186   *-linux* | *-gnu* | arm*-none*)
 187     ;;
 188   *)
 189     echo "*** The GNU C library is currently not available for this platform."
 190     echo "*** So far nobody cared to port it and if there is no volunteer it"
 191     echo "*** might never happen.  So, if you have interest to see glibc on"
 192     echo "*** this platform visit"
 193     echo "***   http://www.gnu.org/software/libc/porting.html"
 194     echo "*** and join the group of porters"
 195     exit 1
 196     ;;
 197   esac
 198 fi
 199
 200 dnl We need to use [ and ] for other purposes for a while now.
 201 changequote(,)dnl
 202 # Expand the configuration machine name into a subdirectory by architecture
 203 # type and particular chip.
 204 case "$machine" in
 205 a29k | am29000) base_machine=a29k machine=a29k ;;
 206 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 207 arm*)           base_machine=arm machine=arm/$machine ;;
 208 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 209 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 210 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 211 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 212 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 213 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 214 m88???)         base_machine=m88k machine=m88k/$machine ;;
 215 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 216 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 217 mips*)          base_machine=mips
 218                 case "`uname -m`" in
 219                 IP22) machine=mips/mips3 ;;
 220                 *)    machine=mips/$machine ;;
 221                 esac ;;
 222 sparc | sparcv[67])
 223                 base_machine=sparc machine=sparc/sparc32 ;;
 224 sparcv8 | supersparc | hypersparc)
 225                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 226 sparcv8plus | sparcv8plusa | sparcv9)
 227                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 228 sparc64 | ultrasparc)
 229                 base_machine=sparc machine=sparc/sparc64 ;;
 230 esac
 231 changequote([,])dnl
 232 AC_SUBST(base_machine)
 233
 234 if test "$base_machine" = "i386"; then
 235   AC_DEFINE(USE_REGPARMS)
 236 fi
 237
 238 # Compute the list of sysdep directories for this configuration.
 239 # This can take a while to compute.
 240 sysdep_dir=$srcdir/sysdeps
 241 AC_MSG_CHECKING(sysdep dirs)
 242 dnl We need to use [ and ] for other purposes for a while now.
 243 changequote(,)dnl
 244 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 245 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 246
 247 case "$os" in
 248 gnu*)
 249   base_os=mach/hurd ;;
 250 netbsd* | 386bsd* | freebsd* | bsdi*)
 251   base_os=unix/bsd/bsd4.4 ;;
 252 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 253   base_os=unix/bsd ;;
 254 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 255   base_os=unix/sysv ;;
 256 irix6*)
 257   base_os=unix/sysv/irix6/$os ;;
 258 solaris[2-9]*)
 259   base_os=unix/sysv/sysv4 ;;
 260 none)
 261   base_os=standalone ;;
 262 *)
 263   base_os='' ;;
 264 esac
 265
 266 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 267 tail=$os
 268 ostry=$os
 269 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 270   ostry="$ostry /$o"
 271   tail=$o
 272 done
 273 o=`echo $tail | sed 's/[0-9]*$//'`
 274 if test $o != $tail; then
 275   ostry="$ostry /$o"
 276 fi
 277 # For linux-gnu, try linux-gnu, then linux.
 278 o=`echo $tail | sed 's/-.*$//'`
 279 if test $o != $tail; then
 280   ostry="$ostry /$o"
 281 fi
 282
 283 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 284 base=
 285 tail=$base_os
 286 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 287   set $b
 288   base="$base /$1"
 289   tail="$2"
 290 done
 291
 292 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 293 mach=
 294 tail=$machine
 295 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 296   set $m
 297   # Prepend the machine's FPU directory unless --without-fp.
 298   if test "$with_fp" = yes; then
 299     mach="$mach /$1/fpu"
 300   fi
 301   mach="$mach /$1"
 302   tail="$2"
 303 done
 304
 305 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 306 changequote([,])dnl
 307
 308 # Find what sysdep directories exist.
 309 sysnames=
 310 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 311 for d in $add_ons_pfx ''; do
 312   for b in $base ''; do
 313     for m0 in $mach ''; do
 314       for v in /$vendor ''; do
 315         test "$v" = / && continue
 316         for o in /$ostry ''; do
 317           test "$o" = / && continue
 318           for m in $mach ''; do
 319             if test "$m0$b$v$o$m"; then
 320               try="${d}sysdeps$m0$b$v$o$m"
 321               test -n "$enable_debug_configure" &&
 322               echo "$0 [DEBUG]: try $try" >&2
 323               if test -d $srcdir/$try; then
 324                 sysnames="$sysnames $try"
 325                 { test -n "$o" || test -n "$b"; } && os_used=t
 326                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 327               fi
 328             fi
 329           done
 330         done
 331       done
 332     done
 333   done
 334 done
 335 IFS="$ac_save_ifs"
 336
 337 if test -z "$os_used" && test "$os" != none; then
 338   AC_MSG_ERROR(Operating system $os is not supported.)
 339 fi
 340 if test -z "$machine_used" && test "$machine" != none; then
 341   AC_MSG_ERROR(The $machine is not supported.)
 342 fi
 343
 344 # We have now validated the configuration.
 345
 346
 347 # If using ELF, look for an `elf' subdirectory of each machine directory.
 348 # We prepend these rather than inserting them whereever the machine appears
 349 # because things specified by the machine's ELF ABI should override
 350 # OS-specific things, and should always be the same for any OS on the
 351 # machine (otherwise what's the point of an ABI?).
 352 if test "$elf" = yes; then
 353   elf_dirs=
 354   for d in $add_ons_pfx ''; do
 355     for m in $mach; do
 356       if test -d $srcdir/${d}sysdeps$m/elf; then
 357         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 358       fi
 359     done
 360   done
 361   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 362 fi
 363
 364
 365 # Expand the list of system names into a full list of directories
 366 # from each element's parent name and Implies file (if present).
 367 set $sysnames
 368 names=
 369 while test $# -gt 0; do
 370   name=$1
 371   shift
 372
 373   case " $names " in *" $name "*)
 374     # Already in the list.
 375     continue
 376   esac
 377
 378   # Report each name as we discover it, so there is no long pause in output.
 379   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 380
 381   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 382
 383   case $name in
 384     /*) xsrcdir= ;;
 385     *)  xsrcdir=$srcdir/ ;;
 386   esac
 387   test -n "$enable_debug_configure" &&
 388   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 389
 390   if test -f $xsrcdir$name/Implies; then
 391     # Collect more names from the `Implies' file (removing comments).
 392     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 393     implied=
 394     for x in $implied_candidate; do
 395       if test -d $xsrcdir$name_base/$x; then
 396         implied="$implied $name_base/$x";
 397       else
 398         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 399       fi
 400     done
 401   else
 402     implied=
 403   fi
 404
 405   # Add NAME to the list of names.
 406   names="$names $name"
 407
 408   # Find the parent of NAME, using the empty string if it has none.
 409 changequote(,)dnl
 410   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 411 changequote([,])dnl
 412
 413   # Add the names implied by NAME, and NAME's parent (if it has one), to
 414   # the list of names to be processed (the argument list).  We prepend the
 415   # implied names to the list and append the parent.  We want implied
 416   # directories to come before further directories inferred from the
 417   # configuration components; this ensures that for sysv4, unix/common
 418   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 419   # after sysv4).
 420   sysnames="`echo $implied $* $parent`"
 421   test -n "$sysnames" && set $sysnames
 422 done
 423
 424 # Add the default directories.
 425 default_sysnames=sysdeps/generic
 426 if test "$elf" = yes; then
 427   default_sysnames="sysdeps/generic/elf $default_sysnames"
 428 fi
 429 sysnames="$names $default_sysnames"
 430 AC_SUBST(sysnames)
 431 # The other names were emitted during the scan.
 432 AC_MSG_RESULT($default_sysnames)
 433
 434
 435 ### Locate tools.
 436
 437 AC_PROG_INSTALL
 438 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 439   # The makefiles need to use a different form to find it in $srcdir.
 440   INSTALL='\$(..)./install-sh -c'
 441 fi
 442 AC_PROG_LN_S
 443
 444 # These programs are version sensitive.
 445 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 446 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 447   [version \([egcygnustp-]*[0-9.]*\)],
 448   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|pgcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|cygnus-2.9[1-9].*],
 449   critic_missing=t)
 450 AC_CHECK_PROG_VER(MAKE, make gmake, --version,
 451   [version \([0-9][0-9.]*\), by],
 452   [3.75 | 3.76.[1-9]* | 3.7[789]* | 3.[89]*], critic_missing=t)
 453
 454 AC_CHECK_PROG_VER(MSGFMT, msgfmt gmsgfmt, --version,
 455   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 456   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 457 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 458   [GNU texinfo.* \([0-9][0-9.]*\)],
 459   [3.1[1-9] | 3.[2-9][0-9] | 1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t)
 460
 461 if test -n "$critic_missing"; then
 462 AC_MSG_ERROR([
 463 *** Some critical program is missing or too old.
 464 *** Check the INSTALL file for required versions.])
 465 fi
 466
 467 test -n "$aux_missing" && AC_MSG_WARN([
 468 *** An auxiliary program is missing or too old;
 469 *** some features will be disabled.
 470 *** Check the INSTALL file for required versions.])
 471
 472 AC_PROG_CC_LOCAL
 473 AC_CANONICAL_BUILD
 474 if test $host != $build; then
 475   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 476 fi
 477 AC_SUBST(cross_compiling)
 478 AC_PROG_CPP
 479 LIBC_PROG_BINUTILS
 480 AC_CHECK_TOOL(MIG, mig)
 481
 482 # if using special system headers, find out the compiler's sekrit
 483 # header directory and add that to the list.  NOTE: Only does the right
 484 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 485 if test -n "$sysheaders"; then
 486   ccheaders=`$CC -print-file-name=include`
 487   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 488 fi
 489 AC_SUBST(SYSINCLUDES)
 490
 491 # check if ranlib is necessary
 492 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 493 cat > conftest.c <<EOF
 494 int a;
 495 char b;
 496 void c(void) {}
 497 EOF
 498 $CC $CFLAGS -c conftest.c
 499 $AR cr conftest.a conftest.c
 500 cp conftest.a conftest2.a
 501 $RANLIB conftest.a
 502 if cmp -s conftest.a conftest2.a; then
 503   libc_cv_ranlib_necessary=no
 504 else
 505   libc_cv_ranlib_necessary=yes
 506 fi
 507 rm -rf conftest*])
 508 if test "$libc_cv_ranlib_necessary" = no; then
 509  RANLIB=:
 510 fi
 511
 512 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 513 # since this would lead to problems installing/building glibc.
 514 # LD_LIBRARY_PATH contains the current directory if one of the following
 515 # is true:
 516 # - one of the terminals (":" and ";") is the first or last sign
 517 # - two terminals occur directly after each other
 518 # - the path contains an element with a dot in it
 519 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 520 changequote(,)dnl
 521 case ${LD_LIBRARY_PATH} in
 522   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 523     ld_library_path_setting="contains current directory"
 524     ;;
 525   *)
 526     ld_library_path_setting="ok"
 527     ;;
 528 esac
 529 changequote([,])dnl
 530 AC_MSG_RESULT($ld_library_path_setting)
 531 if test "$ld_library_path_setting" != "ok"; then
 532 AC_MSG_ERROR([
 533 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 534 *** building glibc. Please change the environment variable
 535 *** and run configure again.])
 536 fi
 537
 538 AC_PATH_PROG(BASH, bash, no)
 539 if test "$BASH" != no &&
 540    $BASH -c 'test "$BASH_VERSINFO" \
 541              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 542   libc_cv_have_bash2=yes
 543 else
 544   libc_cv_have_bash2=no
 545 fi
 546 AC_SUBST(libc_cv_have_bash2)
 547
 548 dnl We need a ksh compatible shell for tzselect.
 549 if test "$BASH" = no; then
 550   AC_PATH_PROG(KSH, ksh, no)
 551   if test "$KSH" = no; then
 552     libc_cv_have_ksh=no
 553   else
 554     libc_cv_have_ksh=yes
 555   fi
 556 else
 557   KSH="$BASH"
 558   AC_SUBST(KSH)
 559   libc_cv_have_ksh=yes
 560 fi
 561 AC_SUBST(libc_cv_have_ksh)
 562
 563 AC_PROG_AWK
 564 AC_PATH_PROG(PERL, perl, no)
 565 AC_SUBST(PERL)
 566 AC_PATH_PROG(INSTALL_INFO, install-info, no,
 567              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
 568 AC_SUBST(INSTALL_INFO)
 569 if test "$INSTALL_INFO" != "no"; then
 570 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 571  [mkdir conftest.d
 572   # There is a hard ^_ on the next line.  I am open to better ideas.
 573   (echo '\x1f'
 574   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 575   echo '* Menu:') >conftest.d/dir
 576   (echo 'INFO-DIR-SECTION i-d-s works'
 577   echo 'START-INFO-DIR-ENTRY'
 578   echo '* Prog: (prog).   Program.'
 579   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 580   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 581   then
 582     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 583     then libc_cv_old_debian_install_info=no
 584     else libc_cv_old_debian_install_info=yes
 585     fi
 586   else libc_cv_old_debian_install_info=no testfailed=t
 587   fi
 588   rm -fr conftest.d])
 589 if test -n "$testfailed"
 590 then AC_MSG_WARN([install-info errored out, check config.log])
 591 fi
 592 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 593 fi
 594 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 595
 596 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 597 echo '#include <stddef.h>
 598 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 599 if eval "$ac_cpp conftest.c 2>/dev/null" \
 600 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 601   libc_cv_signed_size_t=no
 602 else
 603   libc_cv_signed_size_t=yes
 604 fi
 605 rm -f conftest*])
 606 if test $libc_cv_signed_size_t = yes; then
 607   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 608   cat >> confdefs.h <<\EOF
 609 #undef __SIZE_TYPE__
 610 #define __SIZE_TYPE__ unsigned
 611 EOF
 612 fi
 613
 614 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 615 AC_TRY_COMPILE(dnl
 616 [#define __need_size_t
 617 #define __need_wchar_t
 618 #include <stddef.h>
 619 #define __need_NULL
 620 #include <stddef.h>], [size_t size; wchar_t wchar;
 621 #ifdef offsetof
 622 #error stddef.h ignored __need_*
 623 #endif
 624 if (&size == NULL || &wchar == NULL) abort ();],
 625                libc_cv_friendly_stddef=yes,
 626                libc_cv_friendly_stddef=no)])
 627 if test $libc_cv_friendly_stddef = yes; then
 628   config_vars="$config_vars
 629 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 630 fi
 631
 632 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 633                libc_cv_need_minus_P, [dnl
 634 cat > conftest.S <<EOF
 635 #include "confdefs.h"
 636 /* Nothing whatsoever.  */
 637 EOF
 638 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 639   libc_cv_need_minus_P=no
 640 else
 641   libc_cv_need_minus_P=yes
 642 fi
 643 rm -f conftest*])
 644 if test $libc_cv_need_minus_P = yes; then
 645   config_vars="$config_vars
 646 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 647 fi
 648
 649 AC_CACHE_CHECK(for assembler global-symbol directive,
 650                libc_cv_asm_global_directive, [dnl
 651 libc_cv_asm_global_directive=UNKNOWN
 652 for ac_globl in .globl .global; do
 653   cat > conftest.s <<EOF
 654 .text
 655 ${ac_globl} foo
 656 foo:
 657 EOF
 658   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 659     libc_cv_asm_global_directive=${ac_globl}
 660   fi
 661   rm -f conftest*
 662   test $libc_cv_asm_global_directive != UNKNOWN && break
 663 done])
 664 if test $libc_cv_asm_global_directive = UNKNOWN; then
 665   AC_MSG_ERROR(cannot determine asm global directive)
 666 else
 667   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 668 fi
 669
 670 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 671 cat > conftest.s <<EOF
 672 .text
 673 foo:
 674 .set glibc_conftest_frobozz,foo
 675 $libc_cv_asm_global_directive glibc_conftest_frobozz
 676 EOF
 677 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 678 # (but it doesn't work), so we must do a linking check to be sure.
 679 cat > conftest1.c <<\EOF
 680 extern int glibc_conftest_frobozz;
 681 main () { printf ("%d\n", glibc_conftest_frobozz); }
 682 EOF
 683 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 684             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 685   libc_cv_asm_set_directive=yes
 686 else
 687   libc_cv_asm_set_directive=no
 688 fi
 689 rm -f conftest*])
 690 if test $libc_cv_asm_set_directive = yes; then
 691   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 692 fi
 693
 694 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 695 [cat > conftest.s <<EOF
 696 .text
 697 _sym:
 698 .symver _sym,sym@VERS
 699 EOF
 700 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 701   libc_cv_asm_symver_directive=yes
 702 else
 703   libc_cv_asm_symver_directive=no
 704 fi
 705 rm -f conftest*])
 706 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 707 if test $libc_cv_asm_symver_directive = yes; then
 708   cat > conftest.s <<EOF
 709 .text
 710 _sym:
 711 .symver _sym,sym@VERS
 712 EOF
 713   cat > conftest.map <<EOF
 714 VERS_1 {
 715         global: sym;
 716 };
 717
 718 VERS_2 {
 719         global: sym;
 720 } VERS_1;
 721 EOF
 722   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 723     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 724                                         -nostartfiles -nostdlib
 725                                         -Wl,--version-script,conftest.map
 726                        1>&AC_FD_CC]);
 727     then
 728       libc_cv_ld_version_script_option=yes
 729     else
 730       libc_cv_ld_version_script_option=no
 731     fi
 732   else
 733     libc_cv_ld_version_script_option=no
 734   fi
 735 else
 736   libc_cv_ld_version_script_option=no
 737 fi
 738 rm -f conftest*])
 739 if test $libc_cv_asm_symver_directive = yes &&
 740    test $libc_cv_ld_version_script_option = yes &&
 741    test $enable_versioning = yes; then
 742   VERSIONING=yes
 743   AC_DEFINE(DO_VERSIONING)
 744 else
 745   VERSIONING=no
 746 fi
 747 AC_SUBST(VERSIONING)
 748
 749 if test $VERSIONING = no; then
 750   echo "\
 751 *** WARNING: You should not compile GNU libc without versioning. Not using
 752 *** versioning will introduce incompatibilities so that old binaries
 753 *** will not run anymore.
 754 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 755 fi
 756 if test $elf = yes; then
 757   AC_CACHE_CHECK(for .previous assembler directive,
 758                  libc_cv_asm_previous_directive, [dnl
 759   cat > conftest.s <<EOF
 760 .section foo_section
 761 .previous
 762 EOF
 763   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 764     libc_cv_asm_previous_directive=yes
 765   else
 766     libc_cv_asm_previous_directive=no
 767   fi
 768   rm -f conftest*])
 769   if test $libc_cv_asm_previous_directive = yes; then
 770     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 771   else
 772     AC_CACHE_CHECK(for .popsection assembler directive,
 773                    libc_cv_asm_popsection_directive, [dnl
 774     cat > conftest.s <<EOF
 775 .pushsection foo_section
 776 .popsection
 777 EOF
 778     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 779       libc_cv_asm_popsection_directive=yes
 780     else
 781       libc_cv_asm_popsection_directive=no
 782     fi
 783     rm -f conftest*])
 784     if test $libc_cv_asm_popsection_directive = yes; then
 785       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 786     fi
 787   fi
 788 fi
 789
 790 if test $elf != yes; then
 791   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 792                  [AC_TRY_COMPILE(, [asm (".section .init");
 793                                     asm (".section .fini");
 794                                     asm (".text");],
 795                                  libc_cv_have_initfini=yes,
 796                                  libc_cv_have_initfini=no)])
 797   AC_SUBST(libc_cv_have_initfini)dnl
 798   if test $libc_cv_have_initfini = yes; then
 799     AC_DEFINE(HAVE_INITFINI)
 800   fi
 801 fi
 802
 803 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 804 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 805 [cat > conftest.$ac_ext <<EOF
 806 dnl This sometimes fails to find confdefs.h, for some reason.
 807 dnl [#]line __oline__ "[$]0"
 808 [#]line __oline__ "configure"
 809 #include "confdefs.h"
 810 void underscore_test(void) {
 811 return; }
 812 EOF
 813 if AC_TRY_EVAL(ac_compile); then
 814   if grep _underscore_test conftest* >/dev/null; then
 815     ifelse([$1], , :, [rm -f conftest*
 816     $1])
 817   else
 818     ifelse([$2], , , [rm -f conftest*
 819     $2])
 820   fi
 821 else
 822   echo "configure: failed program was:" >&AC_FD_CC
 823   cat conftest.$ac_ext >&AC_FD_CC
 824   ifelse([$2], , , [rm -f conftest*
 825   $2])
 826 fi
 827 rm -f conftest*])
 828
 829 if test $elf = yes; then
 830   libc_cv_asm_underscores=no
 831 else
 832   if test $ac_cv_prog_cc_works = yes; then
 833     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 834                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 835                                 libc_cv_asm_underscores=yes,
 836                                 libc_cv_asm_underscores=no)])
 837   else
 838     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 839                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 840                                             libc_cv_asm_underscores=no)])
 841   fi
 842 fi
 843 if test $libc_cv_asm_underscores = no; then
 844   AC_DEFINE(NO_UNDERSCORES)
 845 fi
 846
 847 if test $elf = yes; then
 848   libc_cv_weak_symbols=yes
 849 fi
 850
 851 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 852                  [dnl
 853 cat > conftest.s <<EOF
 854 .text
 855 ${libc_cv_asm_global_directive} foo
 856 foo:
 857 .weak foo
 858 .weak bar; bar = foo
 859 EOF
 860 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 861   libc_cv_asm_weak_directive=yes
 862 else
 863   libc_cv_asm_weak_directive=no
 864 fi
 865 rm -f conftest*])
 866
 867 if test $libc_cv_asm_weak_directive = no; then
 868   AC_CACHE_CHECK(for assembler .weakext directive,
 869                  libc_cv_asm_weakext_directive,
 870                  [dnl
 871 cat > conftest.s <<EOF
 872 .text
 873 ${libc_cv_asm_global_directive} foo
 874 foo:
 875 .weakext bar foo
 876 .weakext baz
 877 ${libc_cv_asm_global_directive} baz
 878 baz:
 879 EOF
 880   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 881     libc_cv_asm_weakext_directive=yes
 882   else
 883     libc_cv_asm_weakext_directive=no
 884   fi
 885   rm -f conftest*])
 886
 887 fi # no .weak
 888
 889 if test $libc_cv_asm_weak_directive = yes; then
 890   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 891 elif test $libc_cv_asm_weakext_directive = yes; then
 892   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 893 fi
 894
 895 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 896 cat > conftest.c <<\EOF
 897 _start () {}
 898 int __eh_pc;
 899 __throw () {}
 900 EOF
 901 dnl No \ in command here because it ends up inside ''.
 902 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 903                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 904                             -o conftest conftest.c 1>&AC_FD_CC]); then
 905   libc_cv_ld_no_whole_archive=yes
 906 else
 907   libc_cv_ld_no_whole_archive=no
 908 fi
 909 rm -f conftest*])
 910 if test $libc_cv_ld_no_whole_archive = yes; then
 911   no_whole_archive=-Wl,--no-whole-archive
 912 fi
 913 AC_SUBST(no_whole_archive)dnl
 914
 915 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
 916 cat > conftest.c <<\EOF
 917 _start () {}
 918 int __eh_pc;
 919 __throw () {}
 920 EOF
 921 dnl No \ in command here because it ends up inside ''.
 922 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 923                             -nostdlib -nostartfiles -fexceptions
 924                             -o conftest conftest.c 1>&AC_FD_CC]); then
 925   libc_cv_gcc_exceptions=yes
 926 else
 927   libc_cv_gcc_exceptions=no
 928 fi
 929 rm -f conftest*])
 930 if test $libc_cv_gcc_exceptions = yes; then
 931   exceptions=-fexceptions
 932 fi
 933 AC_SUBST(exceptions)dnl
 934
 935 if test "$base_machine" = alpha ; then
 936 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
 937 cat > conftest.c <<\EOF
 938 foo () { }
 939 EOF
 940 dnl
 941 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
 942 then
 943   libc_cv_gcc_alpha_ng_prefix=yes
 944 else
 945   libc_cv_gcc_alpha_ng_prefix=no
 946 fi
 947 rm -f conftest* ])
 948 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
 949   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
 950 else
 951   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
 952 fi
 953 fi
 954
 955 if test "$host_cpu" = powerpc ; then
 956 # Check for a bug present in at least versions 2.8.x of GCC
 957 # and versions 1.0.x of EGCS.
 958 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
 959 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
 960                libc_cv_c_asmcr0_bug='no',
 961                libc_cv_c_asmcr0_bug='yes')])
 962 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
 963   AC_DEFINE(BROKEN_PPC_ASM_CR0)
 964 fi
 965 fi
 966
 967 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
 968 [cat > conftest.c <<EOF
 969 #line __oline__ "configure"
 970 static char __EH_FRAME_BEGIN__[];
 971 _start ()
 972 {
 973 #ifdef CHECK__register_frame
 974   __register_frame (__EH_FRAME_BEGIN__);
 975   __deregister_frame (__EH_FRAME_BEGIN__);
 976 #endif
 977 #ifdef CHECK__register_frame_info
 978   __register_frame_info (__EH_FRAME_BEGIN__);
 979   __deregister_frame_info (__EH_FRAME_BEGIN__);
 980 #endif
 981 }
 982 int __eh_pc;
 983 __throw () {}
 984 /* FIXME: this is fragile.  */
 985 malloc () {}
 986 strcmp () {}
 987 strlen () {}
 988 memcpy () {}
 989 memset () {}
 990 free () {}
 991 abort () {}
 992 __bzero () {}
 993 EOF
 994 dnl No \ in command here because it ends up inside ''.
 995 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
 996                             -nostdlib -nostartfiles
 997                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
 998   libc_cv_gcc_dwarf2_unwind_info=static
 999 else
1000   libc_cv_gcc_dwarf2_unwind_info=no
1001 fi
1002 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1003   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1004                               -nostdlib -nostartfiles
1005                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1006     libc_cv_gcc_dwarf2_unwind_info=yes
1007   else
1008     libc_cv_gcc_dwarf2_unwind_info=no
1009   fi
1010 fi
1011 rm -f conftest*])
1012 case $libc_cv_gcc_dwarf2_unwind_info in
1013 yes)
1014   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1015   ;;
1016 static)
1017   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1018   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1019   ;;
1020 esac
1021
1022 dnl Check whether compiler understands __builtin_expect.
1023 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1024 [cat > conftest.c <<EOF
1025 #line __oline__ "configure"
1026 int foo (int a)
1027 {
1028   a = __builtin_expect (a, 10);
1029   return a == 10 ? 0 : 1;
1030 }
1031 EOF
1032 dnl No \ in command here because it ends up inside ''.
1033 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1034                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1035   libc_cv_gcc_builtin_expect=yes
1036 else
1037   libc_cv_gcc_builtin_expect=no
1038 fi
1039 rm -f conftest*])
1040 if test "$libc_cv_gcc_builtin_expect" = yes; then
1041   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1042 fi
1043
1044 ### End of automated tests.
1045 ### Now run sysdeps configure fragments.
1046
1047 # sysdeps configure fragments may set these with files to be linked below.
1048 libc_link_dests=
1049 libc_link_sources=
1050
1051 # They also can set these variables.
1052 ldd_rewrite_script=no
1053
1054 # Iterate over all the sysdep directories we will use, running their
1055 # configure fragments, and looking for a uname implementation.
1056 uname=
1057 for dir in $sysnames; do
1058   case $dir in
1059     /*) dest=$dir ;;
1060     *)  dest=$srcdir/$dir ;;
1061   esac
1062   if test -r $dest/configure; then
1063     AC_MSG_RESULT(running configure fragment for $dest)
1064     . $dest/configure
1065   fi
1066 [
1067   if test -z "$uname"; then
1068     if test -r $dest/uname.c ||
1069        test -r $dest/uname.S ||
1070        { test -r $dest/syscalls.list &&
1071          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1072       uname=$dir
1073     fi
1074   fi
1075 ]dnl
1076 done
1077
1078 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1079
1080 # If we will use the generic uname implementation, we must figure out what
1081 # it will say by examining the system, and write the results in config-name.h.
1082 if test "$uname" = "sysdeps/generic"; then
1083
1084 changequote(,)dnl
1085   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1086 changequote([,])dnl
1087   if test $uname_sysname != $config_os; then
1088     config_release=`echo $config_os | sed s/$uname_sysname//`
1089   fi
1090 dnl
1091 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1092     if test -r /vmunix; then
1093       kernel_id=`strings /vmunix | grep UNIX`
1094     elif test -r /dynix; then
1095       kernel_id=`strings /dynix | grep DYNIX`
1096     else
1097       kernel_id=
1098     fi
1099 ])dnl
1100
1101   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1102 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1103 changequote(,)dnl
1104   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1105 changequote([,])dnl
1106   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1107          != x$config_release; then
1108     # The configuration release is a substring of the kernel release.
1109     libc_cv_uname_release=$kernel_release
1110   elif test x$config_release != x; then
1111     libc_cv_uname_release=$config_release
1112   elif test x$kernel_release != x; then
1113     libc_cv_uname_release=$kernel_release
1114   else
1115     libc_cv_uname_release=unknown
1116   fi])
1117   uname_release="$libc_cv_uname_release"
1118
1119   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1120 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1121 changequote(,)dnl
1122   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1123 changequote([,])dnl
1124   if test -n "$kernel_version"; then
1125     libc_cv_uname_version="$kernel_version"
1126   else
1127     libc_cv_uname_version=unknown
1128   fi])
1129   uname_version="$libc_cv_uname_version"
1130
1131 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1132   config_uname=config-name.h:config-name.in
1133 else
1134   # For non-generic uname, we don't need to create config-name.h at all.
1135   config_uname=
1136 fi
1137
1138 AC_MSG_CHECKING(stdio selection)
1139 AC_SUBST(stdio)
1140 case $stdio in
1141 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1142 default) stdio=stdio ;;
1143 esac
1144 AC_MSG_RESULT($stdio)
1145
1146 # Test for old glibc 2.0.x headers so that they can be removed properly
1147 # Search only in includedir.
1148 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1149 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1150 then
1151   old_glibc_headers=yes
1152 else
1153   old_glibc_headers=no
1154 fi
1155 AC_MSG_RESULT($old_glibc_headers)
1156 if test ${old_glibc_headers} = yes; then
1157   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1158   AC_MSG_WARN(*** be removed.)
1159 fi
1160 AC_SUBST(old_glibc_headers)
1161
1162 AC_SUBST(libc_cv_slibdir)
1163 AC_SUBST(libc_cv_sysconfdir)
1164 AC_SUBST(libc_cv_rootsbindir)
1165
1166 AC_SUBST(has_ldconfig)
1167 AC_SUBST(ldd_rewrite_script)
1168
1169 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1170 if test $gnu_ld = yes; then
1171   AC_DEFINE(HAVE_GNU_LD)
1172 fi
1173 if test $gnu_as = yes; then
1174   AC_DEFINE(HAVE_GNU_AS)
1175 fi
1176 if test $elf = yes; then
1177   AC_DEFINE(HAVE_ELF)
1178 fi
1179
1180 AC_SUBST(static)
1181 AC_SUBST(shared)
1182 if test $shared = default; then
1183   if test $gnu_ld = yes; then
1184     shared=$elf
1185   else
1186     # For now we do not assume shared libs are available.  In future more
1187     # tests might become available.
1188     shared=no
1189   fi
1190 fi
1191
1192 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1193 [pic_default=yes
1194 cat > conftest.c <<EOF
1195 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1196 # error PIC is default.
1197 #endif
1198 EOF
1199 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1200   pic_default=no
1201 fi
1202 rm -f conftest.*])
1203 AC_SUBST(pic_default)
1204
1205 AC_SUBST(profile)
1206 AC_SUBST(omitfp)
1207 AC_SUBST(bounded)
1208 AC_SUBST(static_nss)
1209 AC_SUBST(nopic_initfini)
1210
1211 AC_SUBST(DEFINES)
1212
1213 case "$add_ons" in
1214   *door*) linux_doors=yes ;;
1215   *) linux_doors=no ;;
1216 esac
1217 AC_SUBST(linux_doors)
1218
1219 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1220   config_makefile=
1221 else
1222   config_makefile=Makefile
1223 fi
1224
1225 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1226 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1227 AC_SUBST(VERSION)
1228 AC_SUBST(RELEASE)
1229
1230 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1231 case $CONFIG_FILES in *config.make*)
1232 echo "$config_vars" >> config.make;;
1233 esac
1234 test -d bits || mkdir bits], [config_vars='$config_vars'])