sysdeps/unix/sysv/linux/sh/sh3/getcontext.S

   1 /* Save current context.
   2    Copyright (C) 2005-2015 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21 #include "ucontext_i.h"
  22
  23 /*  int __getcontext (ucontext_t *uc);  */
  24
  25         .text
  26         .align  5
  27 ENTRY(__getcontext)
  28
  29         /* Return value of getcontext.  R0 is the only register whose
  30            value is not preserved.  */
  31         mov     #0, r0
  32         mov.l   r0, @(oR0,r4)
  33         mov.l   r1, @(oR1,r4)
  34         mov.l   r2, @(oR2,r4)
  35         mov.l   r3, @(oR3,r4)
  36         mov.l   r4, @(oR4,r4)
  37         mov.l   r5, @(oR5,r4)
  38         mov.l   r6, @(oR6,r4)
  39         mov.l   r7, @(oR7,r4)
  40         mov     r4, r0
  41         add     #(oMACL+4), r0
  42         sts.l   macl, @-r0
  43         sts.l   mach, @-r0
  44         stc.l   gbr, @-r0
  45
  46         /* Save T flag to SR.  */
  47         movt    r1
  48         mov.l   r1, @-r0
  49         sts.l   pr, @-r0
  50
  51         /* The return address of getcontext is the restart pc.  */
  52         sts.l   pr, @-r0
  53
  54         mov.l   r15, @-r0
  55         mov.l   r14, @-r0
  56         mov.l   r13, @-r0
  57         mov.l   r12, @-r0
  58         mov.l   r11, @-r0
  59         mov.l   r10, @-r0
  60         mov.l   r9, @-r0
  61         mov.l   r8, @-r0
  62
  63         /* sigprocmask (SIG_BLOCK, NULL, &uc->uc_sigmask).  */
  64         mov     r4, r6
  65         add     #oSIGMASK, r6
  66         mov     #SIG_BLOCK, r4
  67         mov     #0, r5
  68         mov     #+SYS_ify(sigprocmask), r3
  69         trapa   #0x13
  70         mov     r0, r1
  71         mov     #-12, r2
  72         shad    r2, r1
  73         not     r1, r1                  // r1=0 means r0 = -1 to -4095
  74         tst     r1, r1                  // i.e. error in linux
  75         bf      .Lgetcontext_end
  76 .Lsyscall_error:
  77         SYSCALL_ERROR_HANDLER
  78 .Lgetcontext_end:
  79         /* All done, return 0 for success.  */
  80         mov     #0, r0
  81 .Lpseudo_end:
  82         rts
  83          nop
  84
  85 PSEUDO_END(__getcontext)
  86
  87 weak_alias (__getcontext, getcontext)