sysdeps/unix/sysv/linux/s390/s390-32/mmap.S

   1 /* Copyright (C) 2000-2015 Free Software Foundation, Inc.
   2    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21 #define EINVAL  22
  22
  23         .text
  24 ENTRY(__mmap)
  25         /* Save registers and setup stack frame.  */
  26         stm     %r6,%r15,24(%r15)
  27         cfi_offset (%r15, -36)
  28         cfi_offset (%r14, -40)
  29         cfi_offset (%r13, -44)
  30         cfi_offset (%r12, -48)
  31         cfi_offset (%r11, -52)
  32         cfi_offset (%r10, -56)
  33         cfi_offset (%r9, -60)
  34         cfi_offset (%r8, -64)
  35         cfi_offset (%r7, -68)
  36         cfi_offset (%r6, -72)
  37         lr      %r1,%r15
  38         ahi     %r15,-120               /* buy stack space */
  39         cfi_adjust_cfa_offset (120)
  40         st      %r1,0(%r15)             /* store back chain */
  41
  42         /* Store parameters on stack, because mmap2
  43          * takes only one parameter: a pointer to the parameter area
  44          */
  45         st      %r6,0x70(%r15)          /* Store 'fd'.      */
  46         st      %r5,0x6C(%r15)          /* Store 'flags'.   */
  47         st      %r4,0x68(%r15)          /* Store 'prot'.    */
  48         st      %r3,0x64(%r15)          /* Store 'length'.  */
  49         st      %r2,0x60(%r15)          /* Store 'start'.   */
  50         l       %r1,216(%r15)           /* Load offset.     */
  51
  52         tml     %r1,0x0fff              /* Offset page aligned ?  */
  53         lhi     %r2,-EINVAL
  54         jnz     1f                      /* No -> EINVAL.  */
  55         srl     %r1,12                  /* mmap2 takes the offset in pages.  */
  56         st      %r1,0x74(%r15)          /* Store page offset.  */
  57         la      %r2,0x60(%r15)          /* Load address of parameter list.  */
  58         svc     SYS_ify(mmap2)          /* Do the system call trap.  */
  59
  60 1:      l       %r15,0(%r15)            /* Load back chain.  */
  61         cfi_adjust_cfa_offset (-120)
  62         lm      %r6,%r15,24(%r15)       /* Load registers.  */
  63
  64         /* check gpr 2 for error */
  65         lhi     %r0,-4096
  66         clr     %r2,%r0
  67         jnl     SYSCALL_ERROR_LABEL
  68
  69         /* Successful; return the syscall's value.  */
  70         br      %r14
  71
  72 PSEUDO_END (__mmap)
  73
  74 weak_alias (__mmap, mmap)