sysdeps/unix/sysv/linux/ia64/vfork.S

   1 /* Copyright (C) 2000-2015 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, see
  16    <http://www.gnu.org/licenses/>.  */
  17
  18
  19 #include <sysdep.h>
  20 #define _SIGNAL_H
  21 #include <bits/signum.h>
  22 #include <tcb-offsets.h>
  23
  24 /* The following are defined in linux/sched.h, which unfortunately      */
  25 /* is not safe for inclusion in an assembly file.                       */
  26 #define CLONE_VM        0x00000100      /* set if VM shared between processes */
  27 #define CLONE_VFORK     0x00004000      /* set if the parent wants the child to wake it up on mm_release */
  28
  29 /* pid_t vfork(void); */
  30 /* Implemented as __clone_syscall(CLONE_VFORK | CLONE_VM | SIGCHLD, 0)  */
  31
  32 ENTRY (__libc_vfork)
  33         .prologue       // work around a GAS bug which triggers if
  34         .body           // first .prologue is not at the beginning of proc.
  35         alloc r2=ar.pfs,0,0,2,0
  36         adds r14=PID,r13
  37         ;;
  38         ld4 r16=[r14]
  39         ;;
  40         sub r15=0,r16
  41         cmp.eq p6,p0=0,r16
  42         ;;
  43 (p6)    movl r15=0x80000000
  44         mov out0=CLONE_VM+CLONE_VFORK+SIGCHLD
  45         mov out1=0              /* Standard sp value.                   */
  46         ;;
  47         st4 [r14]=r15
  48         DO_CALL (SYS_ify (clone))
  49         cmp.eq p6,p0=0,r8
  50         adds r14=PID,r13
  51 (p6)    br.cond.dptk 1f
  52         ;;
  53         ld4 r15=[r14]
  54         ;;
  55         extr.u r16=r15,0,31
  56         ;;
  57         cmp.eq p0,p6=0,r16
  58         ;;
  59 (p6)    sub r16=0,r15
  60         ;;
  61         st4 [r14]=r16
  62 1:
  63         cmp.eq p6,p0=-1,r10
  64 (p6)    br.cond.spnt.few __syscall_error
  65         ret
  66 PSEUDO_END (__libc_vfork)
  67
  68 strong_alias (__libc_vfork, __vfork)
  69 libc_hidden_def (__vfork)
  70 weak_alias (__vfork, vfork)