sysdeps/unix/sysv/linux/i386/vfork.S

   1 /* Copyright (C) 1999-2015 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Andreas Schwab <schwab@gnu.org>.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #define _ERRNO_H        1
  21 #include <bits/errno.h>
  22 #include <tcb-offsets.h>
  23
  24
  25 /* Clone the calling process, but without copying the whole address space.
  26    The calling process is suspended until the new process exits or is
  27    replaced by a call to `execve'.  Return -1 for errors, 0 to the new process,
  28    and the process ID of the new process to the old process.  */
  29
  30 ENTRY (__vfork)
  31
  32         /* Pop the return PC value into ECX.  */
  33         popl    %ecx
  34         cfi_adjust_cfa_offset (-4)
  35         cfi_register (%eip, %ecx)
  36
  37         /* Save the TCB-cached PID away in %edx, and then negate the TCB
  38            field.  But if it's zero, set it to 0x80000000 instead.  See
  39            raise.c for the logic that relies on this value.  */
  40         movl    %gs:PID, %edx
  41         movl    %edx, %eax
  42         negl    %eax
  43         jne     1f
  44         movl    $0x80000000, %eax
  45 1:      movl    %eax, %gs:PID
  46
  47
  48         /* Stuff the syscall number in EAX and enter into the kernel.  */
  49         movl    $SYS_ify (vfork), %eax
  50         int     $0x80
  51
  52         /* Jump to the return PC.  Don't jump directly since this
  53            disturbs the branch target cache.  Instead push the return
  54            address back on the stack.  */
  55         pushl   %ecx
  56         cfi_adjust_cfa_offset (4)
  57
  58         /* Restore the original value of the TCB cache of the PID, if we're
  59            the parent.  But in the child (syscall return value equals zero),
  60            leave things as they are.  */
  61         testl   %eax, %eax
  62         je      1f
  63         movl    %edx, %gs:PID
  64 1:
  65
  66         cmpl    $-4095, %eax
  67         /* Branch forward if it failed.  */
  68         jae     SYSCALL_ERROR_LABEL
  69
  70         ret
  71
  72 PSEUDO_END (__vfork)
  73 libc_hidden_def (__vfork)
  74
  75 weak_alias (__vfork, vfork)
  76 strong_alias (__vfork, __libc_vfork)