sysdeps/unix/sysv/linux/alpha/clone.S

   1 /* Copyright (C) 1996-2015 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Richard Henderson <rth@tamu.edu>, 1996.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* clone() is even more special than fork() as it mucks with stacks
  20    and invokes a function in the right context after its all over.  */
  21
  22 #include <sysdep.h>
  23 #define _ERRNO_H        1
  24 #include <bits/errno.h>
  25
  26 #define CLONE_VM        0x00000100
  27 #define CLONE_THREAD    0x00010000
  28
  29 /* int clone(int (*fn)(void *arg), void *child_stack, int flags,
  30              void *arg, pid_t *ptid, void *tls, pid_t *ctid);
  31
  32    Note that everything past ARG is technically optional, based
  33    on FLAGS, and that CTID is arg 7, and thus is on the stack.
  34    However, since a load from top-of-stack better be legal always,
  35    we don't bother checking FLAGS.  */
  36
  37         .text
  38         .align  4
  39         .globl  __clone
  40         .ent    __clone
  41         .usepv  __clone, USEPV_PROF
  42
  43         cfi_startproc
  44 __clone:
  45 #ifdef PROF
  46         ldgp    gp,0(pv)
  47         lda     AT, _mcount
  48         jsr     AT, (AT), _mcount
  49 #endif
  50
  51         /* Sanity check arguments.  */
  52         ldiq    v0, EINVAL
  53         beq     a0, SYSCALL_ERROR_LABEL /* no NULL function pointers */
  54         beq     a1, SYSCALL_ERROR_LABEL /* no NULL stack pointers */
  55
  56         /* Save the fn ptr and arg on the new stack.  */
  57         subq    a1, 32, a1
  58         stq     a0, 0(a1)
  59         stq     a3, 8(a1)
  60         stq     a2, 16(a1)
  61
  62         /* The syscall is of the form clone(flags, usp, ptid, ctid, tls).
  63            Shift the flags, ptid, ctid, tls arguments into place; the
  64            child_stack argument is already correct.  */
  65         mov     a2, a0
  66         mov     a4, a2
  67         ldq     a3, 0(sp)
  68         mov     a5, a4
  69
  70         /* Do the system call.  */
  71         ldiq    v0, __NR_clone
  72         call_pal PAL_callsys
  73
  74         bne     a3, SYSCALL_ERROR_LABEL
  75         beq     v0, thread_start
  76
  77         /* Successful return from the parent.  */
  78         ret
  79
  80 PSEUDO_END(__clone)
  81         cfi_endproc
  82
  83 /* Load up the arguments to the function.  Put this block of code in
  84    its own function so that we can terminate the stack trace with our
  85    debug info.  */
  86
  87         .align  4
  88         .ent thread_start
  89         cfi_startproc
  90 thread_start:
  91         mov     0, fp
  92         cfi_def_cfa_register(fp)
  93         cfi_undefined(ra)
  94
  95         /* Check and see if we need to reset the PID.  */
  96         ldq     t0, 16(sp)
  97         lda     t1, CLONE_THREAD
  98         and     t0, t1, t2
  99         beq     t2, 2f
 100 1:
 101
 102         /* Load up the arguments.  */
 103         ldq     pv, 0(sp)
 104         ldq     a0, 8(sp)
 105         addq    sp, 32, sp
 106
 107         /* Call the user's function.  */
 108         jsr     ra, (pv)
 109         ldgp    gp, 0(ra)
 110
 111         /* Call _exit rather than doing it inline for breakpoint purposes.  */
 112         mov     v0, a0
 113 #ifdef PIC
 114         bsr     ra, HIDDEN_JUMPTARGET(_exit)    !samegp
 115 #else
 116         jsr     ra, HIDDEN_JUMPTARGET(_exit)
 117 #endif
 118
 119         /* Die horribly.  */
 120         .align  4
 121         halt
 122
 123         .align  4
 124 2:
 125         rduniq
 126         lda     t1, CLONE_VM
 127         mov     v0, s0
 128         lda     v0, -1
 129         and     t0, t1, t2
 130         bne     t2, 3f
 131         lda     v0, __NR_getxpid
 132         callsys
 133 3:
 134         stl     v0, PID_OFFSET(s0)
 135         stl     v0, TID_OFFSET(s0)
 136         br      1b
 137         cfi_endproc
 138         .end thread_start
 139
 140 weak_alias (__clone, clone)