| blob | 34ecbba540546337b5ec321fc6168c9544b39214 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Note we do not use AC_PREREQ here! See aclocal.m4 for what we use instead.
3 AC_INIT([GNU C Library], [(see version.h)], [https://sourceware.org/bugzilla/],
4 [glibc], [https://www.gnu.org/software/glibc/])
5 AC_CONFIG_SRCDIR([include/features.h])
6 AC_CONFIG_HEADERS([config.h])
7 AC_CONFIG_AUX_DIR([scripts])
9 ACX_PKGVERSION([GNU libc])
10 ACX_BUGURL([https://www.gnu.org/software/libc/bugs.html])
11 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
12 [Package description])
13 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
14 [Bug reporting address])
16 # Glibc should not depend on any header files
17 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
18 [m4_divert_text([DEFAULTS],
19 [ac_includes_default='/* none */'])])
21 # We require GCC, and by default use its preprocessor. Override AC_PROG_CPP
22 # here to work around the Autoconf issue discussed in
23 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
24 AC_DEFUN([AC_PROG_CPP],
25 [AC_REQUIRE([AC_PROG_CC])dnl
26 AC_ARG_VAR([CPP], [C preprocessor])dnl
27 _AC_ARG_VAR_CPPFLAGS()dnl
28 # On Suns, sometimes $CPP names a directory.
29 if test -n "$CPP" && test -d "$CPP"; then
30 CPP=
31 fi
32 if test -z "$CPP"; then
33 CPP="$CC -E"
34 fi
35 AC_SUBST(CPP)dnl
36 ])# AC_PROG_CPP
38 # We require GCC. Override _AC_PROG_CC_C89 here to work around the Autoconf
39 # issue discussed in
40 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
41 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
43 dnl This is here so we can set $subdirs directly based on configure fragments.
44 AC_CONFIG_SUBDIRS()
46 AC_CANONICAL_HOST
48 AC_PROG_CC
49 if test $host != $build; then
50 AC_CHECK_PROGS(BUILD_CC, gcc cc)
51 fi
52 AC_SUBST(cross_compiling)
53 AC_PROG_CPP
54 AC_CHECK_TOOL(READELF, readelf, false)
56 # We need the C++ compiler only for testing.
57 AC_PROG_CXX
58 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
59 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
60 AC_LANG_PUSH([C++])
61 # Default, dynamic case.
62 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
63 [libc_cv_cxx_link_ok=yes],
64 [libc_cv_cxx_link_ok=no])
65 # Static case.
66 old_LDFLAGS="$LDFLAGS"
67 LDFLAGS="$LDFLAGS -static"
68 AC_LINK_IFELSE([AC_LANG_SOURCE([
69 #include <iostream>
71 int
72 main()
73 {
74 std::cout << "Hello, world!";
75 return 0;
76 }
77 ])],
78 [],
79 [libc_cv_cxx_link_ok=no])
80 LDFLAGS="$old_LDFLAGS"
81 AC_LANG_POP([C++])])
82 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
84 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
85 AC_MSG_ERROR([you must configure in a separate build directory])
86 fi
88 # This will get text that should go into config.make.
89 config_vars=
91 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
92 AC_ARG_WITH([gd],
93 AS_HELP_STRING([--with-gd=DIR],
94 [find libgd include dir and library with prefix DIR]),
95 [dnl
96 case "$with_gd" in
97 yes|''|no) ;;
98 *) libgd_include="-I$withval/include"
99 libgd_ldflags="-L$withval/lib" ;;
100 esac
101 ])
102 AC_ARG_WITH([gd-include],
103 AS_HELP_STRING([--with-gd-include=DIR],
104 [find libgd include files in DIR]),
105 [dnl
106 case "$with_gd_include" in
107 ''|no) ;;
108 *) libgd_include="-I$withval" ;;
109 esac
110 ])
111 AC_ARG_WITH([gd-lib],
112 AS_HELP_STRING([--with-gd-lib=DIR],
113 [find libgd library files in DIR]),
114 [dnl
115 case "$with_gd_lib" in
116 ''|no) ;;
117 *) libgd_ldflags="-L$withval" ;;
118 esac
119 ])
121 if test -n "$libgd_include"; then
122 config_vars="$config_vars
123 CFLAGS-memusagestat.c = $libgd_include"
124 fi
125 if test -n "$libgd_ldflags"; then
126 config_vars="$config_vars
127 libgd-LDFLAGS = $libgd_ldflags"
128 fi
130 dnl Arguments to specify presence of other packages/features.
131 AC_ARG_WITH([binutils],
132 AS_HELP_STRING([--with-binutils=PATH],
133 [specify location of binutils (as and ld)]),
134 [path_binutils=$withval],
135 [path_binutils=''])
136 AC_ARG_WITH([selinux],
137 AS_HELP_STRING([--with-selinux],
138 [if building with SELinux support]),
139 [with_selinux=$withval],
140 [with_selinux=auto])
142 AC_ARG_WITH([headers],
143 AS_HELP_STRING([--with-headers=PATH],
144 [location of system headers to use
145 (for example /usr/src/linux/include)
146 @<:@default=compiler default@:>@]),
147 [sysheaders=$withval],
148 [sysheaders=''])
149 AC_SUBST(sysheaders)
151 AC_SUBST(use_default_link)
152 AC_ARG_WITH([default-link],
153 AS_HELP_STRING([--with-default-link],
154 [do not use explicit linker scripts]),
155 [use_default_link=$withval],
156 [use_default_link=default])
158 dnl Additional build flags injection.
159 AC_ARG_WITH([nonshared-cflags],
160 AS_HELP_STRING([--with-nonshared-cflags=CFLAGS],
161 [build nonshared libraries with additional CFLAGS]),
162 [extra_nonshared_cflags=$withval],
163 [extra_nonshared_cflags=])
164 AC_SUBST(extra_nonshared_cflags)
166 AC_ARG_ENABLE([sanity-checks],
167 AS_HELP_STRING([--disable-sanity-checks],
168 [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
169 [enable_sanity=$enableval],
170 [enable_sanity=yes])
172 AC_ARG_ENABLE([shared],
173 AS_HELP_STRING([--enable-shared],
174 [build shared library @<:@default=yes if GNU ld@:>@]),
175 [shared=$enableval],
176 [shared=yes])
177 AC_ARG_ENABLE([profile],
178 AS_HELP_STRING([--enable-profile],
179 [build profiled library @<:@default=no@:>@]),
180 [profile=$enableval],
181 [profile=no])
182 AC_ARG_ENABLE([static-pie],
183 AS_HELP_STRING([--enable-static-pie],
184 [enable static PIE support and use it in the testsuite @<:@default=no@:>@]),
185 [static_pie=$enableval],
186 [static_pie=no])
187 AC_ARG_ENABLE([timezone-tools],
188 AS_HELP_STRING([--disable-timezone-tools],
189 [do not install timezone tools @<:@default=install@:>@]),
190 [enable_timezone_tools=$enableval],
191 [enable_timezone_tools=yes])
192 AC_SUBST(enable_timezone_tools)
194 AC_ARG_ENABLE([hardcoded-path-in-tests],
195 AS_HELP_STRING([--enable-hardcoded-path-in-tests],
196 [hardcode newly built glibc path in tests @<:@default=no@:>@]),
197 [hardcoded_path_in_tests=$enableval],
198 [hardcoded_path_in_tests=no])
199 AC_SUBST(hardcoded_path_in_tests)
201 AC_ARG_ENABLE([hidden-plt],
202 AS_HELP_STRING([--disable-hidden-plt],
203 [do not hide internal function calls to avoid PLT]),
204 [hidden=$enableval],
205 [hidden=yes])
206 if test "x$hidden" = xno; then
207 AC_DEFINE(NO_HIDDEN)
208 fi
210 AC_ARG_ENABLE([bind-now],
211 AS_HELP_STRING([--enable-bind-now],
212 [disable lazy relocations in DSOs]),
213 [bindnow=$enableval],
214 [bindnow=no])
215 AC_SUBST(bindnow)
216 if test "x$bindnow" = xyes; then
217 AC_DEFINE(BIND_NOW)
218 fi
220 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
221 dnl -fstack-protector-strong.
222 AC_ARG_ENABLE([stack-protector],
223 AS_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
224 [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
225 [enable_stack_protector=$enableval],
226 [enable_stack_protector=no])
227 case "$enable_stack_protector" in
228 all|yes|no|strong) ;;
229 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
230 esac
232 dnl On some platforms we cannot use dynamic loading. We must provide
233 dnl static NSS modules.
234 AC_ARG_ENABLE([static-nss],
235 AS_HELP_STRING([--enable-static-nss],
236 [build static NSS modules @<:@default=no@:>@]),
237 [static_nss=$enableval],
238 [static_nss=no])
239 dnl Enable static NSS also if we build no shared objects.
240 if test x"$static_nss" = xyes || test x"$shared" = xno; then
241 static_nss=yes
242 AC_DEFINE(DO_STATIC_NSS)
243 fi
245 AC_ARG_ENABLE([force-install],
246 AS_HELP_STRING([--disable-force-install],
247 [don't force installation of files from this package, even if they are older than the installed files]),
248 [force_install=$enableval],
249 [force_install=yes])
250 AC_SUBST(force_install)
252 AC_ARG_ENABLE([maintainer-mode],
253 AS_HELP_STRING([--enable-maintainer-mode],
254 [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
255 [maintainer=$enableval],
256 [maintainer=no])
258 dnl On some platforms we allow dropping compatibility with all kernel
259 dnl versions.
260 AC_ARG_ENABLE([kernel],
261 AS_HELP_STRING([--enable-kernel=VERSION],
262 [compile for compatibility with kernel not older than VERSION]),
263 [minimum_kernel=$enableval],
264 [])
265 dnl Prevent unreasonable values.
266 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
267 # Better nothing than this.
268 minimum_kernel=""
269 else
270 if test "$minimum_kernel" = current; then
271 minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
272 fi
273 fi
275 dnl For the development we sometimes want gcc to issue even more warnings.
276 dnl This is not the default since many of the extra warnings are not
277 dnl appropriate.
278 AC_ARG_ENABLE([all-warnings],
279 AS_HELP_STRING([--enable-all-warnings],
280 [enable all useful warnings gcc can issue]),
281 [all_warnings=$enableval],
282 [])
283 AC_SUBST(all_warnings)
285 AC_ARG_ENABLE([werror],
286 AS_HELP_STRING([--disable-werror],
287 [do not build with -Werror]),
288 [enable_werror=$enableval],
289 [enable_werror=yes])
290 AC_SUBST(enable_werror)
292 AC_ARG_ENABLE([multi-arch],
293 AS_HELP_STRING([--enable-multi-arch],
294 [enable single DSO with optimizations for multiple architectures]),
295 [multi_arch=$enableval],
296 [multi_arch=default])
298 AC_ARG_ENABLE([experimental-malloc],
299 AS_HELP_STRING([--disable-experimental-malloc],
300 [disable experimental malloc features]),
301 [experimental_malloc=$enableval],
302 [experimental_malloc=yes])
303 AC_SUBST(experimental_malloc)
305 AC_ARG_ENABLE([memory-tagging],
306 AS_HELP_STRING([--enable-memory-tagging],
307 [enable memory tagging if supported by the architecture @<:@default=no@:>@]),
308 [memory_tagging=$enableval],
309 [memory_tagging=no])
310 if test "$memory_tagging" = yes; then
311 # Only enable this on architectures that support it.
312 case $host_cpu in
313 aarch64)
314 AC_DEFINE(USE_MTAG)
315 ;;
316 esac
317 fi
318 AC_SUBST(memory_tagging)
320 AC_ARG_ENABLE([crypt],
321 AS_HELP_STRING([--disable-crypt],
322 [do not build nor install the passphrase hashing library, libcrypt]),
323 [build_crypt=$enableval],
324 [build_crypt=yes])
325 AC_SUBST(build_crypt)
327 AC_ARG_ENABLE([nss-crypt],
328 AS_HELP_STRING([--enable-nss-crypt],
329 [enable libcrypt to use nss]),
330 [nss_crypt=$enableval],
331 [nss_crypt=no])
332 if test x$build_libcrypt = xno && test x$nss_crypt = xyes; then
333 AC_MSG_WARN([--enable-nss-crypt has no effect when libcrypt is disabled])
334 nss_crypt=no
335 fi
336 if test x$nss_crypt = xyes; then
337 nss_includes=-I$(nss-config --includedir 2>/dev/null)
338 if test $? -ne 0; then
339 AC_MSG_ERROR([cannot find include directory with nss-config])
340 fi
341 nspr_includes=-I$(nspr-config --includedir 2>/dev/null)
342 if test $? -ne 0; then
343 AC_MSG_ERROR([cannot find include directory with nspr-config])
344 fi
345 old_CFLAGS="$CFLAGS"
346 CFLAGS="$CFLAGS $nss_includes $nspr_includes"
347 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
348 #include <hasht.h>
349 #include <nsslowhash.h>
350 void f (void) { NSSLOW_Init (); }])],
351 libc_cv_nss_crypt=yes,
352 AC_MSG_ERROR([
353 cannot find NSS headers with lowlevel hash function interfaces]))
354 old_LIBS="$LIBS"
355 old_LDFLAGS="$LDFLAGS"
356 LIBS="$LIBS -lfreebl3"
357 AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
358 #include <hasht.h>
359 #include <nsslowhash.h>],
360 [NSSLOW_Init();])],
361 libc_cv_nss_crypt=yes,
362 AC_MSG_ERROR([
363 cannot link program using lowlevel NSS hash functions]))
364 # Check to see if there is a static NSS cryptographic library.
365 # If there isn't then we can't link anything with libcrypt.a,
366 # and that might mean disabling some static tests.
367 LDFLAGS="$LDFLAGS -static"
368 AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
369 #include <hasht.h>
370 #include <nsslowhash.h>],
371 [NSSLOW_Init();])],
372 libc_cv_static_nss_crypt=yes,
373 libc_cv_static_nss_crypt=no)
374 LDFLAGS="$old_LDFLAGS"
375 CFLAGS="$old_CFLAGS"
376 LIBS="$old_LIBS"
377 else
378 libc_cv_nss_crypt=no
379 libc_cv_static_nss_crypt=no
380 fi
381 AC_SUBST(libc_cv_nss_crypt)
382 AC_SUBST(libc_cv_static_nss_crypt)
385 AC_ARG_ENABLE([systemtap],
386 [AS_HELP_STRING([--enable-systemtap],
387 [enable systemtap static probe points @<:@default=no@:>@])],
388 [systemtap=$enableval],
389 [systemtap=no])
390 if test "x$systemtap" != xno; then
391 AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
392 old_CFLAGS="$CFLAGS"
393 CFLAGS="-std=gnu11 $CFLAGS"
394 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
395 void foo (int i, void *p)
396 {
397 asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
398 :: STAP_PROBE_ASM_OPERANDS (2, i, p));
399 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
400 CFLAGS="$old_CFLAGS"])
401 if test $libc_cv_sdt = yes; then
402 AC_DEFINE([USE_STAP_PROBE])
403 elif test "x$systemtap" != xauto; then
404 AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
405 fi
406 fi
408 AC_ARG_ENABLE([build-nscd],
409 [AS_HELP_STRING([--disable-build-nscd],
410 [disable building and installing the nscd daemon])],
411 [build_nscd=$enableval],
412 [build_nscd=default])
413 AC_SUBST(build_nscd)
415 # Note the use of $use_nscd is near the bottom of the file.
416 AC_ARG_ENABLE([nscd],
417 [AS_HELP_STRING([--disable-nscd],
418 [library functions will not contact the nscd daemon])],
419 [use_nscd=$enableval],
420 [use_nscd=yes])
422 AC_ARG_ENABLE([pt_chown],
423 [AS_HELP_STRING([--enable-pt_chown],
424 [Enable building and installing pt_chown])],
425 [build_pt_chown=$enableval],
426 [build_pt_chown=no])
427 AC_SUBST(build_pt_chown)
428 if test "$build_pt_chown" = yes; then
429 AC_DEFINE(HAVE_PT_CHOWN)
430 fi
432 AC_ARG_ENABLE([tunables],
433 [AS_HELP_STRING([--enable-tunables],
434 [Enable tunables support. Known values are 'yes', 'no' and 'valstring'])],
435 [have_tunables=$enableval],
436 [have_tunables=yes])
437 AC_SUBST(have_tunables)
438 if test "$have_tunables" = yes; then
439 AC_DEFINE(HAVE_TUNABLES)
440 fi
442 # The abi-tags file uses a fairly simplistic model for name recognition that
443 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu. So we mutate a
444 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
445 # This doesn't get used much beyond that, so it's fairly safe.
446 case "$host_os" in
447 linux*)
448 ;;
449 gnu*)
450 host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
451 ;;
452 esac
454 AC_ARG_ENABLE([mathvec],
455 [AS_HELP_STRING([--enable-mathvec],
456 [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
457 [build_mathvec=$enableval],
458 [build_mathvec=notset])
460 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[]], [[
461 #ifndef __CET__
462 # error no CET compiler support
463 #endif]])],
464 [libc_cv_compiler_default_cet=yes],
465 [libc_cv_compiler_default_cet=no])
467 AC_ARG_ENABLE([cet],
468 AS_HELP_STRING([--enable-cet],
469 [enable Intel Control-flow Enforcement Technology (CET), x86 only]),
470 [enable_cet=$enableval],
471 [enable_cet=$libc_cv_compiler_default_cet])
473 AC_ARG_ENABLE([scv],
474 AC_HELP_STRING([--disable-scv],
475 [syscalls will not use scv instruction, even if the kernel supports it, powerpc only]),
476 [use_scv=$enableval],
477 [use_scv=yes])
479 AS_IF([[test "$use_scv" != "no"]],[AC_DEFINE(USE_PPC_SCV)])
481 # We keep the original values in `$config_*' and never modify them, so we
482 # can write them unchanged into config.make. Everything else uses
483 # $machine, $vendor, and $os, and changes them whenever convenient.
484 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
486 # Don't allow vendor == "unknown"
487 test "$config_vendor" = unknown && config_vendor=
488 config_os="`echo $config_os | sed 's/^unknown-//'`"
490 # Some configurations imply other options.
491 elf=yes
493 # The configure fragment of a port can modify these to supplement
494 # or override the table in the case statement below. No fragment should
495 # ever change the config_* variables, however.
496 machine=$config_machine
497 vendor=$config_vendor
498 os=$config_os
499 base_os=''
501 submachine=
502 AC_ARG_WITH([cpu],
503 AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
504 [dnl
505 case "$withval" in
506 yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
507 no) ;;
508 *) submachine="$withval" ;;
509 esac
510 ])
512 # An preconfigure script can set this when it wants to disable the sanity
513 # check below.
514 libc_config_ok=no
516 # A preconfigure script for a system that may or may not use fpu
517 # sysdeps directories sets this to a preprocessor conditional for
518 # whether to use such directories.
519 with_fp_cond=1
521 dnl Let sysdeps/*/preconfigure act here.
522 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
525 ###
526 ### By using the undocumented --enable-hacker-mode option for configure
527 ### one can skip this test to make the configuration not fail for unsupported
528 ### platforms.
529 ###
530 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
531 case "$machine-$host_os" in
532 *-linux* | *-gnu*)
533 ;;
534 *)
535 AC_MSG_ERROR([
536 *** The GNU C library is currently unavailable for this platform.
537 *** If you are interested in seeing glibc on this platform visit
538 *** the "How to submit a new port" in the wiki:
539 *** https://sourceware.org/glibc/wiki/#Development
540 *** and join the community!])
541 ;;
542 esac
543 fi
545 # Set base_machine if not set by a preconfigure fragment.
546 test -n "$base_machine" || base_machine=$machine
547 AC_SUBST(base_machine)
549 # Determine whether to use fpu or nofpu sysdeps directories.
550 AC_CACHE_CHECK([for use of fpu sysdeps directories],
551 libc_cv_with_fp, [dnl
552 cat > conftest.c <<EOF
553 #if $with_fp_cond
554 int dummy;
555 #else
556 # error "no hardware floating point"
557 #endif
558 EOF
559 libc_cv_with_fp=no
560 if ${CC-cc} $CFLAGS $CPPFLAGS -S conftest.c -o conftest.s \
561 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
562 libc_cv_with_fp=yes
563 fi
564 rm -f conftest*])
565 AC_SUBST(libc_cv_with_fp)
567 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
568 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
569 [libc_cv_ssp=yes],
570 [libc_cv_ssp=no])
571 ])
573 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
574 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
575 [libc_cv_ssp_strong=yes],
576 [libc_cv_ssp_strong=no])
577 ])
579 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
580 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
581 [libc_cv_ssp_all=yes],
582 [libc_cv_ssp_all=no])
583 ])
585 stack_protector=
586 no_stack_protector=
587 if test "$libc_cv_ssp" = yes; then
588 no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
589 AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
590 fi
592 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
593 stack_protector="-fstack-protector"
594 AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
595 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
596 stack_protector="-fstack-protector-all"
597 AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
598 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
599 stack_protector="-fstack-protector-strong"
600 AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
601 else
602 stack_protector="-fno-stack-protector"
603 AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
604 fi
605 AC_SUBST(libc_cv_ssp)
606 AC_SUBST(stack_protector)
607 AC_SUBST(no_stack_protector)
609 if test -n "$stack_protector"; then
610 dnl Don't run configure tests with stack-protection on, to avoid problems with
611 dnl bootstrapping.
612 no_ssp=-fno-stack-protector
613 else
614 no_ssp=
616 if test "$enable_stack_protector" != no; then
617 AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
618 fi
619 fi
621 # For the multi-arch option we need support in the assembler & linker.
622 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
623 libc_cv_ld_gnu_indirect_function, [dnl
624 cat > conftest.S <<EOF
625 .type foo,%gnu_indirect_function
626 foo:
627 .globl _start
628 _start:
629 .globl __start
630 __start:
631 .data
632 #ifdef _LP64
633 .quad foo
634 #else
635 .long foo
636 #endif
637 EOF
638 libc_cv_ld_gnu_indirect_function=no
639 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
640 -nostartfiles -nostdlib $no_ssp \
641 -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
642 # Do a link to see if the backend supports IFUNC relocs.
643 $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
644 LC_ALL=C $READELF -Wr conftest | grep -q 'IRELATIVE\|R_SPARC_JMP_IREL' && {
645 libc_cv_ld_gnu_indirect_function=yes
646 }
647 fi
648 rm -f conftest*])
650 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
651 AC_CACHE_CHECK([for gcc attribute ifunc support],
652 libc_cv_gcc_indirect_function, [dnl
653 cat > conftest.c <<EOF
654 extern int func (int);
655 int used_func (int a)
656 {
657 return a;
658 }
659 static void *resolver ()
660 {
661 return &used_func;
662 }
663 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
664 EOF
665 libc_cv_gcc_indirect_function=no
666 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
667 2>&AS_MESSAGE_LOG_FD ; then
668 if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
669 libc_cv_gcc_indirect_function=yes
670 fi
671 fi
672 rm -f conftest*])
674 # Check if linker supports textrel relocation with ifunc (used on elf/tests).
675 # Note that it relies on libc_cv_ld_gnu_indirect_function test above.
676 AC_CACHE_CHECK([whether the linker supports textrels along with ifunc],
677 libc_cv_textrel_ifunc, [dnl
678 cat > conftest.S <<EOF
679 .type foo,%gnu_indirect_function
680 foo:
681 .globl _start
682 _start:
683 .globl __start
684 __start:
685 .data
686 #ifdef _LP64
687 .quad foo
688 #else
689 .long foo
690 #endif
691 .text
692 .globl address
693 address:
694 #ifdef _LP64
695 .quad address
696 #else
697 .long address
698 #endif
699 EOF
700 libc_cv_textrel_ifunc=no
701 if test $libc_cv_ld_gnu_indirect_function = yes; then
702 if AC_TRY_COMMAND(${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -nostartfiles -nostdlib $no_ssp -pie -o conftest conftest.S); then
703 libc_cv_textrel_ifunc=yes
704 fi
705 fi
706 rm -f conftest*])
707 AC_SUBST(libc_cv_textrel_ifunc)
709 # Check if CC supports attribute retain as it is used in attribute_used_retain macro.
710 AC_CACHE_CHECK([for GNU attribute retain support],
711 libc_cv_gnu_retain, [dnl
712 cat > conftest.c <<EOF
713 static int var __attribute__ ((used, retain, section ("__libc_atexit")));
714 EOF
715 libc_cv_gnu_retain=no
716 if ${CC-cc} -Werror -c conftest.c -o /dev/null 1>&AS_MESSAGE_LOG_FD \
717 2>&AS_MESSAGE_LOG_FD ; then
718 libc_cv_gnu_retain=yes
719 fi
720 rm -f conftest*])
721 if test $libc_cv_gnu_retain = yes; then
722 AC_DEFINE(HAVE_GNU_RETAIN)
723 fi
724 LIBC_CONFIG_VAR([have-gnu-retain], [$libc_cv_gnu_retain])
726 # Check if gcc warns about alias for function with incompatible types.
727 AC_CACHE_CHECK([if compiler warns about alias for function with incompatible types],
728 libc_cv_gcc_incompatible_alias, [dnl
729 cat > conftest.c <<EOF
730 int __redirect_foo (const void *s, int c);
732 __typeof (__redirect_foo) *foo_impl (void) __asm__ ("foo");
733 __typeof (__redirect_foo) *foo_impl (void)
734 {
735 return 0;
736 }
738 extern __typeof (__redirect_foo) foo_alias __attribute__ ((alias ("foo")));
739 EOF
740 libc_cv_gcc_incompatible_alias=yes
741 if ${CC-cc} -Werror -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
742 libc_cv_gcc_incompatible_alias=no
743 fi
744 rm -f conftest*])
746 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
747 if test x"$multi_arch" = xyes; then
748 AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
749 else
750 multi_arch=no
751 fi
752 fi
753 if test x"$libc_cv_gcc_indirect_function" != xyes; then
754 # GCC 8+ emits a warning for alias with incompatible types and it might
755 # fail to build ifunc resolvers aliases to either weak or internal
756 # symbols. Disables multiarch build in this case.
757 if test x"$libc_cv_gcc_incompatible_alias" == xyes; then
758 AC_MSG_WARN([gcc emits a warning for alias between functions of incompatible types])
759 if test x"$multi_arch" = xyes; then
760 AC_MSG_ERROR([--enable-multi-arch support requires a gcc with gnu-indirect-function support])
761 fi
762 AC_MSG_WARN([Multi-arch is disabled.])
763 multi_arch=no
764 elif test x"$multi_arch" = xyes; then
765 AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
766 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
767 fi
768 fi
769 multi_arch_d=
770 if test x"$multi_arch" != xno; then
771 multi_arch_d=/multiarch
772 fi
774 # Compute the list of sysdep directories for this configuration.
775 # This can take a while to compute.
776 sysdep_dir=$srcdir/sysdeps
777 AC_MSG_CHECKING(sysdep dirs)
778 dnl We need to use [ and ] for other purposes for a while now.
779 changequote(,)dnl
780 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
781 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
783 test "x$base_os" != x || case "$os" in
784 gnu*)
785 base_os=mach/hurd ;;
786 linux*)
787 base_os=unix/sysv ;;
788 esac
790 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
791 tail=$os
792 ostry=$os
793 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
794 ostry="$ostry /$o"
795 tail=$o
796 done
797 o=`echo $tail | sed 's/[0-9]*$//'`
798 if test $o != $tail; then
799 ostry="$ostry /$o"
800 fi
801 # For linux-gnu, try linux-gnu, then linux.
802 o=`echo $tail | sed 's/-.*$//'`
803 if test $o != $tail; then
804 ostry="$ostry /$o"
805 fi
807 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
808 base=
809 tail=$base_os
810 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
811 set $b
812 base="$base /$1"
813 tail="$2"
814 done
816 # For sparc/sparc32, try sparc/sparc32 and then sparc.
817 mach=
818 tail=$machine${submachine:+/$submachine}
819 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
820 set $m
821 # Prepend the machine's FPU directory unless the architecture specific
822 # preconfigure disables it.
823 if test "$libc_cv_with_fp" = yes; then
824 maybe_fpu=/fpu
825 else
826 maybe_fpu=/nofpu
827 fi
828 # For each machine term, try it with and then without /multiarch.
829 for try_fpu in $maybe_fpu ''; do
830 for try_multi in $multi_arch_d ''; do
831 mach="$mach /$1$try_fpu$try_multi"
832 done
833 done
834 tail="$2"
835 done
837 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
838 changequote([,])dnl
840 # Find what sysdep directories exist.
841 sysnames=
842 for b in $base ''; do
843 for m0 in $mach ''; do
844 for v in /$vendor ''; do
845 test "$v" = / && continue
846 for o in /$ostry ''; do
847 test "$o" = / && continue
848 for m in $mach ''; do
849 try_suffix="$m0$b$v$o$m"
850 if test -n "$try_suffix"; then
851 try_srcdir="${srcdir}/"
852 try="sysdeps$try_suffix"
853 test -n "$enable_debug_configure" &&
854 echo "$0 [DEBUG]: try $try" >&2
855 if test -d "$try_srcdir$try"; then
856 sysnames="$sysnames $try"
857 { test -n "$o" || test -n "$b"; } && os_used=t
858 { test -n "$m" || test -n "$m0"; } && machine_used=t
859 case x${m0:-$m} in
860 x*/$submachine) submachine_used=t ;;
861 esac
862 fi
863 fi
864 done
865 done
866 done
867 done
868 done
870 # If the assembler supports gnu_indirect_function symbol type and the
871 # architecture supports multi-arch, we enable multi-arch by default.
872 case $sysnames in
873 *"$multi_arch_d"*)
874 ;;
875 *)
876 test x"$multi_arch" = xdefault && multi_arch=no
877 ;;
878 esac
879 if test x"$multi_arch" != xno; then
880 AC_DEFINE(USE_MULTIARCH)
881 fi
882 AC_SUBST(multi_arch)
884 if test -z "$os_used" && test "$os" != none; then
885 AC_MSG_ERROR(Operating system $os is not supported.)
886 fi
887 if test -z "$machine_used" && test "$machine" != none; then
888 AC_MSG_ERROR(The $machine is not supported.)
889 fi
890 if test -z "$submachine_used" && test -n "$submachine"; then
891 AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
892 fi
893 AC_SUBST(submachine)
895 # We have now validated the configuration.
897 # Expand the list of system names into a full list of directories
898 # from each element's parent name and Implies file (if present).
899 set $sysnames
900 names=
901 while test $# -gt 0; do
902 name=$1
903 shift
905 case " $names " in *" $name "*)
906 # Already in the list.
907 continue
908 esac
910 # Report each name as we discover it, so there is no long pause in output.
911 echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
913 name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
915 case $name in
916 /*) xsrcdir= ;;
917 *) xsrcdir=$srcdir/ ;;
918 esac
919 test -n "$enable_debug_configure" &&
920 echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
922 for implies_file in Implies Implies-before Implies-after; do
923 implies_type=`echo $implies_file | sed s/-/_/`
924 eval ${implies_type}=
925 if test -f $xsrcdir$name/$implies_file; then
926 # Collect more names from the `Implies' file (removing comments).
927 implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
928 for x in $implied_candidate; do
929 found=no
930 if test -d $xsrcdir$name_base/$x; then
931 eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
932 found=yes
933 fi
934 try="sysdeps/$x"
935 try_srcdir=$srcdir/
936 test -n "$enable_debug_configure" &&
937 echo "[DEBUG]: $name $implies_file $x try() {$try_srcdir}$try" >&2
938 if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
939 then
940 eval "${implies_type}=\"\$${implies_type} \$try\""
941 found=yes
942 fi
943 if test $found = no; then
944 AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
945 fi
946 done
947 fi
948 done
950 # Add NAME to the list of names.
951 names="$names $name"
953 # Find the parent of NAME, using the empty string if it has none.
954 changequote(,)dnl
955 parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
956 changequote([,])dnl
958 test -n "$enable_debug_configure" &&
959 echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
960 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
962 # Add the names implied by NAME, and NAME's parent (if it has one), to
963 # the list of names to be processed (the argument list). We prepend the
964 # implied names to the list and append the parent. We want implied
965 # directories to come before further directories inferred from the
966 # configuration components; this ensures that for sysv4, unix/common
967 # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
968 # after sysv4).
969 sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
970 test -n "$sysnames" && set $sysnames
971 done
973 # Add the default directories.
974 default_sysnames="sysdeps/generic"
975 sysnames="$names $default_sysnames"
976 AC_SUBST(sysnames)
977 # The other names were emitted during the scan.
978 AC_MSG_RESULT($default_sysnames)
981 ### Locate tools.
983 AC_PROG_INSTALL
984 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
985 # The makefiles need to use a different form to find it in $srcdir.
986 INSTALL='\$(..)./scripts/install-sh -c'
987 fi
988 AC_PROG_LN_S
990 LIBC_PROG_BINUTILS
992 # Accept binutils 2.25 or newer.
993 AC_CHECK_PROG_VER(AS, $AS, --version,
994 [GNU assembler.* \([0-9]*\.[0-9.]*\)],
995 [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
996 AS=: critic_missing="$critic_missing as")
998 if test -n "`$LD --version | sed -n 's/^GNU \(gold\).*$/\1/p'`"; then
999 # Accept gold 1.14 or higher
1000 AC_CHECK_PROG_VER(LD, $LD, --version,
1001 [GNU gold.* \([0-9][0-9]*\.[0-9.]*\)],
1002 [1.1[4-9]*|1.[2-9][0-9]*|1.1[0-9][0-9]*|[2-9].*|[1-9][0-9]*],
1003 LD=: critic_missing="$critic_missing GNU gold")
1004 else
1005 AC_CHECK_PROG_VER(LD, $LD, --version,
1006 [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
1007 [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
1008 LD=: critic_missing="$critic_missing GNU ld")
1009 fi
1011 # These programs are version sensitive.
1012 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
1013 [GNU Make[^0-9]*\([0-9][0-9.]*\)],
1014 [[4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
1016 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
1017 [GNU gettext.* \([0-9]*\.[0-9.]*\)],
1018 [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
1019 MSGFMT=: aux_missing="$aux_missing msgfmt")
1020 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1021 [GNU texinfo.* \([0-9][0-9.]*\)],
1022 [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
1023 MAKEINFO=: aux_missing="$aux_missing makeinfo")
1024 AC_CHECK_PROG_VER(SED, sed, --version,
1025 [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
1026 [3.0[2-9]*|3.[1-9]*|[4-9]*],
1027 SED=: aux_missing="$aux_missing sed")
1028 AC_CHECK_PROG_VER(AWK, gawk, --version,
1029 [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
1030 [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
1031 AC_CHECK_PROG_VER(BISON, bison, --version,
1032 [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1033 [2.7*|[3-9].*|[1-9][0-9]*], critic_missing="$critic_missing bison")
1035 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
1036 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[]], [[
1037 #if !defined __GNUC__ || __GNUC__ < 6 || (__GNUC__ == 6 && __GNUC_MINOR__ < 2)
1038 #error insufficient compiler
1039 #endif]])],
1040 [libc_cv_compiler_ok=yes],
1041 [libc_cv_compiler_ok=no])])
1042 AS_IF([test $libc_cv_compiler_ok != yes],
1043 [critic_missing="$critic_missing compiler"])
1045 AC_CHECK_TOOL(NM, nm, false)
1047 if test "x$maintainer" = "xyes"; then
1048 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1049 case "x$AUTOCONF" in
1050 xno|x|x:) AUTOCONF=no ;;
1051 *)
1052 AC_CACHE_CHECK(dnl
1053 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1054 if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
1055 libc_cv_autoconf_works=yes
1056 else
1057 libc_cv_autoconf_works=no
1058 fi])
1059 test $libc_cv_autoconf_works = yes || AUTOCONF=no
1060 ;;
1061 esac
1062 if test "x$AUTOCONF" = xno; then
1063 aux_missing="$aux_missing autoconf"
1064 fi
1065 else
1066 AUTOCONF=no
1067 fi
1069 # Check for python3 if available, or else python.
1070 AC_CHECK_PROG_VER(PYTHON_PROG, python3 python, --version,
1071 [Python \([0-9][0-9.]*\)],
1072 [3.[4-9]*|3.[1-9][0-9]*|[4-9].*|[1-9][0-9]*],
1073 critic_missing="$critic_missing python")
1074 PYTHON="$PYTHON_PROG -B"
1075 AC_SUBST(PYTHON)
1077 test -n "$critic_missing" && AC_MSG_ERROR([
1078 *** These critical programs are missing or too old:$critic_missing
1079 *** Check the INSTALL file for required versions.])
1081 test -n "$aux_missing" && AC_MSG_WARN([
1082 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1083 *** some features or tests will be disabled.
1084 *** Check the INSTALL file for required versions.])
1086 # if using special system headers, find out the compiler's sekrit
1087 # header directory and add that to the list. NOTE: Only does the right
1088 # thing on a system that doesn't need fixincludes. (Not presently a problem.)
1089 if test -n "$sysheaders"; then
1090 SYSINCLUDES=-nostdinc
1091 for d in include include-fixed; do
1092 i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1093 SYSINCLUDES="$SYSINCLUDES -isystem $i"
1094 done
1095 SYSINCLUDES="$SYSINCLUDES \
1096 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1097 if test -n "$CXX"; then
1098 CXX_SYSINCLUDES=
1099 for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1100 | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1101 test "x$cxxheaders" != x &&
1102 CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1103 done
1104 fi
1105 fi
1106 AC_SUBST(SYSINCLUDES)
1107 AC_SUBST(CXX_SYSINCLUDES)
1109 # Obtain some C++ header file paths. This is used to make a local
1110 # copy of those headers in Makerules.
1111 if test -n "$CXX"; then
1112 find_cxx_header () {
1113 echo "#include <$1>" | $CXX -M -MP -x c++ - 2>/dev/null \
1114 | sed -n "\,$1:,{s/:\$//;p}"
1115 }
1116 CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1117 CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1118 CXX_BITS_STD_ABS_H="$(find_cxx_header bits/std_abs.h)"
1119 fi
1120 AC_SUBST(CXX_CSTDLIB_HEADER)
1121 AC_SUBST(CXX_CMATH_HEADER)
1122 AC_SUBST(CXX_BITS_STD_ABS_H)
1124 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1125 # since this would lead to problems installing/building glibc.
1126 # LD_LIBRARY_PATH contains the current directory if one of the following
1127 # is true:
1128 # - one of the terminals (":" and ";") is the first or last sign
1129 # - two terminals occur directly after each other
1130 # - the path contains an element with a dot in it
1131 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1132 changequote(,)dnl
1133 case ${LD_LIBRARY_PATH} in
1134 [:\;]* | *[:\;] | *[:\;][:\;]* | *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1135 ld_library_path_setting="contains current directory"
1136 ;;
1137 *)
1138 ld_library_path_setting="ok"
1139 ;;
1140 esac
1141 changequote([,])dnl
1142 AC_MSG_RESULT($ld_library_path_setting)
1143 if test "$ld_library_path_setting" != "ok"; then
1144 AC_MSG_ERROR([
1145 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1146 *** building glibc. Please change the environment variable
1147 *** and run configure again.])
1148 fi
1150 AC_PATH_PROG(BASH_SHELL, bash, no)
1152 AC_PATH_PROG(PERL, perl, no)
1153 if test "$PERL" != no &&
1154 (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1155 PERL=no
1156 fi
1157 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1158 $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1160 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1161 cat > conftest.s <<EOF
1162 .text
1163 foo:
1164 .set glibc_conftest_frobozz,foo
1165 .globl glibc_conftest_frobozz
1166 EOF
1167 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1168 # (but it doesn't work), so we must do a linking check to be sure.
1169 cat > conftest1.c <<\EOF
1170 extern int glibc_conftest_frobozz;
1171 void _start() { glibc_conftest_frobozz = 1; }
1172 EOF
1173 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1174 -nostartfiles -nostdlib $no_ssp \
1175 -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1176 libc_cv_asm_set_directive=yes
1177 else
1178 libc_cv_asm_set_directive=no
1179 fi
1180 rm -f conftest*])
1181 if test $libc_cv_asm_set_directive = yes; then
1182 AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1183 fi
1185 AC_CACHE_CHECK(linker support for protected data symbol,
1186 libc_cv_protected_data,
1187 [cat > conftest.c <<EOF
1188 int bar __attribute__ ((visibility ("protected"))) = 1;
1189 EOF
1190 libc_cv_protected_data=no
1191 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1192 cat > conftest.c <<EOF
1193 extern int bar;
1194 int main (void) { return bar; }
1195 EOF
1196 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1197 libc_cv_protected_data=yes
1198 fi
1199 fi
1200 rm -f conftest.*
1201 ])
1202 AC_SUBST(libc_cv_protected_data)
1204 AC_CACHE_CHECK(linker support for INSERT in linker script,
1205 libc_cv_insert,
1206 [cat > conftest.c <<EOF
1207 const int __attribute__ ((section(".bar"))) bar = 0x12345678;
1208 int test (void) { return bar; }
1209 EOF
1210 cat > conftest.t <<EOF
1211 SECTIONS
1212 {
1213 .bar : { *(.bar) }
1214 }
1215 INSERT AFTER .rela.dyn;
1216 EOF
1217 libc_cv_insert=no
1218 if AC_TRY_COMMAND([${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -Wl,-T,conftest.t -o conftest.so]); then
1219 libc_cv_insert=yes
1220 fi
1221 rm -f conftest.*
1222 ])
1223 AC_SUBST(libc_cv_insert)
1225 AC_CACHE_CHECK(for broken __attribute__((alias())),
1226 libc_cv_broken_alias_attribute,
1227 [cat > conftest.c <<EOF
1228 extern int foo (int x) __asm ("xyzzy");
1229 int bar (int x) { return x; }
1230 extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1231 extern int dfoo;
1232 extern __typeof (dfoo) dfoo __asm ("abccb");
1233 int dfoo = 1;
1234 EOF
1235 libc_cv_broken_alias_attribute=yes
1236 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1237 if grep 'xyzzy' conftest.s >/dev/null &&
1238 grep 'abccb' conftest.s >/dev/null; then
1239 libc_cv_broken_alias_attribute=no
1240 fi
1241 fi
1242 rm -f conftest.c conftest.s
1243 ])
1244 if test $libc_cv_broken_alias_attribute = yes; then
1245 AC_MSG_ERROR(working alias attribute support required)
1246 fi
1248 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1249 libc_cv_have_sdata_section,
1250 [echo "int i;" > conftest.c
1251 libc_cv_have_sdata_section=no
1252 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1253 | grep '\.sdata' >/dev/null; then
1254 libc_cv_have_sdata_section=yes
1255 fi
1256 rm -f conftest.c conftest.so
1257 ])
1258 if test $libc_cv_have_sdata_section = yes; then
1259 AC_DEFINE(HAVE_SDATA_SECTION)
1260 fi
1262 AC_CACHE_CHECK(for libunwind-support in compiler,
1263 libc_cv_cc_with_libunwind, [
1264 cat > conftest.c <<EOF
1265 int main (void) { return 0; }
1266 EOF
1267 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1268 conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1269 libc_cv_cc_with_libunwind=yes
1270 else
1271 libc_cv_cc_with_libunwind=no
1272 fi
1273 rm -f conftest*])
1274 AC_SUBST(libc_cv_cc_with_libunwind)
1275 if test $libc_cv_cc_with_libunwind = yes; then
1276 AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1277 fi
1279 ASFLAGS_config=
1280 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1281 libc_cv_as_noexecstack, [dnl
1282 cat > conftest.c <<EOF
1283 void foo (void) { }
1284 EOF
1285 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1286 -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1287 && grep .note.GNU-stack conftest.s >/dev/null \
1288 && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1289 -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1290 then
1291 libc_cv_as_noexecstack=yes
1292 else
1293 libc_cv_as_noexecstack=no
1294 fi
1295 rm -f conftest*])
1296 if test $libc_cv_as_noexecstack = yes; then
1297 ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1298 fi
1299 AC_SUBST(ASFLAGS_config)
1301 AC_CACHE_CHECK(for -z combreloc,
1302 libc_cv_z_combreloc, [dnl
1303 cat > conftest.c <<EOF
1304 extern int bar (int);
1305 extern int mumble;
1306 int foo (void) { return bar (mumble); }
1307 EOF
1308 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1309 -fPIC -shared $no_ssp -o conftest.so conftest.c
1310 -nostdlib -nostartfiles
1311 -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1312 then
1313 dnl The following test is a bit weak. We must use a tool which can test
1314 dnl cross-platform since the gcc used can be a cross compiler. Without
1315 dnl introducing new options this is not easily doable. Instead use a tool
1316 dnl which always is cross-platform: readelf. To detect whether -z combreloc
1317 dnl look for a section named .rel.dyn or .rela.dyn.
1318 if $READELF -S conftest.so | grep -E '.rela?.dyn' > /dev/null; then
1319 libc_cv_z_combreloc=yes
1320 else
1321 libc_cv_z_combreloc=no
1322 fi
1323 else
1324 libc_cv_z_combreloc=no
1325 fi
1326 rm -f conftest*])
1327 if test "$libc_cv_z_combreloc" = yes; then
1328 AC_DEFINE(HAVE_Z_COMBRELOC)
1329 fi
1330 AC_SUBST(libc_cv_z_combreloc)
1332 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1333 [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1334 AC_SUBST(libc_cv_z_execstack)
1336 LIBC_LINKER_FEATURE([-z start-stop-gc], [-Wl,-z,start-stop-gc],
1337 [libc_cv_z_start_stop_gc=yes], [libc_cv_z_start_stop_gc=no])
1338 LIBC_CONFIG_VAR([have-z-start-stop-gc], [$libc_cv_z_start_stop_gc])
1340 LIBC_LINKER_FEATURE([--no-dynamic-linker],
1341 [-Wl,--no-dynamic-linker],
1342 [libc_cv_no_dynamic_linker=yes],
1343 [libc_cv_no_dynamic_linker=no])
1344 LIBC_CONFIG_VAR([have-no-dynamic-linker], [$libc_cv_no_dynamic_linker])
1346 AC_CACHE_CHECK(for -static-pie, libc_cv_static_pie, [dnl
1347 LIBC_TRY_CC_OPTION([-static-pie],
1348 [libc_cv_static_pie=yes],
1349 [libc_cv_static_pie=no])
1350 ])
1351 LIBC_CONFIG_VAR([have-static-pie], [$libc_cv_static_pie])
1353 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1354 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1355 ])
1357 AC_SUBST(libc_cv_fpie)
1359 AC_CACHE_CHECK(for --hash-style option,
1360 libc_cv_hashstyle, [dnl
1361 cat > conftest.c <<EOF
1362 int _start (void) { return 42; }
1363 EOF
1364 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1365 -fPIC -shared -o conftest.so conftest.c
1366 -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1367 then
1368 libc_cv_hashstyle=yes
1369 else
1370 libc_cv_hashstyle=no
1371 fi
1372 rm -f conftest*])
1373 AC_SUBST(libc_cv_hashstyle)
1375 # The linker's default -shared behavior is good enough if it
1376 # does these things that our custom linker scripts ensure that
1377 # all allocated NOTE sections come first.
1378 if test "$use_default_link" = default; then
1379 AC_CACHE_CHECK([for sufficient default -shared layout],
1380 libc_cv_use_default_link, [dnl
1381 libc_cv_use_default_link=no
1382 cat > conftest.s <<\EOF
1383 .section .note.a,"a",%note
1384 .balign 4
1385 .long 4,4,9
1386 .string "GNU"
1387 .string "foo"
1388 .section .note.b,"a",%note
1389 .balign 4
1390 .long 4,4,9
1391 .string "GNU"
1392 .string "bar"
1393 EOF
1394 if AC_TRY_COMMAND([dnl
1395 ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1396 ac_try=`$READELF -S conftest.so | sed -n \
1397 ['${x;p;}
1398 s/^ *\[ *[1-9][0-9]*\] *\([^ ][^ ]*\) *\([^ ][^ ]*\) .*$/\2 \1/
1399 t a
1400 b
1401 : a
1402 H']`
1403 then
1404 libc_seen_a=no libc_seen_b=no
1405 set -- $ac_try
1406 while test $# -ge 2 -a "$1" = NOTE; do
1407 case "$2" in
1408 .note.a) libc_seen_a=yes ;;
1409 .note.b) libc_seen_b=yes ;;
1410 esac
1411 shift 2
1412 done
1413 case "$libc_seen_a$libc_seen_b" in
1414 yesyes)
1415 libc_cv_use_default_link=yes
1416 ;;
1417 *)
1418 echo >&AS_MESSAGE_LOG_FD "\
1419 $libc_seen_a$libc_seen_b from:
1420 $ac_try"
1421 ;;
1422 esac
1423 fi
1424 rm -f conftest*])
1425 use_default_link=$libc_cv_use_default_link
1426 fi
1428 AC_CACHE_CHECK(for GLOB_DAT reloc,
1429 libc_cv_has_glob_dat, [dnl
1430 cat > conftest.c <<EOF
1431 extern int mumble;
1432 int foo (void) { return mumble; }
1433 EOF
1434 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1435 -fPIC -shared -o conftest.so conftest.c
1436 -nostdlib -nostartfiles $no_ssp
1437 1>&AS_MESSAGE_LOG_FD])
1438 then
1439 dnl look for GLOB_DAT relocation.
1440 if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1441 libc_cv_has_glob_dat=yes
1442 else
1443 libc_cv_has_glob_dat=no
1444 fi
1445 else
1446 libc_cv_has_glob_dat=no
1447 fi
1448 rm -f conftest*])
1449 AC_SUBST(libc_cv_has_glob_dat)
1451 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1452 cat > conftest.c <<EOF
1453 int foo;
1454 EOF
1455 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1456 conftest.c 1>&AS_MESSAGE_LOG_FD])
1457 then
1458 libc_cv_fno_toplevel_reorder=yes
1459 else
1460 libc_cv_fno_toplevel_reorder=no
1461 fi
1462 rm -f conftest*])
1463 if test $libc_cv_fno_toplevel_reorder = yes; then
1464 fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1465 else
1466 fno_unit_at_a_time=-fno-unit-at-a-time
1467 fi
1468 AC_SUBST(fno_unit_at_a_time)
1470 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1471 [dnl
1472 cat > conftest.c <<EOF
1473 __thread int i;
1474 void foo (void)
1475 {
1476 i = 10;
1477 }
1478 EOF
1479 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1480 conftest.c 1>&AS_MESSAGE_LOG_FD])
1481 then
1482 libc_cv_mtls_dialect_gnu2=yes
1483 else
1484 libc_cv_mtls_dialect_gnu2=no
1485 fi
1486 rm -f conftest*])
1487 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1488 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1490 AC_CACHE_CHECK(whether cc puts quotes around section names,
1491 libc_cv_have_section_quotes,
1492 [cat > conftest.c <<EOF
1493 static const int foo
1494 __attribute__ ((section ("bar"))) = 1;
1495 EOF
1496 if ${CC-cc} -S conftest.c -o conftest.s; then
1497 if grep '\.section.*"bar"' conftest.s >/dev/null; then
1498 libc_cv_have_section_quotes=yes
1499 else
1500 libc_cv_have_section_quotes=no
1501 fi
1502 else
1503 libc_cv_have_section_quotes=unknown
1504 fi
1505 rm -f conftest.{c,s}
1506 ])
1507 if test $libc_cv_have_section_quotes = yes; then
1508 AC_DEFINE(HAVE_SECTION_QUOTES)
1509 fi
1511 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1512 cat > conftest.c <<\EOF
1513 void zero (void *x)
1514 {
1515 __builtin_memset (x, 0, 1000);
1516 }
1517 EOF
1518 dnl
1519 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "memset" > /dev/null]);
1520 then
1521 libc_cv_gcc_builtin_memset=no
1522 else
1523 libc_cv_gcc_builtin_memset=yes
1524 fi
1525 rm -f conftest* ])
1526 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1527 AC_DEFINE(HAVE_BUILTIN_MEMSET)
1528 fi
1530 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1531 cat > conftest.c <<\EOF
1532 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1533 char *foo (const char *a, const char *b)
1534 {
1535 return __builtin_strstr (a, b);
1536 }
1537 EOF
1538 dnl
1539 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "my_strstr" > /dev/null]);
1540 then
1541 libc_cv_gcc_builtin_redirection=yes
1542 else
1543 libc_cv_gcc_builtin_redirection=no
1544 fi
1545 rm -f conftest* ])
1546 if test "$libc_cv_gcc_builtin_redirection" = no; then
1547 AC_MSG_ERROR([support for the symbol redirection needed])
1548 fi
1550 dnl Determine how to disable generation of FMA instructions.
1551 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1552 libc_cv_cc_nofma, [dnl
1553 libc_cv_cc_nofma=
1554 for opt in -ffp-contract=off -mno-fused-madd; do
1555 LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1556 done])
1557 AC_SUBST(libc_cv_cc_nofma)
1559 if test -n "$submachine"; then
1560 AC_CACHE_CHECK([for compiler option for CPU variant],
1561 libc_cv_cc_submachine, [dnl
1562 libc_cv_cc_submachine=no
1563 for opt in "-march=$submachine" "-mcpu=$submachine"; do
1564 LIBC_TRY_CC_OPTION([$opt], [
1565 libc_cv_cc_submachine="$opt"
1566 break], [])
1567 done])
1568 if test "x$libc_cv_cc_submachine" = xno; then
1569 AC_MSG_ERROR([${CC-cc} does not support $submachine])
1570 fi
1571 fi
1572 AC_SUBST(libc_cv_cc_submachine)
1574 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1575 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1576 cat > conftest.c <<EOF
1577 void
1578 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1579 foo (void) {}
1580 EOF
1581 libc_cv_cc_loop_to_function=no
1582 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1583 then
1584 libc_cv_cc_loop_to_function=yes
1585 fi
1586 rm -f conftest*])
1587 if test $libc_cv_cc_loop_to_function = yes; then
1588 AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1589 fi
1590 AC_SUBST(libc_cv_cc_loop_to_function)
1592 dnl Check whether we have the gd library available.
1593 AC_MSG_CHECKING(for libgd)
1594 if test "$with_gd" != "no"; then
1595 old_CFLAGS="$CFLAGS"
1596 CFLAGS="$CFLAGS $libgd_include"
1597 old_LDFLAGS="$LDFLAGS"
1598 LDFLAGS="$LDFLAGS $libgd_ldflags"
1599 old_LIBS="$LIBS"
1600 LIBS="$LIBS -lgd -lpng -lz -lm"
1601 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gd.h>]], [[gdImagePng (0, 0)]])],
1602 [LIBGD=yes], [LIBGD=no])
1603 CFLAGS="$old_CFLAGS"
1604 LDFLAGS="$old_LDFLAGS"
1605 LIBS="$old_LIBS"
1606 else
1607 LIBGD=no
1608 fi
1609 AC_MSG_RESULT($LIBGD)
1610 AC_SUBST(LIBGD)
1612 # SELinux detection
1613 if test x$with_selinux = xno ; then
1614 have_selinux=no;
1615 else
1616 # See if we have the SELinux library
1617 AC_CHECK_LIB(selinux, is_selinux_enabled,
1618 have_selinux=yes, have_selinux=no)
1619 if test x$with_selinux = xyes ; then
1620 if test x$have_selinux = xno ; then
1621 AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1622 fi
1623 fi
1624 fi
1625 # Check if we're building with SELinux support.
1626 if test "x$have_selinux" = xyes; then
1627 AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1629 # See if we have the libaudit library
1630 AC_CHECK_LIB(audit, audit_log_user_avc_message,
1631 have_libaudit=yes, have_libaudit=no)
1632 if test "x$have_libaudit" = xyes; then
1633 AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1634 fi
1635 AC_SUBST(have_libaudit)
1637 # See if we have the libcap library
1638 AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1639 if test "x$have_libcap" = xyes; then
1640 AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1641 fi
1642 AC_SUBST(have_libcap)
1643 fi
1644 AC_SUBST(have_selinux)
1646 CPPUNDEFS=
1647 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1648 dnl Since we are building the implementations of the fortified functions here,
1649 dnl having the macro defined interacts very badly.
1650 dnl _FORTIFY_SOURCE requires compiler optimization level 1 (gcc -O1)
1651 dnl and above (see "man FEATURE_TEST_MACROS").
1652 dnl So do NOT replace AC_COMPILE_IFELSE with AC_PREPROC_IFELSE.
1653 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1654 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
1655 #ifdef _FORTIFY_SOURCE
1656 # error bogon
1657 #endif]])],
1658 [libc_cv_predef_fortify_source=no],
1659 [libc_cv_predef_fortify_source=yes])])
1660 if test $libc_cv_predef_fortify_source = yes; then
1661 CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1662 fi
1663 AC_SUBST(CPPUNDEFS)
1665 # Some linkers on some architectures support __ehdr_start but with
1666 # bugs. Make sure usage of it does not create relocations in the
1667 # output (as the linker should resolve them all for us).
1668 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1669 libc_cv_ehdr_start, [
1670 old_CFLAGS="$CFLAGS"
1671 old_LDFLAGS="$LDFLAGS"
1672 old_LIBS="$LIBS"
1673 CFLAGS="$CFLAGS -fPIC"
1674 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared $no_ssp"
1675 LIBS=
1676 AC_LINK_IFELSE([AC_LANG_SOURCE([
1677 typedef struct {
1678 char foo;
1679 long val;
1680 } Ehdr;
1681 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1682 long ehdr (void) { return __ehdr_start.val; }
1683 ])],
1684 [if $READELF -r conftest | grep -F __ehdr_start >/dev/null; then
1685 libc_cv_ehdr_start=broken
1686 else
1687 libc_cv_ehdr_start=yes
1688 fi], [libc_cv_ehdr_start=no])
1689 CFLAGS="$old_CFLAGS"
1690 LDFLAGS="$old_LDFLAGS"
1691 LIBS="$old_LIBS"
1692 ])
1693 if test "$libc_cv_ehdr_start" = yes; then
1694 AC_DEFINE([HAVE_EHDR_START])
1695 elif test "$libc_cv_ehdr_start" = broken; then
1696 AC_MSG_WARN([linker is broken -- you should upgrade])
1697 fi
1699 dnl Starting with binutils 2.35, GAS can attach multiple symbol versions
1700 dnl to one symbol (PR 23840).
1701 AC_CACHE_CHECK(whether the assembler requires one version per symbol,
1702 libc_cv_symver_needs_alias, [dnl
1703 cat > conftest.s <<EOF
1704 .text
1705 testfunc:
1706 .globl testfunc
1707 .symver testfunc, testfunc1@VERSION1
1708 .symver testfunc, testfunc1@VERSION2
1709 EOF
1710 libc_cv_symver_needs_alias=no
1711 if ${CC-cc} $ASFLAGS -c conftest.s 2>&AS_MESSAGE_LOG_FD; then
1712 libc_cv_symver_needs_alias=no
1713 else
1714 libc_cv_symver_needs_alias=yes
1715 fi
1716 rm conftest.*
1717 ])
1718 if test "$libc_cv_symver_needs_alias" = yes; then
1719 AC_DEFINE(SYMVER_NEEDS_ALIAS)
1720 fi
1722 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1723 libc_cv_builtin_trap, [dnl
1724 libc_cv_builtin_trap=no
1725 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[__builtin_trap ()]])],[
1726 libc_undefs=`$NM -u conftest.o |
1727 LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1728 2>&AS_MESSAGE_LOG_FD` || {
1729 AC_MSG_ERROR([confusing output from $NM -u])
1730 }
1731 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1732 if test -z "$libc_undefs"; then
1733 libc_cv_builtin_trap=yes
1734 fi],[])])
1735 if test $libc_cv_builtin_trap = yes; then
1736 AC_DEFINE([HAVE_BUILTIN_TRAP])
1737 fi
1739 dnl C++ feature tests.
1740 AC_LANG_PUSH([C++])
1742 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1743 libc_cv_cxx_thread_local, [
1744 old_CXXFLAGS="$CXXFLAGS"
1745 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1746 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1747 #include <thread>
1749 // Compiler support.
1750 struct S
1751 {
1752 S ();
1753 ~S ();
1754 };
1755 thread_local S s;
1756 S * get () { return &s; }
1758 // libstdc++ support.
1759 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1760 #error __cxa_thread_atexit_impl not supported
1761 #endif
1762 ])],
1763 [libc_cv_cxx_thread_local=yes],
1764 [libc_cv_cxx_thread_local=no])
1765 CXXFLAGS="$old_CXXFLAGS"
1766 ])
1767 AC_SUBST(libc_cv_cxx_thread_local)
1769 AC_LANG_POP([C++])
1770 dnl End of C++ feature tests.
1772 ### End of automated tests.
1773 ### Now run sysdeps configure fragments.
1775 # They also can set these variables.
1776 use_ldconfig=no
1777 ldd_rewrite_script=no
1778 libc_cv_sysconfdir=$sysconfdir
1779 libc_cv_localstatedir=$localstatedir
1780 libc_cv_gcc_unwind_find_fde=no
1781 libc_cv_idn=no
1782 pthread_in_libc=yes
1784 # Iterate over all the sysdep directories we will use, running their
1785 # configure fragments.
1786 for dir in $sysnames; do
1787 case $dir in
1788 /*) dest=$dir ;;
1789 *) dest=$srcdir/$dir ;;
1790 esac
1791 if test -r $dest/configure; then
1792 AC_MSG_RESULT(running configure fragment for $dir)
1793 . $dest/configure
1794 fi
1795 done
1797 if test x"$build_mathvec" = xnotset; then
1798 build_mathvec=no
1799 fi
1800 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1802 AC_SUBST(libc_extra_cflags)
1803 AC_SUBST(libc_extra_cppflags)
1805 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1806 AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1807 fi
1808 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1810 # A sysdeps configure fragment can reset this if IFUNC is not actually
1811 # usable even though the assembler knows how to generate the symbol type.
1812 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1813 AC_DEFINE(HAVE_IFUNC)
1814 fi
1815 LIBC_CONFIG_VAR([have-ifunc], [$libc_cv_ld_gnu_indirect_function])
1817 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1818 AC_DEFINE(HAVE_GCC_IFUNC)
1819 fi
1820 LIBC_CONFIG_VAR([have-gcc-ifunc], [$libc_cv_gcc_indirect_function])
1822 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1823 # configure fragment can override the value to prevent this AC_DEFINE.
1824 AC_SUBST(use_nscd)
1825 if test "x$use_nscd" != xno; then
1826 AC_DEFINE([USE_NSCD])
1827 fi
1828 if test "x$build_nscd" = xdefault; then
1829 build_nscd=$use_nscd
1830 fi
1832 AC_SUBST(libc_cv_slibdir)
1833 AC_SUBST(libc_cv_rtlddir)
1834 AC_SUBST(libc_cv_complocaledir)
1835 AC_SUBST(libc_cv_sysconfdir)
1836 AC_SUBST(libc_cv_localstatedir)
1837 AC_SUBST(libc_cv_rootsbindir)
1839 if test x$use_ldconfig = xyes; then
1840 AC_DEFINE(USE_LDCONFIG)
1841 fi
1842 AC_SUBST(use_ldconfig)
1843 AC_SUBST(ldd_rewrite_script)
1845 AC_SUBST(static)
1846 AC_SUBST(shared)
1848 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1849 [libc_cv_pic_default=yes
1850 cat > conftest.c <<EOF
1851 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1852 # error PIC is default.
1853 #endif
1854 EOF
1855 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1856 libc_cv_pic_default=no
1857 fi
1858 rm -f conftest.*])
1859 AC_SUBST(libc_cv_pic_default)
1861 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_cc_pie_default,
1862 [libc_cv_cc_pie_default=yes
1863 cat > conftest.c <<EOF
1864 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1865 # error PIE is default.
1866 #endif
1867 EOF
1868 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1869 libc_cv_cc_pie_default=no
1870 fi
1871 rm -f conftest.*])
1872 libc_cv_pie_default=$libc_cv_cc_pie_default
1873 AC_SUBST(libc_cv_cc_pie_default)
1874 AC_SUBST(libc_cv_pie_default)
1876 # Set the `multidir' variable by grabbing the variable from the compiler.
1877 # We do it once and save the result in a generated makefile.
1878 libc_cv_multidir=`${CC-cc} $CFLAGS $CPPFLAGS -print-multi-directory`
1879 AC_SUBST(libc_cv_multidir)
1881 if test "$static_pie" = yes; then
1882 # Check target support for static PIE
1883 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#ifndef SUPPORT_STATIC_PIE
1884 # error static PIE is not supported
1885 #endif]])], , AC_MSG_ERROR([the architecture does not support static PIE]))
1886 # The linker must support --no-dynamic-linker.
1887 if test "$libc_cv_no_dynamic_linker" != yes; then
1888 AC_MSG_ERROR([linker support for --no-dynamic-linker needed])
1889 fi
1890 # Default to PIE.
1891 libc_cv_pie_default=yes
1892 AC_DEFINE(ENABLE_STATIC_PIE)
1893 fi
1894 LIBC_CONFIG_VAR([enable-static-pie], [$static_pie])
1896 AC_SUBST(profile)
1897 AC_SUBST(static_nss)
1899 AC_SUBST(DEFINES)
1901 dnl See sysdeps/mach/configure.ac for this variable.
1902 AC_SUBST(mach_interface_list)
1904 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1905 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1906 AC_SUBST(VERSION)
1907 AC_SUBST(RELEASE)
1909 if test "$pthread_in_libc" = yes; then
1910 AC_DEFINE(PTHREAD_IN_LIBC)
1911 fi
1912 AC_SUBST(pthread_in_libc)
1914 AC_CONFIG_FILES([config.make Makefile])
1915 AC_CONFIG_COMMANDS([default],[[
1916 case $CONFIG_FILES in *config.make*)
1917 echo "$config_vars" >> config.make;;
1918 esac
1919 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1920 AC_OUTPUT