| blob | 5028e6411e4753e47f4ea5faae1134440f414f76 |
1 dnl Process this file with autoconf to produce a configure script.
2 AC_PREREQ(2.53)dnl dnl Minimum Autoconf version required.
3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
4 AC_CONFIG_SRCDIR([include/features.h])
5 AC_CONFIG_HEADERS([config.h])
6 AC_CONFIG_AUX_DIR([scripts])
8 # Glibc should not depend on any header files
9 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
10 [m4_divert_text([DEFAULTS],
11 [ac_includes_default='/* none */'])])
13 dnl This is here so we can set $subdirs directly based on configure fragments.
14 AC_CONFIG_SUBDIRS()
16 AC_CANONICAL_HOST
18 AC_PROG_CC
19 if test $host != $build; then
20 AC_CHECK_PROGS(BUILD_CC, gcc cc)
21 fi
22 AC_SUBST(cross_compiling)
23 AC_PROG_CPP
24 # We need the C++ compiler only for testing.
25 AC_PROG_CXX
27 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
28 AC_MSG_ERROR([you must configure in a separate build directory])
29 fi
31 # This will get text that should go into config.make.
32 config_vars=
34 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
35 AC_ARG_WITH([gd],
36 AC_HELP_STRING([--with-gd=DIR],
37 [find libgd include dir and library with prefix DIR]),
38 [dnl
39 case "$with_gd" in
40 yes|''|no) ;;
41 *) libgd_include="-I$withval/include"
42 libgd_ldflags="-L$withval/lib" ;;
43 esac
44 ])
45 AC_ARG_WITH([gd-include],
46 AC_HELP_STRING([--with-gd-include=DIR],
47 [find libgd include files in DIR]),
48 [dnl
49 case "$with_gd_include" in
50 ''|no) ;;
51 *) libgd_include="-I$withval" ;;
52 esac
53 ])
54 AC_ARG_WITH([gd-lib],
55 AC_HELP_STRING([--with-gd-lib=DIR],
56 [find libgd library files in DIR]),
57 [dnl
58 case "$with_gd_lib" in
59 ''|no) ;;
60 *) libgd_ldflags="-L$withval" ;;
61 esac
62 ])
64 if test -n "$libgd_include"; then
65 config_vars="$config_vars
66 CFLAGS-memusagestat.c = $libgd_include"
67 fi
68 if test -n "$libgd_ldflags"; then
69 config_vars="$config_vars
70 libgd-LDFLAGS = $libgd_ldflags"
71 fi
73 dnl Arguments to specify presence of other packages/features.
74 AC_ARG_WITH([fp],
75 AC_HELP_STRING([--with-fp],
76 [if using floating-point hardware @<:@default=yes@:>@]),
77 [with_fp=$withval],
78 [with_fp=yes])
79 AC_SUBST(with_fp)
80 AC_ARG_WITH([binutils],
81 AC_HELP_STRING([--with-binutils=PATH],
82 [specify location of binutils (as and ld)]),
83 [path_binutils=$withval],
84 [path_binutils=''])
85 AC_ARG_WITH([selinux],
86 AC_HELP_STRING([--with-selinux],
87 [if building with SELinux support]),
88 [with_selinux=$withval],
89 [with_selinux=auto])
91 AC_ARG_WITH([headers],
92 AC_HELP_STRING([--with-headers=PATH],
93 [location of system headers to use
94 (for example /usr/src/linux/include)
95 @<:@default=compiler default@:>@]),
96 [sysheaders=$withval],
97 [sysheaders=''])
99 AC_SUBST(use_default_link)
100 AC_ARG_WITH([default-link],
101 AC_HELP_STRING([--with-default-link],
102 [do not use explicit linker scripts]),
103 [use_default_link=$withval],
104 [use_default_link=default])
106 AC_ARG_ENABLE([sanity-checks],
107 AC_HELP_STRING([--disable-sanity-checks],
108 [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
109 [enable_sanity=$enableval],
110 [enable_sanity=yes])
112 AC_ARG_ENABLE([shared],
113 AC_HELP_STRING([--enable-shared],
114 [build shared library @<:@default=yes if GNU ld@:>@]),
115 [shared=$enableval],
116 [shared=yes])
117 AC_ARG_ENABLE([profile],
118 AC_HELP_STRING([--enable-profile],
119 [build profiled library @<:@default=no@:>@]),
120 [profile=$enableval],
121 [profile=no])
122 AC_ARG_ENABLE([versioning],
123 AC_HELP_STRING([--disable-versioning],
124 [do not include versioning information in the library objects @<:@default=yes if supported@:>@]),
125 [enable_versioning=$enableval],
126 [enable_versioning=yes])
128 AC_ARG_ENABLE([oldest-abi],
129 AC_HELP_STRING([--enable-oldest-abi=ABI],
130 [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
131 [oldest_abi=$enableval],
132 [oldest_abi=no])
133 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
134 oldest_abi=default
135 else
136 AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
137 fi
138 AC_SUBST(oldest_abi)
140 AC_ARG_ENABLE([stackguard-randomization],
141 AC_HELP_STRING([--enable-stackguard-randomization],
142 [initialize __stack_chk_guard canary with a random number at program start]),
143 [enable_stackguard_randomize=$enableval],
144 [enable_stackguard_randomize=no])
145 if test "$enable_stackguard_randomize" = yes; then
146 AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
147 fi
149 dnl Generic infrastructure for drop-in additions to libc.
150 AC_ARG_ENABLE([add-ons],
151 AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
152 [configure and build add-ons in DIR1,DIR2,...
153 search for add-ons if no parameter given]),
154 , [enable_add_ons=yes])
156 AC_ARG_ENABLE([hidden-plt],
157 AC_HELP_STRING([--disable-hidden-plt],
158 [do not hide internal function calls to avoid PLT]),
159 [hidden=$enableval],
160 [hidden=yes])
161 if test "x$hidden" = xno; then
162 AC_DEFINE(NO_HIDDEN)
163 fi
165 AC_ARG_ENABLE([bind-now],
166 AC_HELP_STRING([--enable-bind-now],
167 [disable lazy relocations in DSOs]),
168 [bindnow=$enableval],
169 [bindnow=no])
170 AC_SUBST(bindnow)
172 dnl On some platforms we cannot use dynamic loading. We must provide
173 dnl static NSS modules.
174 AC_ARG_ENABLE([static-nss],
175 AC_HELP_STRING([--enable-static-nss],
176 [build static NSS modules @<:@default=no@:>@]),
177 [static_nss=$enableval],
178 [static_nss=no])
179 dnl Enable static NSS also if we build no shared objects.
180 if test x"$static_nss" = xyes || test x"$shared" = xno; then
181 static_nss=yes
182 AC_DEFINE(DO_STATIC_NSS)
183 fi
185 AC_ARG_ENABLE([force-install],
186 AC_HELP_STRING([--disable-force-install],
187 [don't force installation of files from this package, even if they are older than the installed files]),
188 [force_install=$enableval],
189 [force_install=yes])
190 AC_SUBST(force_install)
192 dnl On some platforms we allow dropping compatibility with all kernel
193 dnl versions.
194 AC_ARG_ENABLE([kernel],
195 AC_HELP_STRING([--enable-kernel=VERSION],
196 [compile for compatibility with kernel not older than VERSION]),
197 [minimum_kernel=$enableval],
198 [])
199 dnl Prevent unreasonable values.
200 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
201 # Better nothing than this.
202 minimum_kernel=""
203 else
204 if test "$minimum_kernel" = current; then
205 minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
206 fi
207 fi
209 dnl For the development we sometimes want gcc to issue even more warnings.
210 dnl This is not the default since many of the extra warnings are not
211 dnl appropriate.
212 AC_ARG_ENABLE([all-warnings],
213 AC_HELP_STRING([--enable-all-warnings],
214 [enable all useful warnings gcc can issue]),
215 [all_warnings=$enableval],
216 [])
217 AC_SUBST(all_warnings)
219 AC_ARG_ENABLE([multi-arch],
220 AC_HELP_STRING([--enable-multi-arch],
221 [enable single DSO with optimizations for multiple architectures]),
222 [multi_arch=$enableval],
223 [multi_arch=default])
225 AC_ARG_ENABLE([nss-crypt],
226 AC_HELP_STRING([--enable-nss-crypt],
227 [enable libcrypt to use nss]),
228 [nss_crypt=$enableval],
229 [nss_crypt=no])
230 if test x$nss_crypt = xyes; then
231 nss_includes=-I$(nss-config --includedir 2>/dev/null)
232 if test $? -ne 0; then
233 AC_MSG_ERROR([cannot find include directory with nss-config])
234 fi
235 old_CFLAGS="$CFLAGS"
236 CFLAGS="$CFLAGS $nss_includes"
237 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
238 #include <hasht.h>
239 #include <nsslowhash.h>
240 void f (void) { NSSLOW_Init (); }])],
241 libc_cv_nss_crypt=yes,
242 AC_MSG_ERROR([
243 cannot find NSS headers with lowlevel hash function interfaces]))
244 old_LIBS="$LIBS"
245 LIBS="$LIBS -lfreebl3"
246 AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
247 #include <hasht.h>
248 #include <nsslowhash.h>],
249 [NSSLOW_Init();])],
250 libc_cv_nss_crypt=yes,
251 AC_MSG_ERROR([
252 cannot link program using lowlevel NSS hash functions]))
253 CFLAGS="$old_CFLAGS"
254 LIBS="$old_LIBS"
255 else
256 libc_cv_nss_crypt=no
257 fi
258 AC_SUBST(libc_cv_nss_crypt)
261 AC_ARG_ENABLE([obsolete-rpc],
262 AC_HELP_STRING([--enable-obsolete-rpc],
263 [build and install the obsolete RPC code for link-time usage]),
264 [link_obsolete_rpc=$enableval],
265 [link_obsolete_rpc=no])
266 AC_SUBST(link_obsolete_rpc)
268 if test "$link_obsolete_rpc" = yes; then
269 AC_DEFINE(LINK_OBSOLETE_RPC)
270 fi
272 AC_ARG_ENABLE([systemtap],
273 [AS_HELP_STRING([--enable-systemtap],
274 [enable systemtap static probe points @<:@default=no@:>@])],
275 [systemtap=$enableval],
276 [systemtap=no])
277 if test "x$systemtap" != xno; then
278 AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
279 old_CFLAGS="$CFLAGS"
280 CFLAGS="-std=gnu99 $CFLAGS"
281 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
282 void foo (int i, void *p)
283 {
284 asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
285 :: STAP_PROBE_ASM_OPERANDS (2, i, p));
286 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
287 CFLAGS="$old_CFLAGS"])
288 if test $libc_cv_sdt = yes; then
289 AC_DEFINE([USE_STAP_PROBE])
290 elif test "x$systemtap" != xauto; then
291 AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
292 fi
293 fi
295 # The way shlib-versions is used to generate soversions.mk uses a
296 # fairly simplistic model for name recognition that can't distinguish
297 # i486-pc-linux-gnu fully from i486-pc-gnu. So we mutate a $host_os
298 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
299 # tell. This doesn't get used much beyond that, so it's fairly safe.
300 case "$host_os" in
301 linux*)
302 ;;
303 gnu*)
304 host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
305 ;;
306 esac
308 # We keep the original values in `$config_*' and never modify them, so we
309 # can write them unchanged into config.make. Everything else uses
310 # $machine, $vendor, and $os, and changes them whenever convenient.
311 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
313 # Don't allow vendor == "unknown"
314 test "$config_vendor" = unknown && config_vendor=
315 config_os="`echo $config_os | sed 's/^unknown-//'`"
317 # Some configurations imply other options.
318 elf=yes
320 # The configure fragment of an add-on port can modify these to supplement
321 # or override the table in the case statement below. No fragment should
322 # ever change the config_* variables, however.
323 machine=$config_machine
324 vendor=$config_vendor
325 os=$config_os
326 base_os=''
328 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
329 # Unify this here.
330 if test "$machine" = rs6000; then
331 machine="powerpc"
332 fi
334 # Braindead PowerPC box with absolutely no FPU.
335 case "$machine-$host_os" in
336 powerpc*-*soft)
337 with_fp=no
338 ;;
339 esac
341 submachine=
342 AC_ARG_WITH([cpu],
343 AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
344 [dnl
345 case "$withval" in
346 yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
347 no) ;;
348 *) submachine="$withval" ;;
349 esac
350 ])
352 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
353 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
355 # An add-on can set this when it wants to disable the sanity check below.
356 libc_config_ok=no
358 dnl Having this here, though empty, makes sure that if add-ons' fragments
359 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
360 dnl our AC_OUTPUT will actually use it.
361 AC_CONFIG_SUBDIRS()
363 case "$enable_add_ons" in
364 ''|no) add_ons= ;;
365 yes|'*')
366 add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
367 sed 's@/[[^/]]*$@@' | sort | uniq`
368 add_ons_automatic=yes
369 ;;
370 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
371 add_ons_automatic=no ;;
372 esac
374 configured_add_ons=
375 add_ons_sfx=
376 add_ons_pfx=
377 if test x"$add_ons" != x; then
378 for f in $add_ons; do
379 # Some sanity checks
380 case "$f" in
381 crypt)
382 AC_MSG_ERROR([
383 *** It seems that you're using an old \`crypt' add-on. crypt is now
384 *** part of glibc and using the old add-on will not work with this
385 *** release. Start again with fresh sources and without the old
386 *** \`crypt' add-on.])
387 ;;
388 localedata)
389 AC_MSG_ERROR([
390 *** It seems that you're using an old \`localedata' add-on. localedata
391 *** is now part of glibc and using the old add-on will not work with
392 *** this release. Start again with fresh sources and without the old
393 *** \`localedata' add-on.])
394 ;;
395 esac
396 done
398 # Now source each add-on's configure fragment.
399 # The fragments can use $srcdir/$libc_add_on to find themselves,
400 # and test $add_ons_automatic to see if they were explicitly requested.
401 # A fragment can clear (or even change) $libc_add_on to affect
402 # whether it goes into the list to be actually used in the build.
403 use_add_ons=
404 for libc_add_on in $add_ons; do
405 # Test whether such a directory really exists.
406 # It can be absolute, or relative to $srcdir, or relative to the build dir.
407 case "$libc_add_on" in
408 /*)
409 libc_add_on_srcdir=$libc_add_on
410 ;;
411 *)
412 test -d "$srcdir/$libc_add_on" || {
413 if test -d "$libc_add_on"; then
414 libc_add_on="`pwd`/$libc_add_on"
415 else
416 AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
417 fi
418 }
419 libc_add_on_srcdir=$srcdir/$libc_add_on
420 ;;
421 esac
423 libc_add_on_frag=$libc_add_on_srcdir/configure
424 libc_add_on_canonical=
425 libc_add_on_config_subdirs=
426 if test -r "$libc_add_on_frag"; then
427 AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
428 libc_add_on_canonical=unknown
429 libc_add_on_subdirs=
430 . "$libc_add_on_frag"
431 test -z "$libc_add_on" || {
432 configured_add_ons="$configured_add_ons $libc_add_on"
433 if test "x$libc_add_on_canonical" = xunknown; then
434 AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
435 fi
436 for d in $libc_add_on_subdirs; do
437 case "$libc_add_on" in
438 /*) subdir_srcdir="$libc_add_on" ;;
439 *) subdir_srcdir="\$(..)$libc_add_on" ;;
440 esac
441 case "$d" in
442 .)
443 d="${libc_add_on_canonical:-$libc_add_on}"
444 ;;
445 /*)
446 subdir_srcdir="$d"
447 ;;
448 *)
449 subdir_srcdir="$subdir_srcdir/$d"
450 ;;
451 esac
452 d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
453 add_on_subdirs="$add_on_subdirs $d"
454 test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
455 $d-srcdir = $subdir_srcdir"
456 done
457 for d in $libc_add_on_config_subdirs; do
458 case "$d" in
459 /*) AC_MSG_ERROR(dnl
460 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
461 esac
462 if test ! -d "$libc_add_on_srcdir/$d"; then
463 AC_MSG_ERROR(fragment wants to configure missing directory $d)
464 fi
465 case "$libc_add_on" in
466 /*) AC_MSG_ERROR(dnl
467 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
468 esac
469 subdirs="$subdirs $libc_add_on/$d"
470 done
471 }
472 fi
473 if test -n "$libc_add_on"; then
474 LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
475 use_add_ons="$use_add_ons $libc_add_on"
476 add_ons_pfx="$add_ons_pfx $libc_add_on/"
477 test -z "$libc_add_on_canonical" ||
478 add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
479 fi
480 done
481 # Use echo to strip excess whitespace.
482 add_ons="`echo $use_add_ons`"
483 fi
484 AC_SUBST(add_ons)
485 AC_SUBST(add_on_subdirs)
488 ###
489 ### I put this here to prevent those annoying emails from people who cannot
490 ### read and try to compile glibc on unsupported platforms. --drepper
491 ###
492 ### By using the undocumented --enable-hacker-mode option for configure
493 ### one can skip this test to make the configuration not fail for unsupported
494 ### platforms.
495 ###
496 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
497 case "$machine-$host_os" in
498 *-linux* | *-gnu*)
499 ;;
500 *)
501 echo "*** The GNU C library is currently not available for this platform."
502 echo "*** So far nobody cared to port it and if there is no volunteer it"
503 echo "*** might never happen. So, if you have interest to see glibc on"
504 echo "*** this platform visit"
505 echo "*** http://www.gnu.org/software/libc/porting.html"
506 echo "*** and join the group of porters"
507 exit 1
508 ;;
509 esac
510 fi
512 dnl We need to use [ and ] for other purposes for a while now.
513 changequote(,)dnl
514 # Expand the configuration machine name into a subdirectory by architecture
515 # type and particular chip. If an add-on configure fragment already set
516 # base_machine, we don't change it.
517 test -n "$base_machine" || case "$machine" in
518 i[34567]86) base_machine=i386 machine=i386/$machine ;;
519 powerpc) base_machine=powerpc machine=powerpc/powerpc32 ;;
520 powerpc64) base_machine=powerpc machine=powerpc/powerpc64 ;;
521 s390) base_machine=s390 machine=s390/s390-32 ;;
522 s390x) base_machine=s390 machine=s390/s390-64 ;;
523 sh3*) base_machine=sh machine=sh/sh3 ;;
524 sh4*) base_machine=sh machine=sh/sh4 ;;
525 sparc | sparcv[67])
526 base_machine=sparc machine=sparc/sparc32 ;;
527 sparcv8 | supersparc | hypersparc)
528 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
529 sparcv8plus | sparcv8plusa | sparcv9)
530 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
531 sparcv8plusb | sparcv9b)
532 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
533 sparcv9v)
534 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
535 sparcv9v2)
536 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
537 sparc64)
538 base_machine=sparc machine=sparc/sparc64 ;;
539 sparc64b)
540 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
541 sparc64v)
542 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
543 sparc64v2)
544 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
545 *) base_machine=$machine ;;
546 esac
547 changequote([,])dnl
548 AC_SUBST(base_machine)
550 if test "$base_machine" = "i386"; then
551 AC_DEFINE(USE_REGPARMS)
552 fi
554 # For the multi-arch option we need support in the assembler.
555 AC_CACHE_CHECK([for assembler gnu_indirect_function symbol type support],
556 libc_cv_asm_gnu_indirect_function, [dnl
557 cat > conftest.s <<EOF
558 .type foo,%gnu_indirect_function
559 EOF
560 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD;
561 then
562 libc_cv_asm_gnu_indirect_function=yes
563 else
564 libc_cv_asm_gnu_indirect_function=no
565 fi
566 rm -f conftest*])
568 AC_MSG_CHECKING(whether .text pseudo-op must be used)
569 AC_CACHE_VAL(libc_cv_dot_text, [dnl
570 cat > conftest.s <<EOF
571 .text
572 EOF
573 libc_cv_dot_text=
574 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
575 libc_cv_dot_text=.text
576 fi
577 rm -f conftest*])
578 if test -z "$libc_cv_dot_text"; then
579 AC_MSG_RESULT(no)
580 else
581 AC_MSG_RESULT(yes)
582 fi
584 AC_CACHE_CHECK(for assembler global-symbol directive,
585 libc_cv_asm_global_directive, [dnl
586 libc_cv_asm_global_directive=UNKNOWN
587 for ac_globl in .globl .global .EXPORT; do
588 cat > conftest.s <<EOF
589 ${libc_cv_dot_text}
590 ${ac_globl} foo
591 foo:
592 EOF
593 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
594 libc_cv_asm_global_directive=${ac_globl}
595 fi
596 rm -f conftest*
597 test $libc_cv_asm_global_directive != UNKNOWN && break
598 done])
599 if test $libc_cv_asm_global_directive = UNKNOWN; then
600 AC_MSG_ERROR(cannot determine asm global directive)
601 else
602 AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
603 fi
605 AC_CACHE_CHECK(for assembler .type directive prefix,
606 libc_cv_asm_type_prefix, [dnl
607 libc_cv_asm_type_prefix=no
608 for ac_try_prefix in '@' '%' '#'; do
609 cat > conftest.s <<EOF
610 ${libc_cv_dot_text}
611 ${libc_cv_asm_global_directive} foo
612 .type foo, ${ac_try_prefix}object
613 .size foo, 1
614 foo:
615 .byte 1
616 EOF
617 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
618 libc_cv_asm_type_prefix=${ac_try_prefix}
619 fi
620 rm -f conftest*
621 test "x$libc_cv_asm_type_prefix" != xno && break
622 done])
623 if test "x$libc_cv_asm_type_prefix" != xno; then
624 AC_DEFINE_UNQUOTED(ASM_TYPE_DIRECTIVE_PREFIX, ${libc_cv_asm_type_prefix})
625 fi
627 if test x"$libc_cv_asm_gnu_indirect_function" != xyes -o x"$libc_cv_asm_type_prefix" = xno; then
628 if test x"$multi_arch" = xyes; then
629 AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
630 else
631 multi_arch=no
632 fi
633 fi
634 if test x"$multi_arch" != xno; then
635 multi_arch_d=/multiarch
636 fi
638 # Compute the list of sysdep directories for this configuration.
639 # This can take a while to compute.
640 sysdep_dir=$srcdir/sysdeps
641 AC_MSG_CHECKING(sysdep dirs)
642 dnl We need to use [ and ] for other purposes for a while now.
643 changequote(,)dnl
644 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
645 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
647 test "x$base_os" != x || case "$os" in
648 gnu*)
649 base_os=mach/hurd ;;
650 linux*)
651 base_os=unix/sysv ;;
652 esac
654 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
655 tail=$os
656 ostry=$os
657 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
658 ostry="$ostry /$o"
659 tail=$o
660 done
661 o=`echo $tail | sed 's/[0-9]*$//'`
662 if test $o != $tail; then
663 ostry="$ostry /$o"
664 fi
665 # For linux-gnu, try linux-gnu, then linux.
666 o=`echo $tail | sed 's/-.*$//'`
667 if test $o != $tail; then
668 ostry="$ostry /$o"
669 fi
671 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
672 base=
673 tail=$base_os
674 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
675 set $b
676 base="$base /$1"
677 tail="$2"
678 done
680 # For sparc/sparc32, try sparc/sparc32 and then sparc.
681 mach=
682 tail=$machine${submachine:+/$submachine}
683 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
684 set $m
685 # Prepend the machine's FPU directory unless --without-fp.
686 if test "$with_fp" = yes; then
687 mach="$mach /$1/fpu"
688 else
689 mach="$mach /$1/nofpu"
690 fi
691 mach="$mach /$1"
692 tail="$2"
693 done
695 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
696 changequote([,])dnl
698 # Find what sysdep directories exist.
699 sysnames_add_ons=
700 sysnames=
701 for b in $base ''; do
702 for m0 in $mach ''; do
703 for v in /$vendor ''; do
704 test "$v" = / && continue
705 for o in /$ostry ''; do
706 test "$o" = / && continue
707 for m in $multi_arch_d $mach ''; do
708 for d in $add_ons_pfx ''; do
709 for a in $add_ons_sfx ''; do
710 if test -n "$m0$m0sub$b$v$o$m$msub"; then
711 try_srcdir="${srcdir}/"
712 case "$d" in
713 /*) try_srcdir= ;;
714 esac
715 try="${d}sysdeps$m0$m0sub$b$v$o$m$msub$a"
716 test -n "$enable_debug_configure" &&
717 echo "$0 [DEBUG]: try $try" >&2
718 if test -d "$try_srcdir$try"; then
719 sysnames="$sysnames $try"
720 { test -n "$o" || test -n "$b"; } && os_used=t
721 { test -n "$m" || test -n "$m0"; } && machine_used=t
722 case x${m0:-$m} in
723 x*/$submachine) submachine_used=t ;;
724 esac
725 if test -n "$d"; then
726 case "$sysnames_add_ons" in
727 *" $d "*) ;;
728 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
729 esac
730 fi
731 fi
732 fi
733 done
734 done
735 done
736 done
737 done
738 done
739 done
741 # If the assembler supports gnu_indirect_function symbol type and the
742 # architecture supports multi-arch, we enable multi-arch by default.
743 case $sysnames_add_ons$sysnames in
744 *"$multi_arch_d"*)
745 ;;
746 *)
747 test x"$multi_arch" = xdefault && multi_arch=no
748 ;;
749 esac
750 if test x"$multi_arch" != xno; then
751 AC_DEFINE(USE_MULTIARCH)
752 fi
753 AC_SUBST(multi_arch)
755 if test -z "$os_used" && test "$os" != none; then
756 AC_MSG_ERROR(Operating system $os is not supported.)
757 fi
758 if test -z "$machine_used" && test "$machine" != none; then
759 AC_MSG_ERROR(The $machine is not supported.)
760 fi
761 if test -z "$submachine_used" && test -n "$submachine"; then
762 AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
763 fi
764 AC_SUBST(submachine)
766 # We have now validated the configuration.
768 # Expand the list of system names into a full list of directories
769 # from each element's parent name and Implies file (if present).
770 set $sysnames
771 names=
772 while test $# -gt 0; do
773 name=$1
774 shift
776 case " $names " in *" $name "*)
777 # Already in the list.
778 continue
779 esac
781 # Report each name as we discover it, so there is no long pause in output.
782 echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
784 name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
786 case $name in
787 /*) xsrcdir= ;;
788 *) xsrcdir=$srcdir/ ;;
789 esac
790 test -n "$enable_debug_configure" &&
791 echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
793 for implies_file in Implies Implies-before Implies-after; do
794 implies_type=`echo $implies_file | sed s/-/_/`
795 eval ${implies_type}=
796 if test -f $xsrcdir$name/$implies_file; then
797 # Collect more names from the `Implies' file (removing comments).
798 implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
799 for x in $implied_candidate; do
800 found=no
801 if test -d $xsrcdir$name_base/$x; then
802 eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
803 found=yes
804 fi
805 for d in $add_ons_pfx ''; do
806 try="${d}sysdeps/$x"
807 case $d in
808 /*) try_srcdir= ;;
809 *) try_srcdir=$srcdir/ ;;
810 esac
811 test -n "$enable_debug_configure" &&
812 echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
813 if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
814 then
815 eval "${implies_type}=\"\$${implies_type} \$try\""
816 found=yes
817 case "$sysnames_add_ons" in
818 *" $d "*) ;;
819 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
820 esac
821 fi
822 done
823 if test $found = no; then
824 AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
825 fi
826 done
827 fi
828 done
830 # Add NAME to the list of names.
831 names="$names $name"
833 # Find the parent of NAME, using the empty string if it has none.
834 changequote(,)dnl
835 parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
836 changequote([,])dnl
838 test -n "$enable_debug_configure" &&
839 echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
840 Implies_before='$Implies_after' Implies_after='$Implies_after'" >&2
842 # Add the names implied by NAME, and NAME's parent (if it has one), to
843 # the list of names to be processed (the argument list). We prepend the
844 # implied names to the list and append the parent. We want implied
845 # directories to come before further directories inferred from the
846 # configuration components; this ensures that for sysv4, unix/common
847 # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
848 # after sysv4).
849 sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
850 test -n "$sysnames" && set $sysnames
851 done
853 # Add the default directories.
854 default_sysnames="sysdeps/generic"
855 sysnames="$names $default_sysnames"
856 AC_SUBST(sysnames)
857 # The other names were emitted during the scan.
858 AC_MSG_RESULT($default_sysnames)
860 # Collect the list of add-ons that supply partial sysdeps trees.
861 sysdeps_add_ons=
862 for add_on in $add_ons; do
863 case "$add_on" in
864 /*) xsrcdir= ;;
865 *) xsrcdir="$srcdir/" ;;
866 esac
868 test -d "$xsrcdir$add_on/sysdeps" || {
869 case "$configured_add_ons " in
870 *" $add_on "*) ;;
871 *|'')
872 AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
873 ;;
874 esac
875 continue
876 }
878 sysdeps_add_ons="$sysdeps_add_ons $add_on"
879 case "$sysnames_add_ons" in
880 *" $add_on/ "*) ;;
881 *|'')
882 AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
883 continue ;;
884 esac
886 found=no
887 for d in $sysnames; do
888 case "$d" in
889 $add_on/sysdeps/*) ;;
890 *) continue ;;
891 esac
892 (cd "$xsrcdir$d" && for f in *[[!~]]; do
893 case "$f" in
894 sys|bits)
895 for ff in $f/*.h; do
896 test -d "$ff" || { test -e "$ff" && exit 88; }
897 done
898 ;;
899 *)
900 test -d "$f" || { test -e "$f" && exit 88; }
901 ;;
902 esac
903 done)
904 if test $? -eq 88; then
905 found=yes
906 break
907 fi
908 done
909 if test $found = no; then
910 AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
911 fi
912 done
913 AC_SUBST(sysdeps_add_ons)
916 ### Locate tools.
918 AC_PROG_INSTALL
919 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
920 # The makefiles need to use a different form to find it in $srcdir.
921 INSTALL='\$(..)./scripts/install-sh -c'
922 fi
923 AC_PROG_LN_S
925 LIBC_PROG_BINUTILS
926 AC_SUBST(MIG)dnl Needed by sysdeps/mach/configure.in
928 # Accept binutils 2.20 or newer.
929 AC_CHECK_PROG_VER(AS, $AS, --version,
930 [GNU assembler.* \([0-9]*\.[0-9.]*\)],
931 [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
932 AC_CHECK_PROG_VER(LD, $LD, --version,
933 [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
934 [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
936 # These programs are version sensitive.
937 AC_CHECK_TOOL_PREFIX
938 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
939 [version \([egcygnustpi-]*[0-9.]*\)], [4.[3-9].* | 4.[1-9][0-9].* | [5-9].* ],
940 critic_missing="$critic_missing gcc")
941 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
942 [GNU Make[^0-9]*\([0-9][0-9.]*\)],
943 [3.79* | 3.[89]*], critic_missing="$critic_missing make")
945 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
946 [GNU gettext.* \([0-9]*\.[0-9.]*\)],
947 [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
948 MSGFMT=: aux_missing="$aux_missing msgfmt")
949 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
950 [GNU texinfo.* \([0-9][0-9.]*\)],
951 [4.[5-9]*|4.[1-9][0-9]*|[5-9].*],
952 MAKEINFO=: aux_missing="$aux_missing makeinfo")
953 AC_CHECK_PROG_VER(SED, sed, --version,
954 [GNU sed version \([0-9]*\.[0-9.]*\)],
955 [3.0[2-9]*|3.[1-9]*|[4-9]*],
956 SED=: aux_missing="$aux_missing sed")
958 AC_CHECK_TOOL(READELF, readelf, false)
959 AC_CHECK_TOOL(NM, nm, false)
961 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
962 case "x$AUTOCONF" in
963 xno|x|x:) AUTOCONF=no ;;
964 *)
965 AC_CACHE_CHECK(dnl
966 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
967 if (cd $srcdir; $AUTOCONF $ACFLAGS configure.in > /dev/null 2>&1); then
968 libc_cv_autoconf_works=yes
969 else
970 libc_cv_autoconf_works=no
971 fi])
972 test $libc_cv_autoconf_works = yes || AUTOCONF=no
973 ;;
974 esac
975 if test "x$AUTOCONF" = xno; then
976 aux_missing="$aux_missing autoconf"
977 fi
979 test -n "$critic_missing" && AC_MSG_ERROR([
980 *** These critical programs are missing or too old:$critic_missing
981 *** Check the INSTALL file for required versions.])
983 test -n "$aux_missing" && AC_MSG_WARN([
984 *** These auxiliary programs are missing or incompatible versions:$aux_missing
985 *** some features will be disabled.
986 *** Check the INSTALL file for required versions.])
988 # if using special system headers, find out the compiler's sekrit
989 # header directory and add that to the list. NOTE: Only does the right
990 # thing on a system that doesn't need fixincludes. (Not presently a problem.)
991 if test -n "$sysheaders"; then
992 SYSINCLUDES=-nostdinc
993 for d in include include-fixed; do
994 i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
995 SYSINCLUDES="$SYSINCLUDES -isystem $i"
996 done
997 SYSINCLUDES="$SYSINCLUDES \
998 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
999 if test -n "$CXX"; then
1000 CXX_SYSINCLUDES=
1001 cxxversion=`$CXX -dumpversion 2>&AS_MESSAGE_LOG_FD` &&
1002 cxxmachine=`$CXX -dumpmachine 2>&AS_MESSAGE_LOG_FD` &&
1003 for d in include "$cxxmachine/include"; do
1004 i=../../../../$d/c++/$cxxversion
1005 cxxheaders=`$CXX -print-file-name="$i"` &&
1006 test "x$cxxheaders" != x && test "x$i" != "x$cxxheaders" &&
1007 CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders \
1008 -isystem $cxxheaders/$cxxmachine -isystem $cxxheaders/backward"
1009 done
1010 fi
1011 fi
1012 AC_SUBST(SYSINCLUDES)
1013 AC_SUBST(CXX_SYSINCLUDES)
1015 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1016 # since this would lead to problems installing/building glibc.
1017 # LD_LIBRARY_PATH contains the current directory if one of the following
1018 # is true:
1019 # - one of the terminals (":" and ";") is the first or last sign
1020 # - two terminals occur directly after each other
1021 # - the path contains an element with a dot in it
1022 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1023 changequote(,)dnl
1024 case ${LD_LIBRARY_PATH} in
1025 [:\;]* | *[:\;] | *[:\;][:\;]* | *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1026 ld_library_path_setting="contains current directory"
1027 ;;
1028 *)
1029 ld_library_path_setting="ok"
1030 ;;
1031 esac
1032 changequote([,])dnl
1033 AC_MSG_RESULT($ld_library_path_setting)
1034 if test "$ld_library_path_setting" != "ok"; then
1035 AC_MSG_ERROR([
1036 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1037 *** building glibc. Please change the environment variable
1038 *** and run configure again.])
1039 fi
1041 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1042 if $CC -v -static-libgcc 2>&1 | grep -q 'unrecognized option.*static-libgcc'; then
1043 libc_cv_gcc_static_libgcc=
1044 else
1045 libc_cv_gcc_static_libgcc=-static-libgcc
1046 fi])
1047 AC_SUBST(libc_cv_gcc_static_libgcc)
1049 AC_PATH_PROG(BASH_SHELL, bash, no)
1050 if test "$BASH_SHELL" != no &&
1051 $BASH_SHELL -c 'test "$BASH_VERSINFO" \
1052 && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
1053 libc_cv_have_bash2=yes
1054 else
1055 libc_cv_have_bash2=no
1056 fi
1057 AC_SUBST(libc_cv_have_bash2)
1059 dnl We need a ksh compatible shell for tzselect.
1060 if test "$BASH_SHELL" = no; then
1061 AC_PATH_PROG(KSH, ksh, no)
1062 if test "$KSH" = no; then
1063 libc_cv_have_ksh=no
1064 else
1065 libc_cv_have_ksh=yes
1066 fi
1067 else
1068 KSH="$BASH_SHELL"
1069 AC_SUBST(KSH)
1070 libc_cv_have_ksh=yes
1071 fi
1072 AC_SUBST(libc_cv_have_ksh)
1074 AC_PROG_AWK
1075 AC_PATH_PROG(PERL, perl, no)
1076 if test "$PERL" != no &&
1077 (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1078 PERL=no
1079 fi
1080 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1081 $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1082 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1084 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1085 AC_TRY_COMPILE(dnl
1086 [#define __need_size_t
1087 #define __need_wchar_t
1088 #include <stddef.h>
1089 #define __need_NULL
1090 #include <stddef.h>], [size_t size; wchar_t wchar;
1091 #ifdef offsetof
1092 #error stddef.h ignored __need_*
1093 #endif
1094 if (&size == NULL || &wchar == NULL) abort ();],
1095 libc_cv_friendly_stddef=yes,
1096 libc_cv_friendly_stddef=no)])
1097 if test $libc_cv_friendly_stddef = yes; then
1098 config_vars="$config_vars
1099 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1100 fi
1102 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1103 libc_cv_need_minus_P, [dnl
1104 cat > conftest.S <<EOF
1105 #include "confdefs.h"
1106 /* Nothing whatsoever. */
1107 EOF
1108 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1109 libc_cv_need_minus_P=no
1110 else
1111 libc_cv_need_minus_P=yes
1112 fi
1113 rm -f conftest*])
1114 if test $libc_cv_need_minus_P = yes; then
1115 config_vars="$config_vars
1116 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1117 fi
1119 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1120 cat > conftest.s <<EOF
1121 ${libc_cv_dot_text}
1122 foo:
1123 .set glibc_conftest_frobozz,foo
1124 $libc_cv_asm_global_directive glibc_conftest_frobozz
1125 EOF
1126 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1127 # (but it doesn't work), so we must do a linking check to be sure.
1128 cat > conftest1.c <<\EOF
1129 extern int glibc_conftest_frobozz;
1130 void _start() { glibc_conftest_frobozz = 1; }
1131 EOF
1132 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1133 -nostartfiles -nostdlib \
1134 -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1135 libc_cv_asm_set_directive=yes
1136 else
1137 libc_cv_asm_set_directive=no
1138 fi
1139 rm -f conftest*])
1140 if test $libc_cv_asm_set_directive = yes; then
1141 AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1142 fi
1144 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1145 libc_cv_asm_unique_object, [dnl
1146 cat > conftest.s <<EOF
1147 ${libc_cv_dot_text}
1148 _sym:
1149 .type _sym, ${libc_cv_asm_type_prefix}gnu_unique_object
1150 EOF
1151 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1152 libc_cv_asm_unique_object=yes
1153 else
1154 libc_cv_asm_unique_object=no
1155 fi
1156 rm -f conftest*])
1157 if test $libc_cv_asm_unique_object = yes; then
1158 AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1159 fi
1161 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
1162 [cat > conftest.s <<EOF
1163 ${libc_cv_dot_text}
1164 _sym:
1165 .symver _sym,sym@VERS
1166 EOF
1167 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1168 libc_cv_asm_symver_directive=yes
1169 else
1170 libc_cv_asm_symver_directive=no
1171 fi
1172 rm -f conftest*])
1173 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
1174 if test $libc_cv_asm_symver_directive = yes; then
1175 cat > conftest.s <<EOF
1176 ${libc_cv_dot_text}
1177 _sym:
1178 .symver _sym,sym@VERS
1179 EOF
1180 cat > conftest.map <<EOF
1181 VERS_1 {
1182 global: sym;
1183 };
1185 VERS_2 {
1186 global: sym;
1187 } VERS_1;
1188 EOF
1189 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1190 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $LDFLAGS -shared
1191 -o conftest.so conftest.o
1192 -nostartfiles -nostdlib
1193 -Wl,--version-script,conftest.map
1194 1>&AS_MESSAGE_LOG_FD]);
1195 then
1196 libc_cv_ld_version_script_option=yes
1197 else
1198 libc_cv_ld_version_script_option=no
1199 fi
1200 else
1201 libc_cv_ld_version_script_option=no
1202 fi
1203 else
1204 libc_cv_ld_version_script_option=no
1205 fi
1206 rm -f conftest*])
1207 if test $shared != no &&
1208 test $libc_cv_asm_symver_directive = yes &&
1209 test $libc_cv_ld_version_script_option = yes &&
1210 test $enable_versioning = yes; then
1211 VERSIONING=yes
1212 AC_DEFINE(DO_VERSIONING)
1213 else
1214 VERSIONING=no
1215 fi
1216 AC_SUBST(VERSIONING)
1218 if test $shared != no && test $VERSIONING = no; then
1219 echo "\
1220 *** WARNING: You should not compile GNU libc without versioning. Not using
1221 *** versioning will introduce incompatibilities so that old binaries
1222 *** will not run anymore.
1223 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
1224 fi
1225 AC_CACHE_CHECK(for .previous assembler directive,
1226 libc_cv_asm_previous_directive, [dnl
1227 cat > conftest.s <<EOF
1228 .section foo_section
1229 .previous
1230 EOF
1231 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1232 libc_cv_asm_previous_directive=yes
1233 else
1234 libc_cv_asm_previous_directive=no
1235 fi
1236 rm -f conftest*])
1237 if test $libc_cv_asm_previous_directive = yes; then
1238 AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1239 else
1240 AC_CACHE_CHECK(for .popsection assembler directive,
1241 libc_cv_asm_popsection_directive, [dnl
1242 cat > conftest.s <<EOF
1243 .pushsection foo_section
1244 .popsection
1245 EOF
1246 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1247 libc_cv_asm_popsection_directive=yes
1248 else
1249 libc_cv_asm_popsection_directive=no
1250 fi
1251 rm -f conftest*])
1252 if test $libc_cv_asm_popsection_directive = yes; then
1253 AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1254 fi
1255 fi
1256 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1257 libc_cv_asm_protected_directive, [dnl
1258 cat > conftest.s <<EOF
1259 .protected foo
1260 foo:
1261 .hidden bar
1262 bar:
1263 EOF
1264 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1265 libc_cv_asm_protected_directive=yes
1266 else
1267 AC_MSG_ERROR(assembler support for symbol visibility is required)
1268 fi
1269 rm -f conftest*])
1271 if test $libc_cv_asm_protected_directive = yes; then
1272 AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1273 libc_cv_visibility_attribute,
1274 [cat > conftest.c <<EOF
1275 int foo __attribute__ ((visibility ("hidden"))) = 1;
1276 int bar __attribute__ ((visibility ("protected"))) = 1;
1277 EOF
1278 libc_cv_visibility_attribute=no
1279 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1280 if grep '\.hidden.*foo' conftest.s >/dev/null; then
1281 if grep '\.protected.*bar' conftest.s >/dev/null; then
1282 libc_cv_visibility_attribute=yes
1283 fi
1284 fi
1285 fi
1286 rm -f conftest.{c,s}
1287 ])
1288 if test $libc_cv_visibility_attribute != yes; then
1289 AC_MSG_ERROR(compiler support for visibility attribute is required)
1290 fi
1291 fi
1293 if test $libc_cv_visibility_attribute = yes; then
1294 AC_CACHE_CHECK(for broken __attribute__((visibility())),
1295 libc_cv_broken_visibility_attribute,
1296 [cat > conftest.c <<EOF
1297 int foo (int x);
1298 int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1299 int bar (int x) { return x; }
1300 EOF
1301 libc_cv_broken_visibility_attribute=yes
1302 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1303 changequote(,)dnl
1304 if grep '\.hidden[ _]foo' conftest.s >/dev/null; then
1305 changequote([,])dnl
1306 libc_cv_broken_visibility_attribute=no
1307 fi
1308 fi
1309 rm -f conftest.c conftest.s
1310 ])
1311 if test $libc_cv_broken_visibility_attribute = yes; then
1312 AC_MSG_ERROR(working compiler support for visibility attribute is required)
1313 fi
1314 fi
1316 AC_CACHE_CHECK(for broken __attribute__((alias())),
1317 libc_cv_broken_alias_attribute,
1318 [cat > conftest.c <<EOF
1319 extern int foo (int x) __asm ("xyzzy");
1320 int bar (int x) { return x; }
1321 extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1322 extern int dfoo;
1323 extern __typeof (dfoo) dfoo __asm ("abccb");
1324 int dfoo = 1;
1325 EOF
1326 libc_cv_broken_alias_attribute=yes
1327 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1328 if grep 'xyzzy' conftest.s >/dev/null &&
1329 grep 'abccb' conftest.s >/dev/null; then
1330 libc_cv_broken_alias_attribute=no
1331 fi
1332 fi
1333 rm -f conftest.c conftest.s
1334 ])
1335 if test $libc_cv_broken_alias_attribute = yes; then
1336 AC_MSG_ERROR(working alias attribute support required)
1337 fi
1339 if test $libc_cv_visibility_attribute = yes; then
1340 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1341 libc_cv_have_sdata_section,
1342 [echo "int i;" > conftest.c
1343 libc_cv_have_sdata_section=no
1344 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1345 | grep '\.sdata' >/dev/null; then
1346 libc_cv_have_sdata_section=yes
1347 fi
1348 rm -f conftest.c conftest.so
1349 ])
1350 if test $libc_cv_have_sdata_section = yes; then
1351 AC_DEFINE(HAVE_SDATA_SECTION)
1352 fi
1353 fi
1355 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1356 libc_cv_initfini_array, [dnl
1357 LIBC_TRY_LINK_STATIC([
1358 int foo (void) { return 1; }
1359 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1360 ],
1361 [if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1362 libc_cv_initfini_array=yes
1363 else
1364 libc_cv_initfini_array=no
1365 fi],
1366 [libc_cv_initfini_array=no])
1367 ])
1368 if test $libc_cv_initfini_array != yes; then
1369 AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1370 fi
1372 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1373 libc_cv_ctors_header, [dnl
1374 libc_cv_ctors_header=yes
1375 LIBC_TRY_LINK_STATIC([
1376 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1377 __attribute__ ((destructor)) void dtor (void) { asm (""); }
1378 ],
1379 [dnl
1380 AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1381 { gsub(/\@<:@ */, "@<:@") }
1382 $2 == ".ctors" || $2 == ".dtors" {
1383 size = strtonum("0x" $6)
1384 align = strtonum("0x" $NF)
1385 seen@<:@$2@:>@ = 1
1386 stub@<:@$2@:>@ = size == align * 2
1387 }
1388 END {
1389 ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1390 dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1391 exit ((ctors_ok && dtors_ok) ? 0 : 1)
1392 }
1393 '], [libc_cv_ctors_header=no])
1394 ], [dnl
1395 AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1396 ])
1397 ])
1398 if test $libc_cv_ctors_header = no; then
1399 AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1400 fi
1402 AC_CACHE_CHECK(for libunwind-support in compiler,
1403 libc_cv_cc_with_libunwind, [
1404 cat > conftest.c <<EOF
1405 int main (void) { return 0; }
1406 EOF
1407 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1408 conftest.c -v 2>&1 >/dev/null | grep -q " -lunwind "; then
1409 libc_cv_cc_with_libunwind=yes
1410 else
1411 libc_cv_cc_with_libunwind=no
1412 fi
1413 rm -f conftest*])
1414 AC_SUBST(libc_cv_cc_with_libunwind)
1415 if test $libc_cv_cc_with_libunwind = yes; then
1416 AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1417 fi
1419 AC_CACHE_CHECK(for -z nodelete option,
1420 libc_cv_z_nodelete, [dnl
1421 cat > conftest.c <<EOF
1422 int _start (void) { return 42; }
1423 EOF
1424 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1425 -fPIC -shared -o conftest.so conftest.c
1426 -nostartfiles -nostdlib
1427 -Wl,--enable-new-dtags,-z,nodelete 1>&AS_MESSAGE_LOG_FD])
1428 then
1429 libc_cv_z_nodelete=yes
1430 else
1431 AC_MSG_ERROR(linker with -z nodelete support required)
1432 fi
1433 rm -f conftest*])
1435 AC_CACHE_CHECK(for -z nodlopen option,
1436 libc_cv_z_nodlopen, [dnl
1437 cat > conftest.c <<EOF
1438 int _start (void) { return 42; }
1439 EOF
1440 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1441 -fPIC -shared -o conftest.so conftest.c
1442 -nostartfiles -nostdlib
1443 -Wl,--enable-new-dtags,-z,nodlopen 1>&AS_MESSAGE_LOG_FD])
1444 then
1445 libc_cv_z_nodlopen=yes
1446 else
1447 AC_MSG_ERROR(linker with -z nodlopen support required)
1448 fi
1449 rm -f conftest*])
1451 AC_CACHE_CHECK(for -z initfirst option,
1452 libc_cv_z_initfirst, [dnl
1453 cat > conftest.c <<EOF
1454 int _start (void) { return 42; }
1455 EOF
1456 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1457 -fPIC -shared -o conftest.so conftest.c
1458 -nostartfiles -nostdlib
1459 -Wl,--enable-new-dtags,-z,initfirst 1>&AS_MESSAGE_LOG_FD])
1460 then
1461 libc_cv_z_initfirst=yes
1462 else
1463 AC_MSG_ERROR(linker with -z initfirst support required)
1464 fi
1465 rm -f conftest*])
1467 # Add-on fragments can set these for other machines.
1468 libc_commonpagesize=${libc_commonpagesize:-no}
1469 libc_relro_required=${libc_relro_required:-no}
1470 case "$base_machine" in
1471 i[[34567]]86 | x86_64 | powerpc* | s390*)
1472 libc_commonpagesize=0x1000
1473 libc_relro_required=yes
1474 ;;
1475 sparc*)
1476 libc_commonpagesize=0x2000
1477 libc_relro_required=yes
1478 ;;
1479 esac
1481 if test $libc_commonpagesize != no; then
1482 AC_CACHE_CHECK(for -z relro option,
1483 libc_cv_z_relro, [dnl
1484 libc_cv_z_relro=no
1485 AC_LANG_CONFTEST([AC_LANG_SOURCE([[
1486 int _start (void) { return 42; }
1487 extern void _exit (int);
1488 /* Since these pointers are const, they should go in rodata.
1489 Since they refer to functions that have to be resolved by
1490 dynamic linking, they should instead go in RELRO data. */
1491 const void *const relro[] = { &_start, &_exit, 0 };
1492 /* GNU ld fails to produce RELRO data when it's very small and there is no
1493 normal writable data following it, or if only uninitialized (.bss) data
1494 follows it, or only very small writable data. */
1495 int data[0x10000] = { 1, };
1496 ]])])
1497 cat > conftest.awk <<\EOF
1498 BEGIN {
1499 result = "no"
1500 commonpagesize = strtonum(commonpagesize)
1501 }
1502 { print "LINE:", $0 > "/dev/stderr" }
1503 $1 == "GNU_RELRO" {
1504 vaddr = strtonum($3)
1505 memsz = strtonum($6)
1506 end = vaddr + memsz
1507 printf "vaddr %#x memsz %#x end %#x commonpagesize %#x\n", \
1508 vaddr, memsz, end, commonpagesize > "/dev/stderr"
1509 result = (end % commonpagesize == 0) ? "yes" : "broken"
1510 }
1511 END { print result }
1512 EOF
1513 AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1514 -fPIC -shared -o conftest.so conftest.c
1515 -nostartfiles -nostdlib
1516 -Wl,-z,relro 1>&AS_MESSAGE_LOG_FD]) &&
1517 AC_TRY_COMMAND([$READELF -Wl conftest.so > conftest.ph]) &&
1518 AC_TRY_COMMAND([
1519 $AWK -v commonpagesize=$libc_commonpagesize -f conftest.awk
1520 conftest.ph > conftest.cps
1521 ]) &&
1522 libc_cv_z_relro=`cat conftest.cps 2>&AS_MESSAGE_LOG_FD`
1523 rm -f conftest*])
1524 if { test "x$libc_relro_required" = xyes &&
1525 test "x$libc_cv_z_relro" != xyes
1526 }
1527 then
1528 AC_MSG_ERROR(linker with -z relro support required)
1529 fi
1530 else
1531 AC_MSG_WARN([missing architecture parameter to check for working -z relro])
1532 fi
1534 AC_CACHE_CHECK(for -Bgroup option,
1535 libc_cv_Bgroup, [dnl
1536 cat > conftest.c <<EOF
1537 int _start (void) { return 42; }
1538 EOF
1539 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1540 -fPIC -shared -o conftest.so conftest.c
1541 -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1542 then
1543 libc_cv_Bgroup=yes
1544 else
1545 libc_cv_Bgroup=no
1546 fi
1547 rm -f conftest*])
1548 AC_SUBST(libc_cv_Bgroup)
1550 ASFLAGS_config=
1551 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1552 libc_cv_as_noexecstack, [dnl
1553 cat > conftest.c <<EOF
1554 void foo (void) { }
1555 EOF
1556 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1557 -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1558 && grep -q .note.GNU-stack conftest.s \
1559 && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1560 -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1561 then
1562 libc_cv_as_noexecstack=yes
1563 else
1564 libc_cv_as_noexecstack=no
1565 fi
1566 rm -f conftest*])
1567 if test $libc_cv_as_noexecstack = yes; then
1568 ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1569 fi
1570 AC_SUBST(ASFLAGS_config)
1572 AC_CACHE_CHECK(for -z combreloc,
1573 libc_cv_z_combreloc, [dnl
1574 cat > conftest.c <<EOF
1575 extern int bar (int);
1576 extern int mumble;
1577 int foo (void) { return bar (mumble); }
1578 EOF
1579 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1580 -fPIC -shared -o conftest.so conftest.c
1581 -nostdlib -nostartfiles
1582 -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1583 then
1584 dnl The following test is a bit weak. We must use a tool which can test
1585 dnl cross-platform since the gcc used can be a cross compiler. Without
1586 dnl introducing new options this is not easily doable. Instead use a tool
1587 dnl which always is cross-platform: readelf. To detect whether -z combreloc
1588 dnl look for a section named .rel.dyn.
1589 if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1590 libc_cv_z_combreloc=yes
1591 else
1592 libc_cv_z_combreloc=no
1593 fi
1594 else
1595 libc_cv_z_combreloc=no
1596 fi
1597 rm -f conftest*])
1598 if test "$libc_cv_z_combreloc" = yes; then
1599 AC_DEFINE(HAVE_Z_COMBRELOC)
1600 fi
1601 AC_SUBST(libc_cv_z_combreloc)
1603 AC_CACHE_CHECK(for -z execstack,
1604 libc_cv_z_execstack, [dnl
1605 cat > conftest.c <<EOF
1606 int _start (void) { return 42; }
1607 EOF
1608 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1609 -fPIC -shared -o conftest.so conftest.c
1610 -Wl,-z,execstack -nostdlib
1611 1>&AS_MESSAGE_LOG_FD])
1612 then
1613 libc_cv_z_execstack=yes
1614 else
1615 libc_cv_z_execstack=no
1616 fi
1617 rm -f conftest*])
1618 AC_SUBST(libc_cv_z_execstack)
1620 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1621 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1622 ])
1624 AC_SUBST(libc_cv_fpie)
1626 AC_CACHE_CHECK(for --hash-style option,
1627 libc_cv_hashstyle, [dnl
1628 cat > conftest.c <<EOF
1629 int _start (void) { return 42; }
1630 EOF
1631 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1632 -fPIC -shared -o conftest.so conftest.c
1633 -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1634 then
1635 libc_cv_hashstyle=yes
1636 else
1637 libc_cv_hashstyle=no
1638 fi
1639 rm -f conftest*])
1640 AC_SUBST(libc_cv_hashstyle)
1642 # The linker's default -shared behavior is good enough if it
1643 # does these things that our custom linker scripts ensure that
1644 # all allocated NOTE sections come first.
1645 if test "$use_default_link" = default; then
1646 AC_CACHE_CHECK([for sufficient default -shared layout],
1647 libc_cv_use_default_link, [dnl
1648 libc_cv_use_default_link=no
1649 cat > conftest.s <<\EOF
1650 .section .note.a,"a",%note
1651 .balign 4
1652 .long 4,4,9
1653 .string "GNU"
1654 .string "foo"
1655 .section .note.b,"a",%note
1656 .balign 4
1657 .long 4,4,9
1658 .string "GNU"
1659 .string "bar"
1660 EOF
1661 if AC_TRY_COMMAND([dnl
1662 ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1663 ac_try=`$READELF -S conftest.so | sed -n \
1664 ['${x;p;}
1665 s/^ *\[ *[1-9][0-9]*\] *\([^ ][^ ]*\) *\([^ ][^ ]*\) .*$/\2 \1/
1666 t a
1667 b
1668 : a
1669 H']`
1670 then
1671 libc_seen_a=no libc_seen_b=no
1672 set -- $ac_try
1673 while test $# -ge 2 -a "$1" = NOTE; do
1674 case "$2" in
1675 .note.a) libc_seen_a=yes ;;
1676 .note.b) libc_seen_b=yes ;;
1677 esac
1678 shift 2
1679 done
1680 case "$libc_seen_a$libc_seen_b" in
1681 yesyes)
1682 libc_cv_use_default_link=yes
1683 ;;
1684 *)
1685 echo >&AS_MESSAGE_LOG_FD "\
1686 $libc_seen_a$libc_seen_b from:
1687 $ac_try"
1688 ;;
1689 esac
1690 fi
1691 rm -f conftest*])
1692 use_default_link=$libc_cv_use_default_link
1693 fi
1695 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1696 if libc_cv_output_format=`
1697 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1698 then
1699 :
1700 else
1701 libc_cv_output_format=
1702 fi
1703 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1704 AC_SUBST(libc_cv_output_format)
1706 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1707 cat > conftest.c <<EOF
1708 int foo;
1709 EOF
1710 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1711 conftest.c 1>&AS_MESSAGE_LOG_FD])
1712 then
1713 libc_cv_fno_toplevel_reorder=yes
1714 else
1715 libc_cv_fno_toplevel_reorder=no
1716 fi
1717 rm -f conftest*])
1718 if test $libc_cv_fno_toplevel_reorder = yes; then
1719 fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1720 else
1721 fno_unit_at_a_time=-fno-unit-at-a-time
1722 fi
1723 AC_SUBST(fno_unit_at_a_time)
1725 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1726 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1727 [libc_cv_ssp=yes],
1728 [libc_cv_ssp=no])
1729 ])
1730 AC_SUBST(libc_cv_ssp)
1732 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1733 cat > conftest.c <<EOF
1734 int foo;
1735 #ifdef __GNUC_GNU_INLINE__
1736 main () { return 0;}
1737 #else
1738 #error
1739 #endif
1740 EOF
1741 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1742 -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1743 then
1744 libc_cv_gnu89_inline=yes
1745 else
1746 libc_cv_gnu89_inline=no
1747 fi
1748 rm -f conftest*])
1749 if test $libc_cv_gnu89_inline = yes; then
1750 gnu89_inline=-fgnu89-inline
1751 else
1752 gnu89_inline=
1753 fi
1754 AC_SUBST(gnu89_inline)
1756 AC_CACHE_CHECK(whether cc puts quotes around section names,
1757 libc_cv_have_section_quotes,
1758 [cat > conftest.c <<EOF
1759 static const int foo
1760 __attribute__ ((section ("bar"))) = 1;
1761 EOF
1762 if ${CC-cc} -S conftest.c -o conftest.s; then
1763 if grep '\.section.*"bar"' conftest.s >/dev/null; then
1764 libc_cv_have_section_quotes=yes
1765 else
1766 libc_cv_have_section_quotes=no
1767 fi
1768 else
1769 libc_cv_have_section_quotes=unknown
1770 fi
1771 rm -f conftest.{c,s}
1772 ])
1773 if test $libc_cv_have_section_quotes = yes; then
1774 AC_DEFINE(HAVE_SECTION_QUOTES)
1775 fi
1777 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1778 [dnl
1779 cat > conftest.s <<EOF
1780 ${libc_cv_dot_text}
1781 ${libc_cv_asm_global_directive} foo
1782 foo:
1783 .weak foo
1784 .weak bar; bar = foo
1785 EOF
1786 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1787 libc_cv_asm_weak_directive=yes
1788 else
1789 libc_cv_asm_weak_directive=no
1790 fi
1791 rm -f conftest*])
1793 if test $libc_cv_asm_weak_directive = no; then
1794 AC_CACHE_CHECK(for assembler .weakext directive,
1795 libc_cv_asm_weakext_directive,
1796 [dnl
1797 cat > conftest.s <<EOF
1798 ${libc_cv_dot_text}
1799 ${libc_cv_asm_global_directive} foo
1800 foo:
1801 .weakext bar foo
1802 .weakext baz
1803 ${libc_cv_asm_global_directive} baz
1804 baz:
1805 EOF
1806 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1807 libc_cv_asm_weakext_directive=yes
1808 else
1809 libc_cv_asm_weakext_directive=no
1810 fi
1811 rm -f conftest*])
1813 fi # no .weak
1815 if test $libc_cv_asm_weak_directive = yes; then
1816 AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1817 elif test $libc_cv_asm_weakext_directive = yes; then
1818 AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1819 fi
1821 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1822 case $machine in
1823 sparc/sparc64*) cfi_offset=2047;;
1824 *) cfi_offset=0;;
1825 esac
1826 cat > conftest.s <<EOF
1827 .text
1828 .type func,%function
1829 func:
1830 .cfi_startproc
1831 .cfi_remember_state
1832 .cfi_rel_offset 1, $cfi_offset
1833 .cfi_endproc
1834 EOF
1835 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1836 libc_cv_asm_cfi_directives=yes
1837 else
1838 libc_cv_asm_cfi_directives=no
1839 fi
1840 rm -f conftest*])
1841 if test $libc_cv_asm_cfi_directives = yes; then
1842 AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1843 fi
1845 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1846 cat > conftest.c <<\EOF
1847 _start () {}
1848 int __eh_pc;
1849 __throw () {}
1850 EOF
1851 dnl No \ in command here because it ends up inside ''.
1852 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1853 -nostdlib -nostartfiles -Wl,--no-whole-archive
1854 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1855 libc_cv_ld_no_whole_archive=yes
1856 else
1857 libc_cv_ld_no_whole_archive=no
1858 fi
1859 rm -f conftest*])
1860 if test $libc_cv_ld_no_whole_archive = no; then
1861 AC_MSG_ERROR([support for --no-whole-archive is needed])
1862 fi
1864 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1865 cat > conftest.c <<\EOF
1866 _start () {}
1867 int __eh_pc;
1868 __throw () {}
1869 EOF
1870 dnl No \ in command here because it ends up inside ''.
1871 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1872 -nostdlib -nostartfiles -fexceptions
1873 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1874 libc_cv_gcc_exceptions=yes
1875 else
1876 libc_cv_gcc_exceptions=no
1877 fi
1878 rm -f conftest*])
1879 if test $libc_cv_gcc_exceptions = yes; then
1880 exceptions=-fexceptions
1881 fi
1882 AC_SUBST(exceptions)dnl
1884 if test "$host_cpu" = powerpc ; then
1885 # Check for a bug present in at least versions 2.8.x of GCC
1886 # and versions 1.0.x of EGCS.
1887 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1888 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1889 libc_cv_c_asmcr0_bug='no',
1890 libc_cv_c_asmcr0_bug='yes')])
1891 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1892 AC_DEFINE(BROKEN_PPC_ASM_CR0)
1893 fi
1894 fi
1896 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1897 cat > conftest.c <<\EOF
1898 void zero (void *x)
1899 {
1900 __builtin_memset (x, 0, 1000);
1901 }
1902 EOF
1903 dnl
1904 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1905 then
1906 libc_cv_gcc_builtin_memset=no
1907 else
1908 libc_cv_gcc_builtin_memset=yes
1909 fi
1910 rm -f conftest* ])
1911 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1912 AC_DEFINE(HAVE_BUILTIN_MEMSET)
1913 fi
1915 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1916 cat > conftest.c <<\EOF
1917 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1918 char *foo (const char *a, const char *b)
1919 {
1920 return __builtin_strstr (a, b);
1921 }
1922 EOF
1923 dnl
1924 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1925 then
1926 libc_cv_gcc_builtin_redirection=yes
1927 else
1928 libc_cv_gcc_builtin_redirection=no
1929 fi
1930 rm -f conftest* ])
1931 if test "$libc_cv_gcc_builtin_redirection" = no; then
1932 AC_MSG_ERROR([support for the symbol redirection needed])
1933 fi
1935 dnl Check whether the compiler supports the __thread keyword.
1936 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1937 [cat > conftest.c <<\EOF
1938 __thread int a = 42;
1939 EOF
1940 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1941 libc_cv_gcc___thread=yes
1942 else
1943 libc_cv_gcc___thread=no
1944 fi
1945 rm -f conftest*])
1946 if test "$libc_cv_gcc___thread" = no; then
1947 AC_MSG_ERROR([support for the __thread keyword is required])
1948 fi
1950 dnl Check whether the compiler supports the tls_model attribute.
1951 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1952 cat > conftest.c <<\EOF
1953 extern __thread int a __attribute__((tls_model ("initial-exec")));
1954 EOF
1955 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
1956 libc_cv_gcc_tls_model_attr=yes
1957 else
1958 libc_cv_gcc_tls_model_attr=no
1959 fi
1960 rm -f conftest*])
1961 if test "$libc_cv_gcc_tls_model_attr" = no; then
1962 AC_MSG_ERROR([support for the tls_model attribute is required])
1963 fi
1965 dnl Determine how to disable generation of FMA instructions.
1966 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1967 libc_cv_cc_nofma, [dnl
1968 libc_cv_cc_nofma=
1969 for opt in -ffp-contract=off -mno-fused-madd; do
1970 LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1971 done])
1973 if test -n "$submachine"; then
1974 AC_CACHE_CHECK([for compiler option for CPU variant],
1975 libc_cv_cc_submachine, [dnl
1976 libc_cv_cc_submachine=no
1977 for opt in "-march=$submachine" "-mcpu=$submachine"; do
1978 LIBC_TRY_CC_OPTION([$opt], [
1979 libc_cv_cc_submachine="$opt"
1980 break], [])
1981 done])
1982 if test "x$libc_cv_cc_submachine" = xno; then
1983 AC_MSG_ERROR([${CC-cc} does not support $submachine])
1984 fi
1985 fi
1986 AC_SUBST(libc_cv_cc_submachine)
1988 dnl Check whether we have the gd library available.
1989 AC_MSG_CHECKING(for libgd)
1990 if test "$with_gd" != "no"; then
1991 old_CFLAGS="$CFLAGS"
1992 CFLAGS="$CFLAGS $libgd_include"
1993 old_LDFLAGS="$LDFLAGS"
1994 LDFLAGS="$LDFLAGS $libgd_ldflags"
1995 old_LIBS="$LIBS"
1996 LIBS="$LIBS -lgd -lpng -lz -lm"
1997 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1998 CFLAGS="$old_CFLAGS"
1999 LDFLAGS="$old_LDFLAGS"
2000 LIBS="$old_LIBS"
2001 else
2002 LIBGD=no
2003 fi
2004 AC_MSG_RESULT($LIBGD)
2005 AC_SUBST(LIBGD)
2007 # SELinux detection
2008 if test x$with_selinux = xno ; then
2009 have_selinux=no;
2010 else
2011 # See if we have the SELinux library
2012 AC_CHECK_LIB(selinux, is_selinux_enabled,
2013 have_selinux=yes, have_selinux=no)
2014 # See if we have the SELinux header with the NSCD permissions in it.
2015 if test x$have_selinux = xyes ; then
2016 AC_MSG_CHECKING([for NSCD Flask permissions in selinux/av_permissions.h])
2017 AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
2018 [#ifdef NSCD__SHMEMHOST
2019 return 0;
2020 #else
2021 #error NSCD__SHMEMHOST not defined
2022 #endif],
2023 have_selinux=yes, have_selinux=no)
2024 AC_MSG_RESULT($have_selinux)
2025 fi
2027 if test x$with_selinux = xyes ; then
2028 if test x$have_selinux = xno ; then
2029 AC_MSG_ERROR([SELinux explicitly required, but sufficiently recent SELinux library not found])
2030 fi
2031 fi
2032 fi
2033 # Check if we're building with SELinux support.
2034 if test "x$have_selinux" = xyes; then
2035 AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
2037 # See if we have the libaudit library
2038 AC_CHECK_LIB(audit, audit_log_user_avc_message,
2039 have_libaudit=yes, have_libaudit=no)
2040 if test "x$have_libaudit" = xyes; then
2041 AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
2042 fi
2043 AC_SUBST(have_libaudit)
2045 # See if we have the libcap library
2046 AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
2047 if test "x$have_libcap" = xyes; then
2048 AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
2049 fi
2050 AC_SUBST(have_libcap)
2051 fi
2052 AC_SUBST(have_selinux)
2054 dnl check for the size of 'long double'.
2055 AC_CHECK_SIZEOF(long double, 0)
2056 sizeof_long_double=$ac_cv_sizeof_long_double
2057 AC_SUBST(sizeof_long_double)
2059 CPPUNDEFS=
2060 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
2061 dnl Since we are building the implementations of the fortified functions here,
2062 dnl having the macro defined interacts very badly.
2063 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
2064 [AC_TRY_COMPILE([], [
2065 #ifdef _FORTIFY_SOURCE
2066 # error bogon
2067 #endif],
2068 [libc_cv_predef_fortify_source=no],
2069 [libc_cv_predef_fortify_source=yes])])
2070 if test $libc_cv_predef_fortify_source = yes; then
2071 CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
2072 fi
2073 AC_SUBST(CPPUNDEFS)
2075 dnl Check for silly hacked compilers inserting -fstack-protector.
2076 dnl This breaks badly for the early startup code we compile, since
2077 dnl the compiled code can refer to a magic machine-dependent location
2078 dnl for the canary value before we have sufficient setup for that to
2079 dnl work. It's also questionable to build all of libc with this flag
2080 dnl even when you're doing that for most applications you build, since
2081 dnl libc's code is so heavily-used and performance-sensitive. If we
2082 dnl ever really want to make that work, it should be enabled explicitly
2083 dnl in the libc build, not inherited from implicit compiler settings.
2084 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
2085 libc_cv_predef_stack_protector, [
2086 AC_TRY_COMPILE([extern void foobar (char *);],
2087 [char large_array[2048]; foobar (large_array);], [
2088 libc_undefs=`$NM -u conftest.o |
2089 LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
2090 2>&AS_MESSAGE_LOG_FD` || {
2091 AC_MSG_ERROR([confusing output from $NM -u])
2092 }
2093 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
2094 # On some architectures, there are architecture-specific undefined
2095 # symbols (resolved by the linker), so filter out unknown symbols.
2096 # This will fail to produce the correct result if the compiler
2097 # defaults to -fstack-protector but this produces an undefined symbol
2098 # other than __stack_chk_fail. However, compilers like that have not
2099 # been encountered in practice.
2100 libc_undefs=`echo "$libc_undefs" | egrep '^(foobar|__stack_chk_fail)$'`
2101 case "$libc_undefs" in
2102 foobar) libc_cv_predef_stack_protector=no ;;
2103 '__stack_chk_fail
2104 foobar') libc_cv_predef_stack_protector=yes ;;
2105 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
2106 esac],
2107 [AC_MSG_ERROR([test compilation failed])])
2108 ])
2109 libc_extra_cflags=
2110 if test $libc_cv_predef_stack_protector = yes; then
2111 libc_extra_cflags=-fno-stack-protector
2112 fi
2113 AC_SUBST(libc_extra_cflags)
2115 ### End of automated tests.
2116 ### Now run sysdeps configure fragments.
2118 # They also can set these variables.
2119 use_ldconfig=no
2120 ldd_rewrite_script=no
2121 libc_cv_sysconfdir=$sysconfdir
2122 libc_cv_localstatedir=$localstatedir
2123 libc_cv_gcc_unwind_find_fde=no
2124 libc_cv_idn=no
2126 # Iterate over all the sysdep directories we will use, running their
2127 # configure fragments.
2128 for dir in $sysnames; do
2129 case $dir in
2130 /*) dest=$dir ;;
2131 *) dest=$srcdir/$dir ;;
2132 esac
2133 if test -r $dest/configure; then
2134 AC_MSG_RESULT(running configure fragment for $dir)
2135 . $dest/configure
2136 fi
2137 done
2139 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2140 AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2141 fi
2142 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2144 # Test for old glibc 2.0.x headers so that they can be removed properly
2145 # Search only in includedir.
2146 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2147 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2148 then
2149 old_glibc_headers=yes
2150 else
2151 old_glibc_headers=no
2152 fi
2153 AC_MSG_RESULT($old_glibc_headers)
2154 if test ${old_glibc_headers} = yes; then
2155 AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2156 AC_MSG_WARN(*** be removed.)
2157 fi
2158 AC_SUBST(old_glibc_headers)
2160 AC_SUBST(libc_cv_slibdir)
2161 AC_SUBST(libc_cv_localedir)
2162 AC_SUBST(libc_cv_sysconfdir)
2163 AC_SUBST(libc_cv_localstatedir)
2164 AC_SUBST(libc_cv_rootsbindir)
2165 AC_SUBST(libc_cv_forced_unwind)
2167 dnl sysdeps/CPU/configure.in checks set this via arch-specific asm tests
2168 AC_SUBST(libc_cv_cpp_asm_debuginfo)
2169 AC_SUBST(libc_cv_cc_sse4)
2170 AC_SUBST(libc_cv_cc_avx)
2171 AC_SUBST(libc_cv_cc_sse2avx)
2172 AC_SUBST(libc_cv_cc_novzeroupper)
2173 AC_SUBST(libc_cv_cc_fma4)
2174 AC_SUBST(libc_cv_cc_nofma)
2175 AC_SUBST(libc_cv_as_i686)
2176 AC_SUBST(libc_cv_sparc_as_vis3)
2178 AC_SUBST(use_ldconfig)
2179 AC_SUBST(ldd_rewrite_script)
2181 AC_SUBST(static)
2182 AC_SUBST(shared)
2184 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2185 [libc_cv_pic_default=yes
2186 cat > conftest.c <<EOF
2187 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2188 # error PIC is default.
2189 #endif
2190 EOF
2191 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2192 libc_cv_pic_default=no
2193 fi
2194 rm -f conftest.*])
2195 AC_SUBST(libc_cv_pic_default)
2197 AC_SUBST(profile)
2198 AC_SUBST(static_nss)
2200 AC_SUBST(DEFINES)
2202 dnl See sysdeps/mach/configure.in for this variable.
2203 AC_SUBST(mach_interface_list)
2205 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
2206 config_makefile=
2207 else
2208 config_makefile=Makefile
2209 fi
2211 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2212 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2213 AC_SUBST(VERSION)
2214 AC_SUBST(RELEASE)
2216 AC_CONFIG_FILES([config.make ${config_makefile}])
2217 AC_CONFIG_COMMANDS([default],[[
2218 case $CONFIG_FILES in *config.make*)
2219 echo "$config_vars" >> config.make;;
2220 esac
2221 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2222 AC_OUTPUT