sysdeps/unix/sysv/linux/x86_64/getcontext.S

   1 /* Save current context.
   2    Copyright (C) 2002 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Andreas Jaeger <aj@suse.de>, 2002.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 #include <sysdep.h>
  22
  23 #include "ucontext_i.h"
  24
  25 /*  int __getcontext (ucontext_t *ucp)
  26
  27   Saves the machine context in UCP such that when it is activated,
  28   it appears as if __getcontext() returned again.
  29
  30   This implementation is intended to be used for *synchronous* context
  31   switches only.  Therefore, it does not have to save anything
  32   other than the PRESERVED state.  */
  33
  34
  35 ENTRY(__getcontext)
  36         /* Save the preserved registers, the registers used for passing
  37            args, and the return address.  */
  38         movq    %rbx, oRBX(%rdi)
  39         movq    %rbp, oRBP(%rdi)
  40         movq    %r12, oR12(%rdi)
  41         movq    %r13, oR13(%rdi)
  42         movq    %r14, oR14(%rdi)
  43         movq    %r15, oR15(%rdi)
  44
  45         movq    %rdi, oRDI(%rdi)
  46         movq    %rsi, oRSI(%rdi)
  47         movq    %rdx, oRDX(%rdi)
  48         movq    %rcx, oRCX(%rdi)
  49         movq    %r8, oR8(%rdi)
  50         movq    %r9, oR9(%rdi)
  51
  52         movq    (%rsp), %rcx
  53         movq    %rcx, oRIP(%rdi)
  54         leaq    8(%rsp), %rcx           /* Exclude the return address.  */
  55         movq    %rcx, oRSP(%rdi)
  56
  57         /* We have separate floating-point register content memory on the
  58            stack.  We use the __fpregs_mem block in the context.  Set the
  59            links up correctly.  */
  60
  61         leaq    oFPREGSMEM(%rdi), %rcx
  62         movq    %rcx, oFPREGS(%rdi)
  63         /* Save the floating-point environment.  */
  64         fnstenv (%rcx)
  65         stmxcsr oMXCSR(%rdi)
  66
  67         /* Save the current signal mask with
  68            rt_sigprocmask (SIG_BLOCK, NULL, set,_NSIG/8).  */
  69         leaq    oSIGMASK(%rdi), %rdx
  70         xorq    %rsi,%rsi
  71         movq    $SIG_BLOCK, %rdi
  72         movq    $_NSIG8,%r10
  73         movq    $__NR_rt_sigprocmask, %rax
  74         syscall
  75         cmpq    $-4095, %rax            /* Check %rax for error.  */
  76         jae     SYSCALL_ERROR_LABEL     /* Jump to error handler if error.  */
  77
  78         /* All done, return 0 for success.  */
  79         xorq    %rax, %rax
  80 L(pseudo_end):
  81         ret
  82 PSEUDO_END(__getcontext)
  83
  84 weak_alias(__getcontext, getcontext)