sysdeps/unix/sysv/linux/s390/s390-32/mmap.S

   1 /* Copyright (C) 2000, 2001 Free Software Foundation, Inc.
   2    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21
  22 #define EINVAL  22
  23
  24         .text
  25 ENTRY(__mmap)
  26         /* Save registers and setup stack frame.  */
  27         stm     %r6,%r15,24(%r15)
  28         cfi_offset (%r15, -36)
  29         cfi_offset (%r14, -40)
  30         cfi_offset (%r13, -44)
  31         cfi_offset (%r12, -48)
  32         cfi_offset (%r11, -52)
  33         cfi_offset (%r10, -56)
  34         cfi_offset (%r9, -60)
  35         cfi_offset (%r8, -64)
  36         cfi_offset (%r7, -68)
  37         cfi_offset (%r6, -72)
  38         lr      %r1,%r15
  39         ahi     %r15,-120               /* buy stack space */
  40         cfi_adjust_cfa_offset (120)
  41         st      %r1,0(%r15)             /* store back chain */
  42
  43         /* Store parameters on stack, because old_mmap/mmap2
  44          * take only one parameter: a pointer to the parameter area
  45          */
  46         st      %r6,0x70(%r15)          /* Store 'fd'.      */
  47         st      %r5,0x6C(%r15)          /* Store 'flags'.   */
  48         st      %r4,0x68(%r15)          /* Store 'prot'.    */
  49         st      %r3,0x64(%r15)          /* Store 'length'.  */
  50         st      %r2,0x60(%r15)          /* Store 'start'.   */
  51         l       %r1,216(%r15)           /* Load offset.     */
  52
  53 #ifdef __ASSUME_MMAP2_SYSCALL
  54         /* I don't think it is worthwhile trying to use mmap2 whenever
  55          * it is available.  Only use it when we are sure the syscall
  56          * exists.  */
  57         tml     %r1,0x0fff              /* Offset page aligned ?  */
  58         lhi     %r2,-EINVAL
  59         jnz     1f                      /* No -> EINVAL.  */
  60         srl     %r1,12                  /* mmap2 takes the offset in pages.  */
  61         st      %r1,0x74(%r15)          /* Store page offset.  */
  62         la      %r2,0x60(%r15)          /* Load address of parameter list.  */
  63         svc     SYS_ify(mmap2)          /* Do the system call trap.  */
  64 #else
  65         st      %r1,0x74(%r15)          /* Store offset unmodified.  */
  66         la      %r2,0x60(%r15)          /* Load address of parameter list.  */
  67         svc     SYS_ify(mmap)           /* Do the system call trap.  */
  68 #endif
  69
  70 1:      l       %r15,0(%r15)            /* Load back chain.  */
  71         cfi_adjust_cfa_offset (-120)
  72         lm      %r6,%r15,24(%r15)       /* Load registers.  */
  73
  74         /* check gpr 2 for error */
  75         lhi     %r0,-4096
  76         clr     %r2,%r0
  77         jnl     SYSCALL_ERROR_LABEL
  78
  79         /* Successful; return the syscall's value.  */
  80         br      %r14
  81
  82 PSEUDO_END (__mmap)
  83
  84 weak_alias (__mmap, mmap)