sysdeps/unix/sysv/linux/i386/vfork.S

   1 /* Copyright (C) 1999, 2002, 2004 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Andreas Schwab <schwab@gnu.org>.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #define _ERRNO_H        1
  22 #include <bits/errno.h>
  23 #include <kernel-features.h>
  24
  25 /* Clone the calling process, but without copying the whole address space.
  26    The calling process is suspended until the new process exits or is
  27    replaced by a call to `execve'.  Return -1 for errors, 0 to the new process,
  28    and the process ID of the new process to the old process.  */
  29
  30 ENTRY (__vfork)
  31
  32 #ifdef __NR_vfork
  33
  34         /* Pop the return PC value into ECX.  */
  35         popl    %ecx
  36
  37 #ifdef SAVE_PID
  38         SAVE_PID
  39 #endif
  40
  41         /* Stuff the syscall number in EAX and enter into the kernel.  */
  42         movl    $SYS_ify (vfork), %eax
  43         int     $0x80
  44
  45         /* Jump to the return PC.  Don't jump directly since this
  46            disturbs the branch target cache.  Instead push the return
  47            address back on the stack.  */
  48         pushl   %ecx
  49
  50 #ifdef RESTORE_PID
  51         RESTORE_PID
  52 #endif
  53
  54         cmpl    $-4095, %eax
  55         /* Branch forward if it failed.  */
  56 # ifdef __ASSUME_VFORK_SYSCALL
  57         jae     SYSCALL_ERROR_LABEL
  58 .Lpseudo_end:
  59 # else
  60         jae     .Lerror
  61 # endif
  62
  63         ret
  64
  65 # ifndef __ASSUME_VFORK_SYSCALL
  66 .Lerror:
  67         /* Check if vfork syscall is known at all.  */
  68         cmpl    $-ENOSYS, %eax
  69         jne     SYSCALL_ERROR_LABEL
  70 # endif
  71 #endif
  72
  73 #ifndef __ASSUME_VFORK_SYSCALL
  74         /* If we don't have vfork, fork is close enough.  */
  75
  76         movl    $SYS_ify (fork), %eax
  77         int     $0x80
  78         cmpl    $-4095, %eax
  79         jae     SYSCALL_ERROR_LABEL
  80 .Lpseudo_end:
  81         ret
  82 #endif
  83 PSEUDO_END (__vfork)
  84 libc_hidden_def (__vfork)
  85
  86 weak_alias (__vfork, vfork)