sysdeps/unix/sysv/linux/i386/socket.S

   1 /* Copyright (C) 1995,1996,1997,1998,2002,2003 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.  */
  18
  19 #include <sysdep-cancel.h>
  20 #include <socketcall.h>
  21 #include <tls.h>
  22
  23 #define P(a, b) P2(a, b)
  24 #define P2(a, b) a##b
  25
  26         .text
  27 /* The socket-oriented system calls are handled unusally in Linux.
  28    They are all gated through the single `socketcall' system call number.
  29    `socketcall' takes two arguments: the first is the subcode, specifying
  30    which socket function is being called; and the second is a pointer to
  31    the arguments to the specific function.
  32
  33    The .S files for the other calls just #define socket and #include this.  */
  34
  35 #ifndef __socket
  36 # ifndef NO_WEAK_ALIAS
  37 #  define __socket P(__,socket)
  38 # else
  39 #  define __socket socket
  40 # endif
  41 #endif
  42
  43 .globl __socket
  44         cfi_startproc
  45 ENTRY (__socket)
  46 #if defined NEED_CANCELLATION && defined CENABLE
  47         SINGLE_THREAD_P
  48         jne 1f
  49 #endif
  50
  51         /* Save registers.  */
  52         movl %ebx, %edx
  53         cfi_register (3, 2)
  54
  55         movl $SYS_ify(socketcall), %eax /* System call number in %eax.  */
  56
  57         /* Use ## so `socket' is a separate token that might be #define'd.  */
  58         movl $P(SOCKOP_,socket), %ebx   /* Subcode is first arg to syscall.  */
  59         lea 4(%esp), %ecx               /* Address of args is 2nd arg.  */
  60
  61         /* Do the system call trap.  */
  62         ENTER_KERNEL
  63
  64         /* Restore registers.  */
  65         movl %edx, %ebx
  66         cfi_restore (3)
  67
  68         /* %eax is < 0 if there was an error.  */
  69         cmpl $-125, %eax
  70         jae SYSCALL_ERROR_LABEL
  71
  72         /* Successful; return the syscall's value.  */
  73 L(pseudo_end):
  74         ret
  75
  76
  77 #if defined NEED_CANCELLATION && defined CENABLE
  78         /* We need one more register.  */
  79 1:      pushl %esi
  80         cfi_adjust_cfa_offset(4)
  81
  82         /* Enable asynchronous cancellation.  */
  83         CENABLE
  84         movl %eax, %esi
  85         cfi_offset(6, -8)               /* %esi */
  86
  87         /* Save registers.  */
  88         movl %ebx, %edx
  89         cfi_register (3, 2)
  90
  91         movl $SYS_ify(socketcall), %eax /* System call number in %eax.  */
  92
  93         /* Use ## so `socket' is a separate token that might be #define'd.  */
  94         movl $P(SOCKOP_,socket), %ebx   /* Subcode is first arg to syscall.  */
  95         lea 8(%esp), %ecx               /* Address of args is 2nd arg.  */
  96
  97         /* Do the system call trap.  */
  98         ENTER_KERNEL
  99
 100         /* Restore registers.  */
 101         movl %edx, %ebx
 102         cfi_restore (3)
 103
 104         /* Restore the cancellation.  */
 105         xchgl %esi, %eax
 106         CDISABLE
 107
 108         /* Restore registers.  */
 109         movl %esi, %eax
 110         popl %esi
 111         cfi_restore (6)
 112         cfi_adjust_cfa_offset(-4)
 113
 114         /* %eax is < 0 if there was an error.  */
 115         cmpl $-125, %eax
 116         jae SYSCALL_ERROR_LABEL
 117
 118         /* Successful; return the syscall's value.  */
 119         ret
 120 #endif
 121         cfi_endproc
 122 PSEUDO_END (__socket)
 123
 124 #ifndef NO_WEAK_ALIAS
 125 weak_alias (__socket, socket)
 126 #endif