sysdeps/unix/sysv/linux/arm/socket.S

   1 /* Copyright (C) 1995, 1996, 1997, 1998, 2003 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.  */
  18
  19 #include <sysdep-cancel.h>
  20 #include <socketcall.h>
  21
  22 #define P(a, b) P2(a, b)
  23 #define P2(a, b) a##b
  24
  25         .text
  26 /* The socket-oriented system calls are handled unusally in Linux.
  27    They are all gated through the single `socketcall' system call number.
  28    `socketcall' takes two arguments: the first is the subcode, specifying
  29    which socket function is being called; and the second is a pointer to
  30    the arguments to the specific function.
  31
  32    The .S files for the other calls just #define socket and #include this.  */
  33
  34 #ifndef __socket
  35 #define __socket P(__,socket)
  36 #endif
  37
  38 #define PUSHARGS_1      str a1, [sp, $-4]!
  39 #define PUSHARGS_2      stmfd sp!, {a1, a2}
  40 #define PUSHARGS_3      stmfd sp!, {a1, a2, a3}
  41 #define PUSHARGS_4      stmfd sp!, {a1, a2, a3, a4}
  42 #define PUSHARGS_5      stmfd sp!, {a1, a2, a3, a4}     /* Caller has already pushed arg 5 */
  43 #define PUSHARGS_6      stmfd sp!, {a1, a2, a3, a4}
  44
  45 #define POPARGS_1       add sp, sp, #4
  46 #define POPARGS_2       add sp, sp, #8
  47 #define POPARGS_3       add sp, sp, #12
  48 #define POPARGS_4       add sp, sp, #16
  49 #define POPARGS_5       add sp, sp, #16
  50 #define POPARGS_6       add sp, sp, #16
  51
  52 #ifndef NARGS
  53 #define NARGS 3                 /* If we were called with no wrapper, this is really socket() */
  54 #endif
  55
  56 #if defined NEED_CANCELLATION && defined CENABLE
  57         PSEUDO_PROLOGUE
  58 #endif
  59
  60 .globl __socket
  61 ENTRY (__socket)
  62         /* This code previously moved sp into ip and stored the args using
  63            stmdb ip!, {a1-a4}.  It did not modify sp, so the stack never had
  64            to be restored after the syscall completed.  It saved an
  65            instruction and meant no stack cleanup work was required.
  66
  67            This will not work in the case of a socket call being interrupted
  68            by a signal.  If the signal handler uses any stack the arguments
  69            to socket will be trashed.  The results of a restart of any
  70            socket call are then unpredictable. */
  71
  72         /* Push args onto the stack.  */
  73         P(PUSHARGS_,NARGS)
  74
  75 #if defined NEED_CANCELLATION && defined CENABLE
  76 #ifdef PIC
  77         SINGLE_THREAD_P_PIC(r3)
  78 #else
  79         SINGLE_THREAD_P
  80 #endif
  81         bne 1f
  82 #endif
  83
  84         /* Do the system call trap.  */
  85         mov a1, $P(SOCKOP_,socket)
  86         mov a2, sp
  87         swi SYS_ify(socketcall)
  88
  89         /* Pop args off the stack */
  90         P(POPARGS_,NARGS)
  91
  92         /* r0 is < 0 if there was an error.  */
  93         cmn r0, $124
  94         RETINSTR(cc, r14)
  95         b PLTJMP(SYSCALL_ERROR)
  96
  97 #if defined NEED_CANCELLATION && defined CENABLE
  98 1:
  99         str lr, [sp, #-4]!
 100         CENABLE
 101         mov ip, r0
 102
 103         mov r0, #P(SOCKOP_,socket)
 104         add r1, sp, #4
 105         swi SYS_ify(socketcall)
 106
 107         str r0, [sp, #-4]!
 108         mov r0, ip
 109         CDISABLE
 110         ldr r0, [sp], #4
 111         ldr lr, [sp], #4
 112
 113         P(POPARGS_,NARGS)
 114
 115         /* r0 is < 0 if there was an error.  */
 116         cmn r0, $124
 117         RETINSTR(cc, r14)
 118         b PLTJMP(SYSCALL_ERROR)
 119 #endif
 120
 121 PSEUDO_END (__socket)
 122
 123 weak_alias (__socket, socket)