sysdeps/unix/sh/sysdep.S

   1 /* Copyright (C) 1999, 2000 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.  */
  18
  19 #include <sysdep.h>
  20 #define _ERRNO_H
  21 #include <bits/errno.h>
  22
  23 ENTRY(__syscall_error)
  24 #if defined (EWOULDBLOCK_sys) && EWOULDBLOCK_sys != EAGAIN
  25         /* We translate the system's EWOULDBLOCK error into EAGAIN.
  26            The GNU C library always defines EWOULDBLOCK==EAGAIN.
  27            EWOULDBLOCK_sys is the original number.  */
  28         mov.l   .L1, r1
  29         cmp/eq  r1, r0
  30         bf      skip
  31         nop
  32         mov.l   .L2, r0
  33 skip:
  34 #endif
  35         /* Store it in errno... */
  36 #ifndef SHARED
  37 #ifndef _LIBC_REENTRANT
  38         mov.l   .L3, r1
  39         mov.l   r0, @r1
  40 #else
  41         mov.l   .L3, r1
  42         sts.l   pr, @-r15
  43         jsr     @r1
  44          mov.l  r0, @-r15
  45         mov.l   @r15+, r1
  46         lds.l   @r15+, pr
  47         mov.l   r1, @r0
  48 #endif
  49 #else
  50         mov.l   r12, @-r15
  51 #ifndef _LIBC_REENTRANT
  52         mov     r0, r2
  53         mov.l   0f, r12
  54         mova    0f, r0
  55         add     r0, r12
  56         mov.l   .L3, r0
  57         mov.l   @(r0,r12), r1
  58         mov.l   r2, @r1
  59 #else
  60         mov.l   r0, @-r15
  61         sts.l   pr, @-r15
  62         mov.l   0f, r12
  63         mova    0f, r0
  64         add     r0, r12
  65         mov.l   .L3, r1
  66         mova    .L3, r0
  67         add     r0, r1
  68         jsr     @r1
  69          nop
  70         lds.l   @r15+, pr
  71         mov.l   @r15+, r1
  72         mov.l   r1, @r0
  73 #endif
  74         mov.l   @r15+, r12
  75 #endif
  76         /* And just kick back a -1.  */
  77         rts
  78          mov    #-1, r0
  79
  80         .align  2
  81 #if defined (EWOULDBLOCK_sys) && EWOULDBLOCK_sys != EAGAIN
  82 .L1:    .long   EWOULDBLOCK_sys
  83 .L2:    .long   EAGAIN
  84 #endif
  85 #ifndef SHARED
  86 #ifndef _LIBC_REENTRANT
  87 .L3:    .long   C_SYMBOL_NAME(errno)
  88 #else
  89 .L3:    .long   C_SYMBOL_NAME(__errno_location)
  90 #endif
  91 #else
  92 0:
  93         .long   _GLOBAL_OFFSET_TABLE_
  94 #ifndef _LIBC_REENTRANT
  95 .L3:    .long   C_SYMBOL_NAME(errno@GOT)
  96 #else
  97 .L3:    .long   C_SYMBOL_NAME(__errno_location@PLT)
  98 #endif
  99 #endif
 100 END(__syscall_error)
 101
 102 weak_alias (__syscall_error, syscall_error)