sysdeps/sparc/sparc32/__longjmp.S

   1 /* Copyright (C) 1991, 93, 96, 97, 98, 99, 2000 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.  */
  18
  19 #include <sysdep.h>
  20
  21 #define _ASM 1
  22 #define _SETJMP_H
  23 #include <bits/setjmp.h>
  24 #define ENV(base,reg) [%base + (reg * 4)]
  25 #define ST_FLUSH_WINDOWS 3
  26 #define RW_FP [%fp + 0x48]
  27
  28 ENTRY(__longjmp)
  29         /* Store our arguments in global registers so we can still
  30            use them while unwinding frames and their register windows.  */
  31
  32         ld ENV(o0,JB_FP), %g3   /* Cache target FP in register %g3.  */
  33         mov %o0, %g1            /* ENV in %g1 */
  34         orcc %o1, %g0, %g2      /* VAL in %g2 */
  35         be,a 0f                 /* Branch if zero; else skip delay slot.  */
  36          mov 1, %g2             /* Delay slot only hit if zero: VAL = 1.  */
  37 0:
  38         xor %fp, %g3, %o0
  39         add %fp, 512, %o1
  40         andncc %o0, 4095, %o0
  41         bne LOC(thread)
  42          cmp %o1, %g3
  43         bl LOC(thread)
  44
  45         /* Now we will loop, unwinding the register windows up the stack
  46            until the restored %fp value matches the target value in %g3.  */
  47
  48 LOC(loop):
  49         cmp %fp, %g3            /* Have we reached the target frame? */
  50         bl,a LOC(loop)          /* Loop while current fp is below target.  */
  51          restore                /* Unwind register window in delay slot.  */
  52         be,a LOC(found)         /* Better have hit it exactly.  */
  53          ld ENV(g1,JB_SP), %o0  /* Delay slot: extract target SP.  */
  54
  55 LOC(thread):
  56         /*
  57          * Do a "flush register windows trap".  The trap handler in the
  58          * kernel writes all the register windows to their stack slots, and
  59          * marks them all as invalid (needing to be sucked up from the
  60          * stack when used).  This ensures that all information needed to
  61          * unwind to these callers is in memory, not in the register
  62          * windows.
  63          */
  64         ta      ST_FLUSH_WINDOWS
  65         ld      ENV(g1,JB_PC), %o7 /* Set return PC. */
  66         ld      ENV(g1,JB_SP), %fp /* Set saved SP on restore below. */
  67         sub     %fp, 64, %sp    /* Allocate a register frame. */
  68         st      %g3, RW_FP      /* Set saved FP on restore below. */
  69         retl
  70          restore %g2, 0, %o0    /* Restore values from above register frame. */
  71
  72 LOC(found):
  73         /* We have unwound register windows so %fp matches the target.  */
  74         mov %o0, %sp            /* OK, install new SP.  */
  75
  76 LOC(sp_ok):
  77         ld ENV(g1,JB_PC), %o0   /* Extract target return PC.  */
  78         jmp %o0 + 8             /* Return there.  */
  79          mov %g2, %o0           /* Delay slot: set return value.  */
  80
  81 END(__longjmp)