sysdeps/s390/s390-64/elf/setjmp.S

   1 /* setjmp for 64 bit S/390, ELF version.
   2    Copyright (C) 2001, 2002 Free Software Foundation, Inc.
   3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 #include <sysdep.h>
  22 #define _ASM
  23 #define _SETJMP_H
  24 #include <bits/setjmp.h>
  25
  26         /* We include the BSD entry points here as well but we make
  27            them weak.  */
  28 ENTRY (setjmp)
  29         .weak C_SYMBOL_NAME (setjmp)
  30         lghi   %r3,1                /* Second argument of one.  */
  31         j      .Linternal_sigsetjmp /* Branch relativ to __sigsetjmp.  */
  32 END (setjmp)
  33
  34         /* Binary compatibility entry point.  */
  35 ENTRY(_setjmp)
  36         .weak  C_SYMBOL_NAME (_setjmp)
  37         slgr   %r3,%r3              /* Second argument of zero.  */
  38         j      .Linternal_sigsetjmp /* Branch relativ to __sigsetjmp.  */
  39 END (setjmp)
  40 libc_hidden_def (_setjmp)
  41
  42 ENTRY(__setjmp)
  43         slgr   %r3,%r3              /* Second argument of zero.  */
  44         j      .Linternal_sigsetjmp /* Branch relativ to __sigsetjmp.  */
  45 END (setjmp)
  46
  47 ENTRY(__sigsetjmp)
  48 .Linternal_sigsetjmp:
  49         stmg   %r6,%r15,0(%r2)      /* Store registers in jmp_buf.  */
  50         std    %f1,80(%r2)
  51         std    %f3,88(%r2)
  52         std    %f5,96(%r2)
  53         std    %f7,104(%r2)
  54 #ifdef PIC
  55         jg     __sigjmp_save@PLT    /* Branch to PLT of __sigsetjmp.  */
  56 #else
  57         jg     __sigjmp_save
  58 #endif
  59 END (__sigsetjmp)