sysdeps/s390/s390-32/elf/start.S

   1 /* Startup code compliant to the ELF s390 ABI.
   2    Copyright (C) 2000, 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    In addition to the permissions in the GNU Lesser General Public
  12    License, the Free Software Foundation gives you unlimited
  13    permission to link the compiled version of this file with other
  14    programs, and to distribute those programs without any restriction
  15    coming from the use of this file. (The GNU Lesser General Public
  16    License restrictions do apply in other respects; for example, they
  17    cover modification of the file, and distribution when not linked
  18    into another program.)
  19
  20    Note that people who make modified versions of this file are not
  21    obligated to grant this special exception for their modified
  22    versions; it is their choice whether to do so. The GNU Lesser
  23    General Public License gives permission to release a modified
  24    version without this exception; this exception also makes it
  25    possible to release a modified version which carries forward this
  26    exception.
  27
  28    The GNU C Library is distributed in the hope that it will be useful,
  29    but WITHOUT ANY WARRANTY; without even the implied warranty of
  30    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  31    Lesser General Public License for more details.
  32
  33    You should have received a copy of the GNU Lesser General Public
  34    License along with the GNU C Library; if not, write to the Free
  35    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  36    02111-1307 USA.  */
  37
  38 /*
  39    This is the canonical entry point, usually the first thing in the text
  40    segment. Most registers' values are unspecified, except for:
  41
  42    %r14         Contains a function pointer to be registered with `atexit'.
  43                 This is how the dynamic linker arranges to have DT_FINI
  44                 functions called for shared libraries that have been loaded
  45                 before this code runs.
  46
  47    %r15         The stack contains the arguments and environment:
  48                 0(%r15)                 argc
  49                 4(%r15)                 argv[0]
  50                 ...
  51                 (4*argc)(%r15)          NULL
  52                 (4*(argc+1))(%r15)      envp[0]
  53                 ...
  54                                         NULL
  55 */
  56
  57         .text
  58         .globl _start
  59         .type _start,@function
  60 _start:
  61         /* Setup pointer to literal pool of _start */
  62         basr    %r13,0
  63 .L0:    ahi     %r13,.Llit-.L0
  64
  65         /* load argc and argv from stack */
  66         la      %r4,4(%r15)             # get argv
  67         l       %r3,0(%r15)             # get argc
  68
  69         /* align the stack to a double word boundary */
  70         lhi     %r0,-8
  71         nr      %r15,%r0
  72
  73         /* Setup a stack frame and a parameter area */
  74         ahi     %r15,-104               # make room on stack
  75         xc      0(4,%r15),0(%r15)       # clear back-chain
  76
  77         /* set up arguments for __libc_start_main:
  78            main, argc, argv, envp, _init, _fini, rtld_fini, stack_end
  79            Note that envp will be determined later in __libc_start_main
  80          */
  81         stm     %r14,%r15,96(%r15)      # store rtld_fini/stack_end to parameter area
  82         la      %r7,96(%r15)
  83         l       %r6,.L2-.Llit(%r13)     # load pointer to __libc_csu_fini
  84         l       %r5,.L1-.Llit(%r13)     # load pointer to __libc_csu_init
  85         l       %r2,.L3-.Llit(%r13)     # load pointer to main
  86         l       %r1,.L4-.Llit(%r13)     # load pointer to __libc_start_main
  87 #ifdef PIC
  88         l       %r12,.L5-.Llit(%r13)    # load .got pointer
  89         la      %r6,0(%r13,%r6)
  90         la      %r5,0(%r13,%r5)
  91         la      %r2,0(%r13,%r2)
  92         la      %r1,0(%r13,%r1)
  93         la      %r12,0(%r13,%r12)
  94 #endif
  95
  96         /* ok, now branch to the libc main routine */
  97         basr    %r14,%r1
  98
  99         /* crash if __libc_start_main returns */
 100         .word   0
 101
 102 .Llit:
 103 #ifndef PIC
 104 .L1:    .long  __libc_csu_init
 105 .L2:    .long  __libc_csu_fini
 106 .L3:    .long  main
 107 .L4:    .long  __libc_start_main
 108 #else
 109 .L1:    .long  __libc_csu_init-.Llit
 110 .L2:    .long  __libc_csu_fini-.Llit
 111 .L3:    .long  main-.Llit
 112 .L4:    .long  __libc_start_main@plt-.Llit
 113 .L5:    .long  _GLOBAL_OFFSET_TABLE_-.Llit
 114 #endif
 115
 116 /* Define a symbol for the first piece of initialized data.  */
 117         .data
 118         .globl __data_start
 119 __data_start:
 120         .long 0
 121         .weak data_start
 122         data_start = __data_start