sysdeps/powerpc/powerpc64/strncmp.S

   1 /* Optimized strcmp implementation for PowerPC64.
   2    Copyright (C) 2003 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <bp-sym.h>
  22 #include <bp-asm.h>
  23
  24 /* See strlen.s for comments on how the end-of-string testing works.  */
  25
  26 /* int [r3] strncmp (const char *s1 [r3], const char *s2 [r4], size_t size [r5])  */
  27
  28 EALIGN (BP_SYM(strncmp), 4, 0)
  29         CALL_MCOUNT 3
  30
  31 #define rTMP    r0
  32 #define rRTN    r3
  33 #define rSTR1   r3      /* first string arg */
  34 #define rSTR2   r4      /* second string arg */
  35 #define rN      r5      /* max string length */
  36 /* Note:  The Bounded pointer support in this code is broken.  This code
  37    was inherited from PPC32 and and that support was never completed.
  38    Current PPC gcc does not support -fbounds-check or -fbounded-pointers.  */
  39 #define rWORD1  r6      /* current word in s1 */
  40 #define rWORD2  r7      /* current word in s2 */
  41 #define rFEFE   r8      /* constant 0xfefefefefefefeff (-0x0101010101010101) */
  42 #define r7F7F   r9      /* constant 0x7f7f7f7f7f7f7f7f */
  43 #define rNEG    r10     /* ~(word in s1 | 0x7f7f7f7f7f7f7f7f) */
  44 #define rBITDIF r11     /* bits that differ in s1 & s2 words */
  45
  46         dcbt    0,rSTR1
  47         or      rTMP, rSTR2, rSTR1
  48         lis     r7F7F, 0x7f7f
  49         dcbt    0,rSTR2
  50         clrldi. rTMP, rTMP, 61
  51         lis     rFEFE, -0x101
  52         bne     L(unaligned)
  53 /* We are doubleword alligned so set up for two loops.  first a double word
  54    loop, then fall into the byte loop if any residual.  */
  55         srdi.   rTMP, rN, 3
  56         clrldi  rN, rN, 61
  57         addi    rFEFE, rFEFE, -0x101
  58         addi    r7F7F, r7F7F, 0x7f7f
  59         beq     L(unaligned)
  60
  61         mtctr   rTMP    /* Power4 wants mtctr 1st in dispatch group.  */
  62         ld      rWORD1, 0(rSTR1)
  63         ld      rWORD2, 0(rSTR2)
  64         sldi    rTMP, rFEFE, 32
  65         insrdi  r7F7F, r7F7F, 32, 0
  66         add     rFEFE, rFEFE, rTMP
  67         b       L(g1)
  68
  69 L(g0):
  70         ldu     rWORD1, 8(rSTR1)
  71         bne-    cr1, L(different)
  72         ldu     rWORD2, 8(rSTR2)
  73 L(g1):  add     rTMP, rFEFE, rWORD1
  74         nor     rNEG, r7F7F, rWORD1
  75         bdz     L(tail)
  76         and.    rTMP, rTMP, rNEG
  77         cmpd    cr1, rWORD1, rWORD2
  78         beq+    L(g0)
  79
  80 /* OK. We've hit the end of the string. We need to be careful that
  81    we don't compare two strings as different because of gunk beyond
  82    the end of the strings...  */
  83
  84 L(endstring):
  85         and     rTMP, r7F7F, rWORD1
  86         beq     cr1, L(equal)
  87         add     rTMP, rTMP, r7F7F
  88         xor.    rBITDIF, rWORD1, rWORD2
  89
  90         andc    rNEG, rNEG, rTMP
  91         blt-    L(highbit)
  92         cntlzd  rBITDIF, rBITDIF
  93         cntlzd  rNEG, rNEG
  94         addi    rNEG, rNEG, 7
  95         cmpd    cr1, rNEG, rBITDIF
  96         sub     rRTN, rWORD1, rWORD2
  97         blt-    cr1, L(equal)
  98         sradi   rRTN, rRTN, 63
  99         ori     rRTN, rRTN, 1
 100         blr
 101 L(equal):
 102         li      rRTN, 0
 103         blr
 104
 105 L(different):
 106         ldu     rWORD1, -8(rSTR1)
 107         xor.    rBITDIF, rWORD1, rWORD2
 108         sub     rRTN, rWORD1, rWORD2
 109         blt-    L(highbit)
 110         sradi   rRTN, rRTN, 63
 111         ori     rRTN, rRTN, 1
 112         blr
 113 L(highbit):
 114         srdi    rWORD2, rWORD2, 56
 115         srdi    rWORD1, rWORD1, 56
 116         sub     rRTN, rWORD1, rWORD2
 117         blr
 118
 119
 120 /* Oh well.  In this case, we just do a byte-by-byte comparison.  */
 121         .align 4
 122 L(tail):
 123         and.    rTMP, rTMP, rNEG
 124         cmpd    cr1, rWORD1, rWORD2
 125         bne-    L(endstring)
 126         addi    rSTR1, rSTR1, 8
 127         bne-    cr1, L(different)
 128         addi    rSTR2, rSTR2, 8
 129 L(unaligned):
 130         mtctr   rN      /* Power4 wants mtctr 1st in dispatch group */
 131         cmpdi   rN,0
 132         lbz     rWORD1, 0(rSTR1)
 133         lbz     rWORD2, 0(rSTR2)
 134         bgt     L(u1)
 135 L(ux):
 136         li      rRTN, 0
 137         blr
 138
 139 L(u0):
 140         lbzu    rWORD2, 1(rSTR2)
 141 L(u1):
 142         bdz     L(u3)
 143         cmpdi   cr1, rWORD1, 0
 144         cmpd    rWORD1, rWORD2
 145         beq-    cr1, L(u3)
 146         lbzu    rWORD1, 1(rSTR1)
 147         bne-    L(u2)
 148         lbzu    rWORD2, 1(rSTR2)
 149         bdz     L(u3)
 150         cmpdi   cr1, rWORD1, 0
 151         cmpd    rWORD1, rWORD2
 152         bne-    L(u3)
 153         lbzu    rWORD1, 1(rSTR1)
 154         bne+    cr1, L(u0)
 155
 156 L(u2):  lbzu    rWORD1, -1(rSTR1)
 157 L(u3):  sub     rRTN, rWORD1, rWORD2
 158         blr
 159 END (BP_SYM (strncmp))
 160 libc_hidden_builtin_def (strncmp)