| blob | 0de07a82d3f20d64cdc9c8d22fc65f93881abcac |
1 /* setjmp for PowerPC64.
2 Copyright (C) 1995-2003, 2004 Free Software Foundation, Inc.
3 This file is part of the GNU C Library.
5 The GNU C Library is free software; you can redistribute it and/or
6 modify it under the terms of the GNU Lesser General Public
7 License as published by the Free Software Foundation; either
8 version 2.1 of the License, or (at your option) any later version.
10 The GNU C Library is distributed in the hope that it will be useful,
11 but WITHOUT ANY WARRANTY; without even the implied warranty of
12 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 Lesser General Public License for more details.
15 You should have received a copy of the GNU Lesser General Public
16 License along with the GNU C Library; if not, write to the Free
17 Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
18 02111-1307 USA. */
20 #include <sysdep.h>
21 #define _ASM
22 #define _SETJMP_H
23 #ifdef __NO_VMX__
24 #include <novmxsetjmp.h>
25 #else
26 #include <bits/setjmp.h>
27 #endif
28 #include <bp-sym.h>
29 #include <bp-asm.h>
31 #ifndef __NO_VMX__
32 .section ".toc","aw"
33 .LC__dl_hwcap:
34 # ifdef SHARED
35 .tc _rtld_global_ro[TC],_rtld_global_ro
36 # else
37 .tc _dl_hwcap[TC],_dl_hwcap
38 # endif
39 .section ".text"
40 #endif
42 .machine "altivec"
43 ENTRY (BP_SYM (__sigsetjmp))
44 CALL_MCOUNT 2
45 .globl JUMPTARGET(GLUE(__sigsetjmp,_ent))
46 .hidden JUMPTARGET(GLUE(__sigsetjmp,_ent))
47 JUMPTARGET(GLUE(__sigsetjmp,_ent)):
48 CHECK_BOUNDS_BOTH_WIDE_LIT (r3, r8, r9, JB_SIZE)
49 std r1,(JB_GPR1*8)(3)
50 mflr r0
51 #if defined SHARED && !defined IS_IN_rtld
52 ld r5,40(r1) /* Retrieve the callers TOC. */
53 std r5,(JB_GPR2*8)(3)
54 #else
55 std r2,(JB_GPR2*8)(3)
56 #endif
57 std r14,((JB_GPRS+0)*8)(3)
58 stfd fp14,((JB_FPRS+0)*8)(3)
59 std r0,(JB_LR*8)(3)
60 std r15,((JB_GPRS+1)*8)(3)
61 stfd fp15,((JB_FPRS+1)*8)(3)
62 mfcr r0
63 std r16,((JB_GPRS+2)*8)(3)
64 stfd fp16,((JB_FPRS+2)*8)(3)
65 std r0,(JB_CR*8)(3)
66 std r17,((JB_GPRS+3)*8)(3)
67 stfd fp17,((JB_FPRS+3)*8)(3)
68 std r18,((JB_GPRS+4)*8)(3)
69 stfd fp18,((JB_FPRS+4)*8)(3)
70 std r19,((JB_GPRS+5)*8)(3)
71 stfd fp19,((JB_FPRS+5)*8)(3)
72 std r20,((JB_GPRS+6)*8)(3)
73 stfd fp20,((JB_FPRS+6)*8)(3)
74 std r21,((JB_GPRS+7)*8)(3)
75 stfd fp21,((JB_FPRS+7)*8)(3)
76 std r22,((JB_GPRS+8)*8)(3)
77 stfd fp22,((JB_FPRS+8)*8)(3)
78 std r23,((JB_GPRS+9)*8)(3)
79 stfd fp23,((JB_FPRS+9)*8)(3)
80 std r24,((JB_GPRS+10)*8)(3)
81 stfd fp24,((JB_FPRS+10)*8)(3)
82 std r25,((JB_GPRS+11)*8)(3)
83 stfd fp25,((JB_FPRS+11)*8)(3)
84 std r26,((JB_GPRS+12)*8)(3)
85 stfd fp26,((JB_FPRS+12)*8)(3)
86 std r27,((JB_GPRS+13)*8)(3)
87 stfd fp27,((JB_FPRS+13)*8)(3)
88 std r28,((JB_GPRS+14)*8)(3)
89 stfd fp28,((JB_FPRS+14)*8)(3)
90 std r29,((JB_GPRS+15)*8)(3)
91 stfd fp29,((JB_FPRS+15)*8)(3)
92 std r30,((JB_GPRS+16)*8)(3)
93 stfd fp30,((JB_FPRS+16)*8)(3)
94 std r31,((JB_GPRS+17)*8)(3)
95 stfd fp31,((JB_FPRS+17)*8)(3)
96 #ifndef __NO_VMX__
97 ld r5,.LC__dl_hwcap@toc(r2)
98 # ifdef SHARED
99 /* Load _rtld-global._dl_hwcap. */
100 ld r5,RTLD_GLOBAL_RO_DL_HWCAP_OFFSET(r5)
101 # else
102 ld r5,0(r5) /* Load extern _dl_hwcap. */
103 # endif
104 andis. r5,r5,(PPC_FEATURE_HAS_ALTIVEC >> 16)
105 beq L(no_vmx)
106 la r5,((JB_VRS)*8)(3)
107 andi. r6,r5,0xf
108 mfspr r0,VRSAVE
109 stw r0,((JB_VRSAVE)*8)(3)
110 addi r6,r5,16
111 beq+ L(aligned_save_vmx)
112 lvsr v0,0,r5
113 vspltisb v1,-1 /* set v1 to all 1's */
114 vspltisb v2,0 /* set v2 to all 0's */
115 vperm v3,v2,v1,v0 /* v3 contains shift mask with num all 1 bytes
116 on left = misalignment */
119 /* Special case for v20 we need to preserve what is in save area
120 below v20 before obliterating it */
121 lvx v5,0,r5
122 vperm v20,v20,v20,v0
123 vsel v5,v5,v20,v3
124 vsel v20,v20,v2,v3
125 stvx v5,0,r5
127 # define save_2vmx_partial(savevr,prev_savevr,hivr,shiftvr,maskvr,savegpr,addgpr) \
128 addi addgpr,addgpr,32; \
129 vperm savevr,savevr,savevr,shiftvr; \
130 vsel hivr,prev_savevr,savevr,maskvr; \
131 stvx hivr,0,savegpr;
133 save_2vmx_partial(v21,v20,v5,v0,v3,r6,r5)
134 save_2vmx_partial(v22,v21,v5,v0,v3,r5,r6)
135 save_2vmx_partial(v23,v22,v5,v0,v3,r6,r5)
136 save_2vmx_partial(v24,v23,v5,v0,v3,r5,r6)
137 save_2vmx_partial(v25,v24,v5,v0,v3,r6,r5)
138 save_2vmx_partial(v26,v25,v5,v0,v3,r5,r6)
139 save_2vmx_partial(v27,v26,v5,v0,v3,r6,r5)
140 save_2vmx_partial(v28,v27,v5,v0,v3,r5,r6)
141 save_2vmx_partial(v29,v28,v5,v0,v3,r6,r5)
142 save_2vmx_partial(v30,v29,v5,v0,v3,r5,r6)
144 /* Special case for r31 we need to preserve what is in save area
145 above v31 before obliterating it */
146 addi r5,r5,32
147 vperm v31,v31,v31,v0
148 lvx v4,0,r5
149 vsel v5,v30,v31,v3
150 stvx v5,0,r6
151 vsel v4,v31,v4,v3
152 stvx v4,0,r5
153 b L(no_vmx)
155 L(aligned_save_vmx):
156 stvx 20,0,r5
157 addi r5,r5,32
158 stvx 21,0,r6
159 addi r6,r6,32
160 stvx 22,0,r5
161 addi r5,r5,32
162 stvx 23,0,r6
163 addi r6,r6,32
164 stvx 24,0,r5
165 addi r5,r5,32
166 stvx 25,0,r6
167 addi r6,r6,32
168 stvx 26,0,r5
169 addi r5,r5,32
170 stvx 27,0,r6
171 addi r6,r6,32
172 stvx 28,0,r5
173 addi r5,r5,32
174 stvx 29,0,r6
175 addi r6,r6,32
176 stvx 30,0,r5
177 stvx 31,0,r6
178 L(no_vmx):
179 #endif
180 b JUMPTARGET (BP_SYM (__sigjmp_save))
181 END (BP_SYM (__sigsetjmp))