sysdeps/powerpc/powerpc64/fpu/s_truncf.S

   1 /* truncf function.  PowerPC64 version.
   2    Copyright (C) 2004 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21
  22         .section        ".toc","aw"
  23 .LC0:   /* 2**23 */
  24         .tc FD_41600000_0[TC],0x4160000000000000
  25 .LC2:   /* -0.0 */
  26         .tc FD_80000000_0[TC],0x8000000000000000
  27         .section        ".text"
  28
  29 /* float [fp1] truncf (float x [fp1])
  30    IEEE 1003.1 trunc function.  IEEE specifies "trunc to the integer
  31    value, in floating format, nearest to but no larger in magnitude
  32    then the argument."
  33    We set "round toward Zero" mode and trunc by adding +-2**23 then
  34    subtracting +-2**23.  */
  35
  36 ENTRY (__truncf)
  37         CALL_MCOUNT 0
  38         mffs    fp11            /* Save current FPU rounding mode.  */
  39         lfd     fp13,.LC0@toc(2)
  40         fabs    fp0,fp1
  41         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  42         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  43         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  44         bnllr-  cr7
  45         mtfsfi  7,1             /* Set rounding toward 0 mode.  */
  46         ble-    cr6,.L4
  47         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  48         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  49 .L9:
  50         mtfsf   0x01,fp11       /* restore previous truncing mode.  */
  51         blr
  52 .L4:
  53         bge-    cr6,.L9         /* if (x < 0.0)  */
  54         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  55         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  56         fcmpu   cr5,fp1,fp12    /* if (x > 0.0)  */
  57         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  58         bnelr+  cr5
  59         lfd     fp1,.LC2@toc(2) /* x must be -0.0 for the 0.0 case.  */
  60         blr
  61         END (__truncf)
  62
  63 weak_alias (__truncf, truncf)
  64