sysdeps/powerpc/powerpc64/fpu/s_floorf.S

   1 /* float Floor function.  PowerPC64 version.
   2    Copyright (C) 2004 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21
  22         .section        ".toc","aw"
  23 .LC0:   /* 2**23 */
  24         .tc FD_41600000_0[TC],0x4160000000000000
  25         .section        ".text"
  26
  27 ENTRY (__floorf)
  28         CALL_MCOUNT 0
  29         mffs    fp11            /* Save current FPU rounding mode.  */
  30         lfd     fp13,.LC0@toc(2)
  31         fabs    fp0,fp1
  32         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  33         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  34         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  35         bnllr-  cr7
  36         mtfsfi  7,3             /* Set rounding mode toward -inf.  */
  37         ble-    cr6,.L4
  38         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  39         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  40         fcmpu   cr5,fp1,fp12    /* if (x > 0.0)  */
  41         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  42         bnelr+  cr5
  43         fmr     fp1,fp12        /* x must be +0.0 for the 0.0 case.  */
  44         blr
  45 .L4:
  46         bge-    cr6,.L9         /* if (x < 0.0)  */
  47         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  48         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  49 .L9:
  50         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  51         blr
  52         END (__floorf)
  53
  54 weak_alias (__floorf, floorf)
  55