sysdeps/powerpc/powerpc32/fpu/s_rint.S

   1 /* Round to int floating-point values.  PowerPC32 version.
   2    Copyright (C) 2004 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 /* This has been coded in assembler because GCC makes such a mess of it
  21    when it's coded in C.  */
  22
  23 #include <sysdep.h>
  24
  25         .section        .rodata
  26         .align 3
  27         .type   TWO52.0,@object
  28         .size   TWO52.0,8
  29 TWO52.0:
  30         .long 0x43300000
  31         .long 0
  32
  33         .section        .rodata.cst8,"aM",@progbits,8
  34         .align 3
  35 .LC0:   /* 2**52 */
  36         .long 0x43300000
  37         .long 0
  38
  39         .section        ".text"
  40 ENTRY (__rint)
  41 #ifdef SHARED
  42         mflr    r11
  43         bl      _GLOBAL_OFFSET_TABLE_@local-4
  44         mflr    r10
  45         lwz     r9,.LC0@got(10)
  46         mtlr    r11
  47         lfd     fp13,0(r9)
  48 #else
  49         lis     r9,.LC0@ha
  50         lfd     fp13,.LC0@l(r9)
  51 #endif
  52         fabs    fp0,fp1
  53         fsub    fp12,fp13,fp13  /* generate 0.0  */
  54         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  55         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  56         bnllr-  cr7
  57         bng-    cr6,.L4
  58         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  59         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  60         blr
  61 .L4:
  62         bnllr-  cr6             /* if (x < 0.0)  */
  63         fsub    fp1,fp13,fp1    /* x = TWO52 - x;  */
  64         fsub    fp0,fp1,fp13    /* x = - (x - TWO52);  */
  65         fneg    fp1,fp0
  66         blr
  67         END (__rint)
  68
  69 weak_alias (__rint, rint)
  70
  71 #ifdef NO_LONG_DOUBLE
  72 weak_alias (__rint, rintl)
  73 strong_alias (__rint, __rintl)
  74 #endif