sysdeps/powerpc/powerpc32/fpu/s_floor.S

   1 /* Floor function.  PowerPC32 version.
   2    Copyright (C) 2004 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21
  22         .section        .rodata
  23         .align 3
  24         .type   TWO52.0,@object
  25         .size   TWO52.0,8
  26 TWO52.0:
  27         .long 0x43300000
  28         .long 0
  29
  30         .section        .rodata.cst8,"aM",@progbits,8
  31         .align 3
  32 .LC0:   /* 2**52 */
  33         .long 0x43300000
  34         .long 0
  35
  36         .section        ".text"
  37 ENTRY (__floor)
  38         mffs    fp11            /* Save current FPU rounding mode.  */
  39 #ifdef SHARED
  40         mflr    r11
  41         bl      _GLOBAL_OFFSET_TABLE_@local-4
  42         mflr    r10
  43         lwz     r9,.LC0@got(10)
  44         mtlr    r11
  45         lfd     fp13,0(r9)
  46 #else
  47         lis     r9,.LC0@ha
  48         lfd     fp13,.LC0@l(r9)
  49 #endif
  50         fabs    fp0,fp1
  51         fsub    fp12,fp13,fp13  /* generate 0.0  */
  52         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  53         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  54         bnllr-  cr7
  55         mtfsfi  7,3             /* Set rounding mode toward -inf.  */
  56         ble-    cr6,.L4
  57         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  58         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  59         fcmpu   cr5,fp1,fp12    /* if (x > 0.0)  */
  60         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  61         bnelr+  cr5
  62         fmr     fp1,fp12        /* x must be +0.0 for the 0.0 case.  */
  63         blr
  64 .L4:
  65         bge-    cr6,.L9         /* if (x < 0.0)  */
  66         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  67         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  68 .L9:
  69         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  70         blr
  71         END (__floor)
  72
  73 weak_alias (__floor, floor)
  74
  75 #ifdef NO_LONG_DOUBLE
  76 weak_alias (__floor, floorl)
  77 strong_alias (__floor, __floorl)
  78 #endif