sysdeps/powerpc/powerpc32/fpu/s_ceil.S

   1 /* ceil function.  PowerPC32 version.
   2    Copyright (C) 2004 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21
  22         .section        .rodata
  23         .align 3
  24         .type   TWO52.0,@object
  25         .size   TWO52.0,8
  26 TWO52.0:
  27         .long 0x43300000
  28         .long 0
  29         .type   NEGZERO.0,@object
  30         .size   NEGZERO.0,8
  31 NEGZERO.0:
  32         .long 0x80000000
  33         .long 0
  34
  35         .section        .rodata.cst8,"aM",@progbits,8
  36         .align 3
  37 .LC0:   /* 2**52 */
  38         .long 0x43300000
  39         .long 0
  40 .LC1:   /* -0.0 */
  41         .long 0x80000000
  42         .long 0
  43
  44         .section        ".text"
  45 ENTRY (__ceil)
  46         mffs    fp11            /* Save current FPU rounding mode.  */
  47 #ifdef SHARED
  48         mflr    r11
  49         bl      _GLOBAL_OFFSET_TABLE_@local-4
  50         mflr    r10
  51         lwz     r9,.LC0@got(10)
  52         mtlr    r11
  53         lfd     fp13,0(r9)
  54 #else
  55         lis     r9,.LC0@ha
  56         lfd     fp13,.LC0@l(r9)
  57 #endif
  58         fabs    fp0,fp1
  59         fsub    fp12,fp13,fp13  /* generate 0.0  */
  60         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  61         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  62         bnllr-  cr7
  63         mtfsfi  7,2             /* Set rounding mode toward +inf.  */
  64         ble-    cr6,.L4
  65         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  66         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  67 .L9:
  68         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  69         blr
  70 .L4:
  71         bge-    cr6,.L9         /* if (x < 0.0)  */
  72         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  73         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  74         fcmpu   cr5,fp1,fp12    /* if (x > 0.0)  */
  75         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  76         bnelr+  cr5
  77 #ifdef SHARED
  78         mflr    r11
  79         bl      _GLOBAL_OFFSET_TABLE_@local-4
  80         mflr    r10
  81         lwz     r9,.LC1@got(10)
  82         mtlr    r11
  83         lfd     fp1,0(r9)
  84 #else
  85         lis     r9,.LC1@ha
  86         lfd     fp1,.LC1@l(r9)
  87 #endif
  88         blr
  89         END (__ceil)
  90
  91 weak_alias (__ceil, ceil)
  92
  93 #ifdef NO_LONG_DOUBLE
  94 weak_alias (__ceil, ceill)
  95 strong_alias (__ceil, __ceill)
  96 #endif