| blob | 3a497fcf4cf5076fdafefea4283e7f22e07c1979 |
1 .file "tan.s"
3 // Copyright (C) 2000, 2001, Intel Corporation
4 // All rights reserved.
5 //
6 // Contributed 2/2/2000 by John Harrison, Ted Kubaska, Bob Norin, Shane Story,
7 // and Ping Tak Peter Tang of the Computational Software Lab, Intel Corporation.
8 //
9 // Redistribution and use in source and binary forms, with or without
10 // modification, are permitted provided that the following conditions are
11 // met:
12 //
13 // * Redistributions of source code must retain the above copyright
14 // notice, this list of conditions and the following disclaimer.
15 //
16 // * Redistributions in binary form must reproduce the above copyright
17 // notice, this list of conditions and the following disclaimer in the
18 // documentation and/or other materials provided with the distribution.
19 //
20 // * The name of Intel Corporation may not be used to endorse or promote
21 // products derived from this software without specific prior written
22 // permission.
23 //
24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
35 //
36 // Intel Corporation is the author of this code, and requests that all
37 // problem reports or change requests be submitted to it directly at
38 // http://developer.intel.com/opensource.
39 //
40 // History
41 //==============================================================
42 // 2/02/00: Initial version
43 // 4/04/00 Unwind support added
44 // 12/27/00 Improved speed
45 //
46 // API
47 //==============================================================
48 // double tan( double x);
49 //
50 // Overview of operation
51 //==============================================================
52 // If the input value in radians is |x| >= 1.xxxxx 2^10 call the
53 // older slower version.
54 //
55 // The new algorithm is used when |x| <= 1.xxxxx 2^9.
56 //
57 // Represent the input X as Nfloat * pi/2 + r
58 // where r can be negative and |r| <= pi/4
59 //
60 // tan_W = x * 2/pi
61 // Nfloat = round_int(tan_W)
62 //
63 // tan_r = x - Nfloat * (pi/2)_hi
64 // tan_r = tan_r - Nfloat * (pi/2)_lo
65 //
66 // We have two paths: p8, when Nfloat is even and p9. when Nfloat is odd.
67 // p8: tan(X) = tan(r)
68 // p9: tan(X) = -cot(r)
69 //
70 // Each is evaluated as a series. The p9 path requires 1/r.
71 //
72 // The coefficients used in the series are stored in a table as
73 // are the pi constants.
74 //
75 // Registers used
76 //==============================================================
77 //
78 // predicate registers used:
79 // p6-10
80 //
81 // floating-point registers used:
82 // f10-15, f32-105
83 // f8, input
84 //
85 // general registers used
86 // r14-18, r32-43
87 //
89 #include "libm_support.h"
91 // Assembly macros
92 //==============================================================
93 TAN_INV_PI_BY_2_2TO64 = f10
94 TAN_RSHF_2TO64 = f11
95 TAN_2TOM64 = f12
96 TAN_RSHF = f13
97 TAN_W_2TO64_RSH = f14
98 TAN_NFLOAT = f15
100 tan_Inv_Pi_by_2 = f32
101 tan_Pi_by_2_hi = f33
102 tan_Pi_by_2_lo = f34
105 tan_P0 = f35
106 tan_P1 = f36
107 tan_P2 = f37
108 tan_P3 = f38
109 tan_P4 = f39
110 tan_P5 = f40
111 tan_P6 = f41
112 tan_P7 = f42
113 tan_P8 = f43
114 tan_P9 = f44
115 tan_P10 = f45
116 tan_P11 = f46
117 tan_P12 = f47
118 tan_P13 = f48
119 tan_P14 = f49
120 tan_P15 = f50
122 tan_Q0 = f51
123 tan_Q1 = f52
124 tan_Q2 = f53
125 tan_Q3 = f54
126 tan_Q4 = f55
127 tan_Q5 = f56
128 tan_Q6 = f57
129 tan_Q7 = f58
130 tan_Q8 = f59
131 tan_Q9 = f60
132 tan_Q10 = f61
134 tan_r = f62
135 tan_rsq = f63
136 tan_rcube = f64
138 tan_v18 = f65
139 tan_v16 = f66
140 tan_v17 = f67
141 tan_v12 = f68
142 tan_v13 = f69
143 tan_v7 = f70
144 tan_v8 = f71
145 tan_v4 = f72
146 tan_v5 = f73
147 tan_v15 = f74
148 tan_v11 = f75
149 tan_v14 = f76
150 tan_v3 = f77
151 tan_v6 = f78
152 tan_v10 = f79
153 tan_v2 = f80
154 tan_v9 = f81
155 tan_v1 = f82
156 tan_int_Nfloat = f83
157 tan_Nfloat = f84
159 tan_NORM_f8 = f85
160 tan_W = f86
162 tan_y0 = f87
163 tan_d = f88
164 tan_y1 = f89
165 tan_dsq = f90
166 tan_y2 = f91
167 tan_d4 = f92
168 tan_inv_r = f93
170 tan_z1 = f94
171 tan_z2 = f95
172 tan_z3 = f96
173 tan_z4 = f97
174 tan_z5 = f98
175 tan_z6 = f99
176 tan_z7 = f100
177 tan_z8 = f101
178 tan_z9 = f102
179 tan_z10 = f103
180 tan_z11 = f104
181 tan_z12 = f105
184 /////////////////////////////////////////////////////////////
186 tan_GR_sig_inv_pi_by_2 = r14
187 tan_GR_rshf_2to64 = r15
188 tan_GR_exp_2tom64 = r16
189 tan_GR_n = r17
190 tan_GR_rshf = r18
192 tan_AD = r33
193 tan_GR_10009 = r34
194 tan_GR_17_ones = r35
195 tan_GR_N_odd_even = r36
196 tan_GR_N = r37
197 tan_signexp = r38
198 tan_exp = r39
199 tan_ADQ = r40
201 GR_SAVE_PFS = r41
202 GR_SAVE_B0 = r42
203 GR_SAVE_GP = r43
206 #ifdef _LIBC
207 .rodata
208 #else
209 .data
210 #endif
212 .align 16
214 double_tan_constants:
215 ASM_TYPE_DIRECTIVE(double_tan_constants,@object)
216 // data8 0xA2F9836E4E44152A, 0x00003FFE // 2/pi
217 data8 0xC90FDAA22168C234, 0x00003FFF // pi/2 hi
219 data8 0xBEEA54580DDEA0E1 // P14
220 data8 0x3ED3021ACE749A59 // P15
221 data8 0xBEF312BD91DC8DA1 // P12
222 data8 0x3EFAE9AFC14C5119 // P13
223 data8 0x3F2F342BF411E769 // P8
224 data8 0x3F1A60FC9F3B0227 // P9
225 data8 0x3EFF246E78E5E45B // P10
226 data8 0x3F01D9D2E782875C // P11
227 data8 0x3F8226E34C4499B6 // P4
228 data8 0x3F6D6D3F12C236AC // P5
229 data8 0x3F57DA1146DCFD8B // P6
230 data8 0x3F43576410FE3D75 // P7
231 data8 0x3FD5555555555555 // P0
232 data8 0x3FC11111111111C2 // P1
233 data8 0x3FABA1BA1BA0E850 // P2
234 data8 0x3F9664F4886725A7 // P3
235 ASM_SIZE_DIRECTIVE(double_tan_constants)
237 double_Q_tan_constants:
238 ASM_TYPE_DIRECTIVE(double_Q_tan_constants,@object)
239 data8 0xC4C6628B80DC1CD1, 0x00003FBF // pi/2 lo
240 data8 0x3E223A73BA576E48 // Q8
241 data8 0x3DF54AD8D1F2CA43 // Q9
242 data8 0x3EF66A8EE529A6AA // Q4
243 data8 0x3EC2281050410EE6 // Q5
244 data8 0x3E8D6BB992CC3CF5 // Q6
245 data8 0x3E57F88DE34832E4 // Q7
246 data8 0x3FD5555555555555 // Q0
247 data8 0x3F96C16C16C16DB8 // Q1
248 data8 0x3F61566ABBFFB489 // Q2
249 data8 0x3F2BBD77945C1733 // Q3
250 data8 0x3D927FB33E2B0E04 // Q10
251 ASM_SIZE_DIRECTIVE(double_Q_tan_constants)
255 .align 32
256 .global tan#
257 #ifdef _LIBC
258 .global __tan#
259 #endif
261 ////////////////////////////////////////////////////////
265 .section .text
266 .proc tan#
267 #ifdef _LIBC
268 .proc __tan#
269 #endif
270 .align 32
271 tan:
272 #ifdef _LIBC
273 __tan:
274 #endif
275 // The initial fnorm will take any unmasked faults and
276 // normalize any single/double unorms
278 { .mlx
279 alloc r32=ar.pfs,1,11,0,0
280 movl tan_GR_sig_inv_pi_by_2 = 0xA2F9836E4E44152A // significand of 2/pi
281 }
282 { .mlx
283 addl tan_AD = @ltoff(double_tan_constants), gp
284 movl tan_GR_rshf_2to64 = 0x47e8000000000000 // 1.1000 2^(63+63+1)
285 }
286 ;;
288 { .mfi
289 ld8 tan_AD = [tan_AD]
290 fnorm tan_NORM_f8 = f8
291 mov tan_GR_exp_2tom64 = 0xffff-64 // exponent of scaling factor 2^-64
292 }
293 { .mlx
294 nop.m 999
295 movl tan_GR_rshf = 0x43e8000000000000 // 1.1000 2^63 for right shift
296 }
297 ;;
300 // Form two constants we need
301 // 2/pi * 2^1 * 2^63, scaled by 2^64 since we just loaded the significand
302 // 1.1000...000 * 2^(63+63+1) to right shift int(W) into the significand
303 { .mmi
304 setf.sig TAN_INV_PI_BY_2_2TO64 = tan_GR_sig_inv_pi_by_2
305 setf.d TAN_RSHF_2TO64 = tan_GR_rshf_2to64
306 mov tan_GR_17_ones = 0x1ffff ;;
307 }
310 // Form another constant
311 // 2^-64 for scaling Nfloat
312 // 1.1000...000 * 2^63, the right shift constant
313 { .mmf
314 setf.exp TAN_2TOM64 = tan_GR_exp_2tom64
315 adds tan_ADQ = double_Q_tan_constants - double_tan_constants, tan_AD
316 fclass.m.unc p6,p0 = f8, 0x07 // Test for x=0
317 }
318 ;;
321 // Form another constant
322 // 2^-64 for scaling Nfloat
323 // 1.1000...000 * 2^63, the right shift constant
324 { .mmf
325 setf.d TAN_RSHF = tan_GR_rshf
326 ldfe tan_Pi_by_2_hi = [tan_AD],16
327 fclass.m.unc p7,p0 = f8, 0x23 // Test for x=inf
328 }
329 ;;
331 { .mfb
332 ldfe tan_Pi_by_2_lo = [tan_ADQ],16
333 fclass.m.unc p8,p0 = f8, 0xc3 // Test for x=nan
334 (p6) br.ret.spnt b0 ;; // Exit for x=0
335 }
337 { .mfi
338 ldfpd tan_P14,tan_P15 = [tan_AD],16
339 (p7) frcpa.s0 f8,p9=f0,f0 // Set qnan indef if x=inf
340 mov tan_GR_10009 = 0x10009
341 }
342 { .mib
343 ldfpd tan_Q8,tan_Q9 = [tan_ADQ],16
344 nop.i 999
345 (p7) br.ret.spnt b0 ;; // Exit for x=inf
346 }
348 { .mfi
349 ldfpd tan_P12,tan_P13 = [tan_AD],16
350 (p8) fma.d f8=f8,f1,f8 // Set qnan if x=nan
351 nop.i 999
352 }
353 { .mib
354 ldfpd tan_Q4,tan_Q5 = [tan_ADQ],16
355 nop.i 999
356 (p8) br.ret.spnt b0 ;; // Exit for x=nan
357 }
359 { .mmi
360 getf.exp tan_signexp = tan_NORM_f8
361 ldfpd tan_P8,tan_P9 = [tan_AD],16
362 nop.i 999 ;;
363 }
365 // Multiply x by scaled 2/pi and add large const to shift integer part of W to
366 // rightmost bits of significand
367 { .mfi
368 ldfpd tan_Q6,tan_Q7 = [tan_ADQ],16
369 fma.s1 TAN_W_2TO64_RSH = tan_NORM_f8,TAN_INV_PI_BY_2_2TO64,TAN_RSHF_2TO64
370 nop.i 999 ;;
371 }
373 { .mmi
374 ldfpd tan_P10,tan_P11 = [tan_AD],16
375 nop.m 999
376 and tan_exp = tan_GR_17_ones, tan_signexp ;;
377 }
380 // p7 is true if we must call DBX TAN
381 // p7 is true if f8 exp is > 0x10009 (which includes all ones
382 // NAN or inf)
383 { .mmi
384 ldfpd tan_Q0,tan_Q1 = [tan_ADQ],16
385 cmp.ge.unc p7,p0 = tan_exp,tan_GR_10009
386 nop.i 999 ;;
387 }
390 { .mmb
391 ldfpd tan_P4,tan_P5 = [tan_AD],16
392 nop.m 999
393 (p7) br.cond.spnt L(TAN_DBX) ;;
394 }
397 { .mmi
398 ldfpd tan_Q2,tan_Q3 = [tan_ADQ],16
399 nop.m 999
400 nop.i 999 ;;
401 }
405 // TAN_NFLOAT = Round_Int_Nearest(tan_W)
406 { .mfi
407 ldfpd tan_P6,tan_P7 = [tan_AD],16
408 fms.s1 TAN_NFLOAT = TAN_W_2TO64_RSH,TAN_2TOM64,TAN_RSHF
409 nop.i 999 ;;
410 }
413 { .mfi
414 ldfd tan_Q10 = [tan_ADQ]
415 nop.f 999
416 nop.i 999 ;;
417 }
420 { .mfi
421 ldfpd tan_P0,tan_P1 = [tan_AD],16
422 nop.f 999
423 nop.i 999 ;;
424 }
427 { .mfi
428 getf.sig tan_GR_n = TAN_W_2TO64_RSH
429 nop.f 999
430 nop.i 999 ;;
431 }
433 // tan_r = -tan_Nfloat * tan_Pi_by_2_hi + x
434 { .mfi
435 ldfpd tan_P2,tan_P3 = [tan_AD]
436 fnma.s1 tan_r = TAN_NFLOAT, tan_Pi_by_2_hi, tan_NORM_f8
437 nop.i 999 ;;
438 }
441 // p8 ==> even
442 // p9 ==> odd
443 { .mmi
444 and tan_GR_N_odd_even = 0x1, tan_GR_n ;;
445 nop.m 999
446 cmp.eq.unc p8,p9 = tan_GR_N_odd_even, r0 ;;
447 }
450 // tan_r = tan_r -tan_Nfloat * tan_Pi_by_2_lo
451 { .mfi
452 nop.m 999
453 fnma.s1 tan_r = TAN_NFLOAT, tan_Pi_by_2_lo, tan_r
454 nop.i 999 ;;
455 }
458 { .mfi
459 nop.m 999
460 fma.s1 tan_rsq = tan_r, tan_r, f0
461 nop.i 999 ;;
462 }
465 { .mfi
466 nop.m 999
467 (p9) frcpa.s1 tan_y0, p10 = f1,tan_r
468 nop.i 999 ;;
469 }
472 { .mfi
473 nop.m 999
474 (p8) fma.s1 tan_v18 = tan_rsq, tan_P15, tan_P14
475 nop.i 999
476 }
477 { .mfi
478 nop.m 999
479 (p8) fma.s1 tan_v4 = tan_rsq, tan_P1, tan_P0
480 nop.i 999 ;;
481 }
485 { .mfi
486 nop.m 999
487 (p8) fma.s1 tan_v16 = tan_rsq, tan_P13, tan_P12
488 nop.i 999
489 }
490 { .mfi
491 nop.m 999
492 (p8) fma.s1 tan_v17 = tan_rsq, tan_rsq, f0
493 nop.i 999 ;;
494 }
498 { .mfi
499 nop.m 999
500 (p8) fma.s1 tan_v12 = tan_rsq, tan_P9, tan_P8
501 nop.i 999
502 }
503 { .mfi
504 nop.m 999
505 (p8) fma.s1 tan_v13 = tan_rsq, tan_P11, tan_P10
506 nop.i 999 ;;
507 }
511 { .mfi
512 nop.m 999
513 (p8) fma.s1 tan_v7 = tan_rsq, tan_P5, tan_P4
514 nop.i 999
515 }
516 { .mfi
517 nop.m 999
518 (p8) fma.s1 tan_v8 = tan_rsq, tan_P7, tan_P6
519 nop.i 999 ;;
520 }
524 { .mfi
525 nop.m 999
526 (p9) fnma.s1 tan_d = tan_r, tan_y0, f1
527 nop.i 999
528 }
529 { .mfi
530 nop.m 999
531 (p8) fma.s1 tan_v5 = tan_rsq, tan_P3, tan_P2
532 nop.i 999 ;;
533 }
537 { .mfi
538 nop.m 999
539 (p9) fma.s1 tan_z11 = tan_rsq, tan_Q9, tan_Q8
540 nop.i 999
541 }
542 { .mfi
543 nop.m 999
544 (p9) fma.s1 tan_z12 = tan_rsq, tan_rsq, f0
545 nop.i 999 ;;
546 }
549 { .mfi
550 nop.m 999
551 (p8) fma.s1 tan_v15 = tan_v17, tan_v18, tan_v16
552 nop.i 999
553 }
554 { .mfi
555 nop.m 999
556 (p9) fma.s1 tan_z7 = tan_rsq, tan_Q5, tan_Q4
557 nop.i 999 ;;
558 }
561 { .mfi
562 nop.m 999
563 (p8) fma.s1 tan_v11 = tan_v17, tan_v13, tan_v12
564 nop.i 999
565 }
566 { .mfi
567 nop.m 999
568 (p9) fma.s1 tan_z8 = tan_rsq, tan_Q7, tan_Q6
569 nop.i 999 ;;
570 }
574 { .mfi
575 nop.m 999
576 (p8) fma.s1 tan_v14 = tan_v17, tan_v17, f0
577 nop.i 999
578 }
579 { .mfi
580 nop.m 999
581 (p9) fma.s1 tan_z3 = tan_rsq, tan_Q1, tan_Q0
582 nop.i 999 ;;
583 }
588 { .mfi
589 nop.m 999
590 (p8) fma.s1 tan_v3 = tan_v17, tan_v5, tan_v4
591 nop.i 999
592 }
593 { .mfi
594 nop.m 999
595 (p8) fma.s1 tan_v6 = tan_v17, tan_v8, tan_v7
596 nop.i 999 ;;
597 }
601 { .mfi
602 nop.m 999
603 (p9) fma.s1 tan_y1 = tan_y0, tan_d, tan_y0
604 nop.i 999
605 }
606 { .mfi
607 nop.m 999
608 (p9) fma.s1 tan_dsq = tan_d, tan_d, f0
609 nop.i 999 ;;
610 }
613 { .mfi
614 nop.m 999
615 (p9) fma.s1 tan_z10 = tan_z12, tan_Q10, tan_z11
616 nop.i 999
617 }
618 { .mfi
619 nop.m 999
620 (p9) fma.s1 tan_z9 = tan_z12, tan_z12,f0
621 nop.i 999 ;;
622 }
625 { .mfi
626 nop.m 999
627 (p9) fma.s1 tan_z4 = tan_rsq, tan_Q3, tan_Q2
628 nop.i 999
629 }
630 { .mfi
631 nop.m 999
632 (p9) fma.s1 tan_z6 = tan_z12, tan_z8, tan_z7
633 nop.i 999 ;;
634 }
638 { .mfi
639 nop.m 999
640 (p8) fma.s1 tan_v10 = tan_v14, tan_v15, tan_v11
641 nop.i 999 ;;
642 }
646 { .mfi
647 nop.m 999
648 (p9) fma.s1 tan_y2 = tan_y1, tan_d, tan_y0
649 nop.i 999
650 }
651 { .mfi
652 nop.m 999
653 (p9) fma.s1 tan_d4 = tan_dsq, tan_dsq, tan_d
654 nop.i 999 ;;
655 }
658 { .mfi
659 nop.m 999
660 (p8) fma.s1 tan_v2 = tan_v14, tan_v6, tan_v3
661 nop.i 999
662 }
663 { .mfi
664 nop.m 999
665 (p8) fma.s1 tan_v9 = tan_v14, tan_v14, f0
666 nop.i 999 ;;
667 }
670 { .mfi
671 nop.m 999
672 (p9) fma.s1 tan_z2 = tan_z12, tan_z4, tan_z3
673 nop.i 999
674 }
675 { .mfi
676 nop.m 999
677 (p9) fma.s1 tan_z5 = tan_z9, tan_z10, tan_z6
678 nop.i 999 ;;
679 }
682 { .mfi
683 nop.m 999
684 (p9) fma.s1 tan_inv_r = tan_d4, tan_y2, tan_y0
685 nop.i 999
686 }
687 { .mfi
688 nop.m 999
689 (p8) fma.s1 tan_rcube = tan_rsq, tan_r, f0
690 nop.i 999 ;;
691 }
695 { .mfi
696 nop.m 999
697 (p8) fma.s1 tan_v1 = tan_v9, tan_v10, tan_v2
698 nop.i 999
699 }
700 { .mfi
701 nop.m 999
702 (p9) fma.s1 tan_z1 = tan_z9, tan_z5, tan_z2
703 nop.i 999 ;;
704 }
708 { .mfi
709 nop.m 999
710 (p8) fma.d.s0 f8 = tan_v1, tan_rcube, tan_r
711 nop.i 999
712 }
713 { .mfb
714 nop.m 999
715 (p9) fms.d.s0 f8 = tan_r, tan_z1, tan_inv_r
716 br.ret.sptk b0 ;;
717 }
718 .endp tan#
719 ASM_SIZE_DIRECTIVE(tan)
722 .proc __libm_callout
723 __libm_callout:
724 L(TAN_DBX):
725 .prologue
727 { .mfi
728 nop.m 0
729 fmerge.s f9 = f0,f0
730 .save ar.pfs,GR_SAVE_PFS
731 mov GR_SAVE_PFS=ar.pfs
732 }
733 ;;
735 { .mfi
736 mov GR_SAVE_GP=gp
737 nop.f 0
738 .save b0, GR_SAVE_B0
739 mov GR_SAVE_B0=b0
740 }
742 .body
743 { .mfb
744 nop.m 999
745 nop.f 999
746 br.call.sptk.many b0=__libm_tan# ;;
747 }
750 { .mfi
751 mov gp = GR_SAVE_GP
752 fnorm.d f8 = f8
753 mov b0 = GR_SAVE_B0
754 }
755 ;;
758 { .mib
759 nop.m 999
760 mov ar.pfs = GR_SAVE_PFS
761 br.ret.sptk b0
762 ;;
763 }
766 .endp __libm_callout
767 ASM_SIZE_DIRECTIVE(__libm_callout)
769 .type __libm_tan#,@function
770 .global __libm_tan#