sysdeps/ia64/fpu/s_significandf.S

   1 .file "significandf.s"
   2
   3 // Copyright (C) 2000, 2001, Intel Corporation
   4 // All rights reserved.
   5 //
   6 // Contributed 2/2/2000 by John Harrison, Ted Kubaska, Bob Norin, Shane Story,
   7 // and Ping Tak Peter Tang of the Computational Software Lab, Intel Corporation.
   8 //
   9 // Redistribution and use in source and binary forms, with or without
  10 // modification, are permitted provided that the following conditions are
  11 // met:
  12 //
  13 // * Redistributions of source code must retain the above copyright
  14 // notice, this list of conditions and the following disclaimer.
  15 //
  16 // * Redistributions in binary form must reproduce the above copyright
  17 // notice, this list of conditions and the following disclaimer in the
  18 // documentation and/or other materials provided with the distribution.
  19 //
  20 // * The name of Intel Corporation may not be used to endorse or promote
  21 // products derived from this software without specific prior written
  22 // permission.
  23 //
  24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  35 //
  36 // Intel Corporation is the author of this code, and requests that all
  37 // problem reports or change requests be submitted to it directly at
  38 // http://developer.intel.com/opensource.
  39 //
  40 // History
  41 //==============================================================
  42 // 2/02/00: Initial version
  43 // 2/03/00: Modified to improve speed
  44 // 5/31/00: Fixed bug when x a double-extended denormal
  45 //
  46 // API
  47 //==============================================================
  48 // float significandf(float x)
  49 // Overview of operation
  50 //==============================================================
  51 // If x = sig * 2**n with 1 <= sig < 2
  52 // significandf returns sig
  53 //
  54 // predicate registers used:
  55 // p6, p7
  56 //
  57 // floating-point registers used:
  58 // f8, f9, f10
  59
  60 #include "libm_support.h"
  61
  62 .align 32
  63 .global significandf#
  64
  65 .section .text
  66 .proc  significandf#
  67 .align 32
  68
  69 significandf:
  70
  71 // qnan snan inf norm     unorm 0 -+
  72 // 1    1    1   0        0     1 11
  73
  74 // f10 gets f8(sign) with f1(exp,significand)
  75 { .mfi
  76       nop.m 999
  77 (p0)  fmerge.s       f10 = f8,f1
  78       nop.i 999
  79 }
  80 { .mfi
  81       nop.m 999
  82 (p0)  fnorm          f9  = f8
  83       nop.i 999 ;;
  84 }
  85
  86 // Test for denormal input
  87 { .mfi
  88       nop.m 999
  89 (p0)  fclass.m.unc   p7,p0 = f8, 0x0b
  90       nop.i 999 ;;
  91 }
  92
  93 // p6 = TRUE ==> x is not (nan,inf,0)
  94 //               return sign(f8) exp(f1) significand(f8)
  95 // else          x is (nan,inf,0)
  96 //               return sign(f8) exp(f8) significand(f8), normalized.
  97 { .mfi
  98       nop.m 999
  99 (p0)  fclass.m.unc   p0,p6 = f8, 0xe7
 100       nop.i 999 ;;
 101 }
 102
 103 { .mmb
 104       nop.m 999
 105       nop.m 999
 106 (p7)  br.cond.spnt L(SIGNIFICAND_DENORM) ;; // Branch if x denormal
 107 }
 108
 109 { .mfi
 110       nop.m 999
 111 (p6)  fmerge.se      f8 = f10,f8
 112       nop.i 999 ;;
 113 }
 114
 115 { .mfb
 116       nop.m 999
 117 (p0)  fnorm.s        f8 = f8
 118 (p0)  br.ret.sptk    b0 ;;
 119 }
 120
 121 L(SIGNIFICAND_DENORM):
 122 // Here if x denorm
 123 { .mfi
 124       nop.m 999
 125 (p0)  fmerge.se      f8 = f10,f9
 126       nop.i 999 ;;
 127 }
 128
 129 // Check if fnorm(x) still denormal, means x double-extended denormal
 130 { .mfi
 131       nop.m 999
 132 (p0)  fclass.m.unc   p7,p0 = f9, 0x0b
 133       nop.i 999 ;;
 134 }
 135
 136 // This will be the final result unless x double-extended denormal
 137 { .mfi
 138       nop.m 999
 139 (p0)  fnorm.s        f8 = f8
 140       nop.i 999 ;;
 141 }
 142
 143 // If x double-extended denorm, then significand ok, but must merge in
 144 //    correct signexp
 145 { .mfi
 146       nop.m 999
 147 (p7)  fmerge.se      f8 = f10,f8
 148       nop.i 999 ;;
 149 }
 150
 151 // Final normalization if x double-extended denorm
 152 { .mfb
 153       nop.m 999
 154 (p7)  fnorm.s        f8 = f8
 155 (p0)  br.ret.sptk    b0 ;;
 156 }
 157
 158 .endp significandf
 159 ASM_SIZE_DIRECTIVE(significandf)