sysdeps/ia64/fpu/s_rintl.S

   1 .file "rintl.s"
   2
   3 // Copyright (C) 2000, 2001, Intel Corporation
   4 // All rights reserved.
   5 //
   6 // Contributed 2/2/2000 by John Harrison, Ted Kubaska, Bob Norin, Shane Story,
   7 // and Ping Tak Peter Tang of the Computational Software Lab, Intel Corporation.
   8 //
   9 // Redistribution and use in source and binary forms, with or without
  10 // modification, are permitted provided that the following conditions are
  11 // met:
  12 //
  13 // * Redistributions of source code must retain the above copyright
  14 // notice, this list of conditions and the following disclaimer.
  15 //
  16 // * Redistributions in binary form must reproduce the above copyright
  17 // notice, this list of conditions and the following disclaimer in the
  18 // documentation and/or other materials provided with the distribution.
  19 //
  20 // * The name of Intel Corporation may not be used to endorse or promote
  21 // products derived from this software without specific prior written
  22 // permission.
  23 //
  24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  35 //
  36 // Intel Corporation is the author of this code, and requests that all
  37 // problem reports or change requests be submitted to it directly at
  38 // http://developer.intel.com/opensource.
  39 //
  40 // History
  41 //==============================================================
  42 // 2/02/00: Initial version
  43 // 5/24/00  Fixed case of 2^63 - 1 + 0.5 (0x1007dffffffffffffffff)
  44 // 2/08/01  Corrected behavior for all rounding modes.
  45 //
  46 // API
  47 //==============================================================
  48 // long double rintl(long double x)
  49
  50 #include "libm_support.h"
  51
  52 //
  53 // general registers used:
  54 //
  55 rint_GR_FFFF      = r14
  56 rint_GR_signexp   = r15
  57 rint_GR_exponent  = r16
  58 rint_GR_17ones    = r17
  59 rint_GR_10033     = r18
  60 rint_GR_fpsr      = r19
  61 rint_GR_rcs0      = r20
  62 rint_GR_rcs0_mask = r21
  63
  64
  65 // predicate registers used:
  66 // p6-11
  67
  68 // floating-point registers used:
  69
  70 RINT_NORM_f8      = f9
  71 RINT_FFFF         = f10
  72 RINT_INEXACT      = f11
  73 RINT_FLOAT_INT_f8 = f12
  74 RINT_INT_f8       = f13
  75 RINT_SIGNED_FLOAT_INT_f8 = f14
  76
  77 // Overview of operation
  78 //==============================================================
  79
  80 // long double rintl(long double x)
  81 // Return an integer value (represented as a long double) that is x rounded to integer in current
  82 // rounding mode
  83 // Inexact is set if x != rintl(x)
  84 // *******************************************************************************
  85
  86 // Set denormal flag for denormal input and
  87 // and take denormal fault if necessary.
  88
  89 // Is the input an integer value already?
  90
  91 // double_extended
  92 // if the exponent is >= 1003e => 3F(true) = 63(decimal)
  93 // we have a significand of 64 bits 1.63-bits.
  94 // If we multiply by 2^63, we no longer have a fractional part
  95 // So input is an integer value already.
  96
  97 // double
  98 // if the exponent is >= 10033 => 34(true) = 52(decimal)
  99 // 34 + 3ff = 433
 100 // we have a significand of 53 bits 1.52-bits. (implicit 1)
 101 // If we multiply by 2^52, we no longer have a fractional part
 102 // So input is an integer value already.
 103
 104 // single
 105 // if the exponent is >= 10016 => 17(true) = 23(decimal)
 106 // we have a significand of 53 bits 1.52-bits. (implicit 1)
 107 // If we multiply by 2^52, we no longer have a fractional part
 108 // So input is an integer value already.
 109
 110 // If x is NAN, ZERO, or INFINITY, then  return
 111
 112 // qnan snan inf norm     unorm 0 -+
 113 // 1    1    1   0        0     1 11     0xe7
 114
 115
 116 .align 32
 117 .global rintl#
 118
 119 .section .text
 120 .proc  rintl#
 121 .align 32
 122
 123
 124 rintl:
 125 #ifdef _LIBC
 126 .global __rintl
 127 .type __rintl,@function
 128 __rintl:
 129 #endif
 130
 131 { .mfi
 132       mov rint_GR_fpsr = ar40           // Read the fpsr--need to check rc.s0
 133       fcvt.fx.s1     RINT_INT_f8  = f8
 134       addl            rint_GR_10033 = 0x1003e, r0
 135 }
 136 { .mfi
 137       mov        rint_GR_FFFF      = -1
 138       fnorm.s1        RINT_NORM_f8  = f8
 139       mov         rint_GR_17ones    = 0x1FFFF
 140 ;;
 141 }
 142
 143 { .mfi
 144       setf.sig    RINT_FFFF  = rint_GR_FFFF
 145       fclass.m.unc  p6,p0 = f8, 0xe7
 146       mov         rint_GR_rcs0_mask  = 0x0c00
 147 ;;
 148 }
 149
 150 { .mfb
 151         nop.m 999
 152 (p6)  fnorm f8 = f8
 153 (p6)  br.ret.spnt   b0    // Exit if x nan, inf, zero
 154 ;;
 155 }
 156
 157 { .mfi
 158         nop.m 999
 159       fcvt.xf         RINT_FLOAT_INT_f8   = RINT_INT_f8
 160         nop.i 999
 161 ;;
 162 }
 163
 164 { .mfi
 165       getf.exp rint_GR_signexp  = RINT_NORM_f8
 166       fcmp.eq.s0  p8,p0 = f8,f0      // Dummy op to set denormal
 167         nop.i 999
 168 ;;
 169 }
 170
 171
 172 { .mii
 173         nop.m 999
 174         nop.i 999
 175       and      rint_GR_exponent = rint_GR_signexp, rint_GR_17ones
 176 ;;
 177 }
 178
 179 { .mmi
 180       cmp.ge.unc      p7,p6 = rint_GR_exponent, rint_GR_10033
 181       and rint_GR_rcs0 = rint_GR_rcs0_mask, rint_GR_fpsr
 182         nop.i 999
 183 ;;
 184 }
 185
 186 // Check to see if s0 rounding mode is round to nearest.  If not then set s2
 187 // rounding mode to that of s0 and repeat conversions.
 188 // Must merge the original sign for cases where the result is zero or the input
 189 // is the largest that still has a fraction (0x1007dfffffffffff)
 190 L(RINT_COMMON):
 191 { .mfb
 192       cmp.ne   p11,p0 = rint_GR_rcs0, r0
 193 (p6) fmerge.s  RINT_SIGNED_FLOAT_INT_f8 = f8, RINT_FLOAT_INT_f8
 194 (p11) br.cond.spnt L(RINT_NOT_ROUND_NEAREST)  // Branch if not round to nearest
 195 ;;
 196 }
 197
 198 { .mfi
 199         nop.m 999
 200 (p6) fcmp.eq.unc.s1  p0,p8  = RINT_FLOAT_INT_f8, RINT_NORM_f8
 201         nop.i 999
 202 }
 203 { .mfi
 204         nop.m 999
 205 (p7) fnorm.s0   f8 = f8
 206         nop.i 999
 207 ;;
 208 }
 209
 210 { .mfi
 211       nop.m 999
 212 (p6) fnorm f8 = RINT_SIGNED_FLOAT_INT_f8
 213      nop.i 999
 214 ;;
 215 }
 216
 217 { .mfb
 218      nop.m 999
 219 (p8) fmpy.s0     RINT_INEXACT = RINT_FFFF,RINT_FFFF  // Dummy to set inexact
 220      br.ret.sptk    b0
 221 ;;
 222 }
 223
 224 L(RINT_NOT_ROUND_NEAREST):
 225 // Set rounding mode of s2 to that of s0
 226 { .mfi
 227       mov rint_GR_rcs0 = r0       // Clear so we don't come back here
 228       fsetc.s2     0x7f, 0x40
 229         nop.i 999
 230 ;;
 231 }
 232
 233 { .mfi
 234         nop.m 999
 235       fcvt.fx.s2     RINT_INT_f8  = f8
 236         nop.i 999
 237 ;;
 238 }
 239
 240 { .mfb
 241         nop.m 999
 242       fcvt.xf         RINT_FLOAT_INT_f8   = RINT_INT_f8
 243       br.cond.sptk  L(RINT_COMMON)
 244 ;;
 245 }
 246
 247
 248 .endp rintl
 249 ASM_SIZE_DIRECTIVE(rintl)
 250 #ifdef _LIBC
 251 ASM_SIZE_DIRECTIVE(__rintl)
 252 #endif