| blob | a3425414cf9c5355dbc4248a16b82550bd014d55 |
1 .file "acosf.s"
3 // Copyright (C) 2000, 2001, Intel Corporation
4 // All rights reserved.
5 //
6 // Contributed 2/2/2000 by John Harrison, Ted Kubaska, Bob Norin, Shane Story,
7 // and Ping Tak Peter Tang of the Computational Software Lab, Intel Corporation.
8 //
9 // Redistribution and use in source and binary forms, with or without
10 // modification, are permitted provided that the following conditions are
11 // met:
12 //
13 // * Redistributions of source code must retain the above copyright
14 // notice, this list of conditions and the following disclaimer.
15 //
16 // * Redistributions in binary form must reproduce the above copyright
17 // notice, this list of conditions and the following disclaimer in the
18 // documentation and/or other materials provided with the distribution.
19 //
20 // * The name of Intel Corporation may not be used to endorse or promote
21 // products derived from this software without specific prior written
22 // permission.
23 //
24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
35 //
36 // Intel Corporation is the author of this code, and requests that all
37 // problem reports or change requests be submitted to it directly at
38 // http://developer.intel.com/opensource.
40 // History
41 //==============================================================
42 // 2/02/00 Initial revision
43 // 6/28/00 Improved speed
44 // 6/31/00 Changed register allocation because of some duplicate macros
45 // moved nan exit bundle up to gain a cycle.
46 // 8/15/00 Bundle added after call to __libm_error_support to properly
47 // set [the previously overwritten] GR_Parameter_RESULT.
48 // 8/17/00 Changed predicate register macro-usage to direct predicate
49 // names due to an assembler bug.
50 // 10/17/00 Improved speed of x=0 and x=1 paths, set D flag if x denormal.
53 // Description
54 //=========================================
55 // The acosf function computes the principle value of the arc sine of x.
56 // A doman error occurs for arguments not in the range [-1,+1].
58 // The acosf function returns the arc cosine in the range [0, +pi] radians.
59 // acos(1) returns +0
60 // acos(x) returns a Nan and raises the invalid exception for |x| >1
62 // |x| <= sqrt(2)/2. get Ax and Bx
64 // poly_p1 = x p1
65 // poly_p3 = x2 p4 + p3
66 // poly_p1 = x2 (poly_p1) + x = x2(x p1) + x
67 // poly_p2 = x2( poly_p3) + p2 = x2(x2 p4 + p3) + p2
69 // poly_Ax = x5(x2( poly_p3) + p2) + x2(x p1) + x
70 // = x5(x2(x2 p4 + p3) + p2) + x2(x p1) + x
72 // poly_p7 = x2 p8 + p7
73 // poly_p5 = x2 p6 + p5
75 // poly_p7 = x4 p9 + (x2 p8 + p7)
76 // poly_Bx = x4 (x4 p9 + (x2 p8 + p7)) + x2 p6 + p5
78 // sinf1 = x11(x4 (x4 p9 + (x2 p8 + p7)) + x2 p6 + p5) + x5(x2(x2 p4 + p3) + p2) + x2(x p1) + x
79 // = x19 p9 + x17 p8 + x15 p7 x13 p6 + x11 p5 + x9 p4 + x7 p3 + x5 p2 + x3 p1 + x
80 // answer1 = pi/2 - sinf1
84 // |x| > sqrt(2)/2
86 // Get z = sqrt(1-x2)
88 // Get polynomial in t = 1-x2
90 // t2 = t t
91 // t4 = t2 t2
93 // poly_p4 = t p5 + p4
94 // poly_p1 = t p1 + 1
96 // poly_p6 = t p7 + p6
97 // poly_p2 = t p3 + p2
99 // poly_p8 = t p9 + p8
101 // poly_p4 = t2 poly_p6 + poly_p4
102 // = t2 (t p7 + p6) + (t p5 + p4)
104 // poly_p2 = t2 poly_p2 + poly_p1
105 // = t2 (t p3 + p2) + (t p1 + 1)
107 // poly_p4 = t4 poly_p8 + poly_p4
108 // = t4 (t p9 + p8) + (t2 (t p7 + p6) + (t p5 + p4))
110 // P(t) = poly_p2 + t4 poly_p8
111 // = t2 (t p3 + p2) + (t p1 + 1) + t4 (t4 (t p9 + p8) + (t2 (t p7 + p6) + (t p5 + p4)))
112 // = t3 p3 + t2 p2 + t p1 + 1 + t9 p9 + t8 p8 + t7 p7 + t6 p6 + t5 p5 + t4 p4
115 // answer2 = sign(x) z P(t) if x>0
116 // = sign(x) z P(t) + pi if x<0
118 #include "libm_support.h"
120 //
121 // Assembly macros
122 //=========================================
124 // predicate registers
125 //acosf_pred_LEsqrt2by2 = p7
126 //acosf_pred_GTsqrt2by2 = p8
128 // integer registers
129 ACOSF_Addr1 = r33
130 ACOSF_Addr2 = r34
131 ACOSF_GR_1by2 = r35
133 ACOSF_GR_3by2 = r36
134 ACOSF_GR_5by2 = r37
136 GR_SAVE_B0 = r38
137 GR_SAVE_PFS = r39
138 GR_SAVE_GP = r40
140 GR_Parameter_X = r41
141 GR_Parameter_Y = r42
142 GR_Parameter_RESULT = r43
143 GR_Parameter_TAG = r44
145 // floating point registers
147 acosf_y = f32
148 acosf_abs_x = f33
149 acosf_x2 = f34
150 acosf_sgn_x = f35
152 acosf_1by2 = f36
153 acosf_3by2 = f37
154 acosf_5by2 = f38
155 acosf_coeff_P3 = f39
156 acosf_coeff_P8 = f40
158 acosf_coeff_P1 = f41
159 acosf_coeff_P4 = f42
160 acosf_coeff_P5 = f43
161 acosf_coeff_P2 = f44
162 acosf_coeff_P7 = f45
164 acosf_coeff_P6 = f46
165 acosf_coeff_P9 = f47
166 acosf_x2 = f48
167 acosf_x3 = f49
168 acosf_x4 = f50
170 acosf_x8 = f51
171 acosf_x5 = f52
172 acosf_const_piby2 = f53
173 acosf_const_sqrt2by2 = f54
174 acosf_x11 = f55
176 acosf_poly_p1 = f56
177 acosf_poly_p3 = f57
178 acosf_sinf1 = f58
179 acosf_poly_p2 = f59
180 acosf_poly_Ax = f60
182 acosf_poly_p7 = f61
183 acosf_poly_p5 = f62
184 acosf_sgnx_t4 = f63
185 acosf_poly_Bx = f64
186 acosf_t = f65
188 acosf_yby2 = f66
189 acosf_B = f67
190 acosf_B2 = f68
191 acosf_Az = f69
192 acosf_dz = f70
194 acosf_Sz = f71
195 acosf_d2z = f72
196 acosf_Fz = f73
197 acosf_z = f74
198 acosf_sgnx_z = f75
200 acosf_t2 = f76
201 acosf_2poly_p4 = f77
202 acosf_2poly_p6 = f78
203 acosf_2poly_p1 = f79
204 acosf_2poly_p2 = f80
206 acosf_2poly_p8 = f81
207 acosf_t4 = f82
208 acosf_Pt = f83
209 acosf_sgnx_2poly_p2 = f84
210 acosf_sgn_x_piby2 = f85
212 acosf_poly_p7a = f86
213 acosf_2poly_p4a = f87
214 acosf_2poly_p4b = f88
215 acosf_2poly_p2a = f89
216 acosf_poly_p1a = f90
222 // Data tables
223 //==============================================================
225 #ifdef _LIBC
226 .rodata
227 #else
228 .data
229 #endif
231 .align 16
233 acosf_coeff_1_table:
234 ASM_TYPE_DIRECTIVE(acosf_coeff_1_table,@object)
235 data8 0x3FC5555607DCF816 // P1
236 data8 0x3F9CF81AD9BAB2C6 // P4
237 data8 0x3FC59E0975074DF3 // P7
238 data8 0xBFA6F4CC2780AA1D // P6
239 data8 0x3FC2DD45292E93CB // P9
240 data8 0x3fe6a09e667f3bcd // sqrt(2)/2
241 ASM_SIZE_DIRECTIVE(acosf_coeff_1_table)
243 acosf_coeff_2_table:
244 ASM_TYPE_DIRECTIVE(acosf_coeff_2_table,@object)
245 data8 0x3FA6F108E31EFBA6 // P3
246 data8 0xBFCA31BF175D82A0 // P8
247 data8 0x3FA30C0337F6418B // P5
248 data8 0x3FB332C9266CB1F9 // P2
249 data8 0x3ff921fb54442d18 // pi_by_2
250 ASM_SIZE_DIRECTIVE(acosf_coeff_2_table)
252 .align 32
253 .global acosf
254 ASM_TYPE_DIRECTIVE(acosf,@function)
256 .section .text
257 .proc acosf
258 .align 32
260 acosf:
262 // Load the addresses of the two tables.
263 // Then, load the coefficients and other constants.
265 { .mfi
266 alloc r32 = ar.pfs,1,8,4,0
267 fnma.s1 acosf_t = f8,f8,f1
268 dep.z ACOSF_GR_1by2 = 0x3f,24,8 // 0x3f000000
269 }
270 { .mfi
271 addl ACOSF_Addr1 = @ltoff(acosf_coeff_1_table),gp
272 fma.s1 acosf_x2 = f8,f8,f0
273 addl ACOSF_Addr2 = @ltoff(acosf_coeff_2_table),gp ;;
274 }
277 { .mfi
278 ld8 ACOSF_Addr1 = [ACOSF_Addr1]
279 fmerge.s acosf_abs_x = f1,f8
280 dep ACOSF_GR_3by2 = -1,r0,22,8 // 0x3fc00000
281 }
282 { .mlx
283 nop.m 999
284 movl ACOSF_GR_5by2 = 0x40200000;;
285 }
289 { .mfi
290 setf.s acosf_1by2 = ACOSF_GR_1by2
291 fmerge.s acosf_sgn_x = f8,f1
292 nop.i 999
293 }
294 { .mfi
295 ld8 ACOSF_Addr2 = [ACOSF_Addr2]
296 nop.f 0
297 nop.i 999;;
298 }
301 { .mfi
302 setf.s acosf_5by2 = ACOSF_GR_5by2
303 fcmp.lt.s1 p11,p12 = f8,f0
304 nop.i 999;;
305 }
307 { .mmf
308 ldfpd acosf_coeff_P1,acosf_coeff_P4 = [ACOSF_Addr1],16
309 setf.s acosf_3by2 = ACOSF_GR_3by2
310 fclass.m.unc p8,p0 = f8, 0xc3 ;; //@qnan | @snan
311 }
314 { .mfi
315 ldfpd acosf_coeff_P7,acosf_coeff_P6 = [ACOSF_Addr1],16
316 fma.s1 acosf_t2 = acosf_t,acosf_t,f0
317 nop.i 999
318 }
319 { .mfi
320 ldfpd acosf_coeff_P3,acosf_coeff_P8 = [ACOSF_Addr2],16
321 fma.s1 acosf_x4 = acosf_x2,acosf_x2,f0
322 nop.i 999;;
323 }
326 { .mfi
327 ldfpd acosf_coeff_P9,acosf_const_sqrt2by2 = [ACOSF_Addr1]
328 fclass.m.unc p10,p0 = f8, 0x07 //@zero
329 nop.i 999
330 }
331 { .mfi
332 ldfpd acosf_coeff_P5,acosf_coeff_P2 = [ACOSF_Addr2],16
333 fma.s1 acosf_x3 = f8,acosf_x2,f0
334 nop.i 999;;
335 }
338 { .mfi
339 ldfd acosf_const_piby2 = [ACOSF_Addr2]
340 frsqrta.s1 acosf_B,p0 = acosf_t
341 nop.i 999
342 }
343 { .mfb
344 nop.m 999
345 (p8) fma.s f8 = f8,f1,f0
346 (p8) br.ret.spnt b0 ;; // Exit if x=nan
347 }
350 { .mfb
351 nop.m 999
352 fcmp.eq.s1 p6,p0 = acosf_abs_x,f1
353 (p10) br.cond.spnt L(ACOSF_ZERO) ;; // Branch if x=0
354 }
356 { .mfi
357 nop.m 999
358 fcmp.gt.s1 p9,p0 = acosf_abs_x,f1
359 nop.i 999;;
360 }
362 { .mfi
363 nop.m 999
364 fma.s1 acosf_x8 = acosf_x4,acosf_x4,f0
365 nop.i 999
366 }
367 { .mfb
368 nop.m 999
369 fma.s1 acosf_t4 = acosf_t2,acosf_t2,f0
370 (p6) br.cond.spnt L(ACOSF_ABS_ONE) ;; // Branch if |x|=1
371 }
373 { .mfi
374 nop.m 999
375 fma.s1 acosf_x5 = acosf_x2,acosf_x3,f0
376 nop.i 999
377 }
378 { .mfb
379 (p9) mov GR_Parameter_TAG = 59
380 fma.s1 acosf_yby2 = acosf_t,acosf_1by2,f0
381 (p9) br.cond.spnt __libm_error_region ;; // Branch if |x|>1
382 }
385 { .mfi
386 nop.m 999
387 fma.s1 acosf_Az = acosf_t,acosf_B,f0
388 nop.i 999
389 }
390 { .mfi
391 nop.m 999
392 fma.s1 acosf_B2 = acosf_B,acosf_B,f0
393 nop.i 999;;
394 }
396 { .mfi
397 nop.m 999
398 fma.s1 acosf_poly_p1 = f8,acosf_coeff_P1,f0
399 nop.i 999
400 }
401 { .mfi
402 nop.m 999
403 fma.s1 acosf_2poly_p1 = acosf_coeff_P1,acosf_t,f1
404 nop.i 999;;
405 }
407 { .mfi
408 nop.m 999
409 fma.s1 acosf_poly_p3 = acosf_coeff_P4,acosf_x2,acosf_coeff_P3
410 nop.i 999
411 }
412 { .mfi
413 nop.m 999
414 fma.s1 acosf_2poly_p6 = acosf_coeff_P7,acosf_t,acosf_coeff_P6
415 nop.i 999;;
416 }
418 { .mfi
419 nop.m 999
420 fma.s1 acosf_poly_p7 = acosf_x2,acosf_coeff_P8,acosf_coeff_P7
421 nop.i 999
422 }
423 { .mfi
424 nop.m 999
425 fma.s1 acosf_2poly_p2 = acosf_coeff_P3,acosf_t,acosf_coeff_P2
426 nop.i 999;;
427 }
430 { .mfi
431 nop.m 999
432 fma.s1 acosf_poly_p5 = acosf_x2,acosf_coeff_P6,acosf_coeff_P5
433 nop.i 999
434 }
435 { .mfi
436 nop.m 999
437 fma.s1 acosf_2poly_p4 = acosf_coeff_P5,acosf_t,acosf_coeff_P4
438 nop.i 999;;
439 }
442 { .mfi
443 nop.m 999
444 fma.s1 acosf_x11 = acosf_x8,acosf_x3,f0
445 nop.i 999
446 }
447 { .mfi
448 nop.m 999
449 fnma.s1 acosf_dz = acosf_B2,acosf_yby2,acosf_1by2
450 nop.i 999;;
451 }
454 { .mfi
455 nop.m 999
456 fma.s1 acosf_poly_p1a = acosf_x2,acosf_poly_p1,f8
457 nop.i 999
458 }
459 { .mfi
460 nop.m 999
461 fma.s1 acosf_2poly_p8 = acosf_coeff_P9,acosf_t,acosf_coeff_P8
462 nop.i 999;;
463 }
466 // Get the absolute value of x and determine the region in which x lies
468 { .mfi
469 nop.m 999
470 fcmp.le.s1 p7,p8 = acosf_abs_x,acosf_const_sqrt2by2
471 nop.i 999
472 }
473 { .mfi
474 nop.m 999
475 fma.s1 acosf_poly_p2 = acosf_x2,acosf_poly_p3,acosf_coeff_P2
476 nop.i 999;;
477 }
480 { .mfi
481 nop.m 999
482 fma.s1 acosf_poly_p7a = acosf_x4,acosf_coeff_P9,acosf_poly_p7
483 nop.i 999
484 }
485 { .mfi
486 nop.m 999
487 fma.s1 acosf_2poly_p2a = acosf_2poly_p2,acosf_t2,acosf_2poly_p1
488 nop.i 999;;
489 }
492 { .mfi
493 nop.m 999
494 (p8) fma.s1 acosf_sgnx_t4 = acosf_sgn_x,acosf_t4,f0
495 nop.i 999
496 }
497 { .mfi
498 nop.m 999
499 (p8) fma.s1 acosf_2poly_p4a = acosf_2poly_p6,acosf_t2,acosf_2poly_p4
500 nop.i 999;;
501 }
504 { .mfi
505 nop.m 999
506 (p8) fma.s1 acosf_Sz = acosf_5by2,acosf_dz,acosf_3by2
507 nop.i 999
508 }
509 { .mfi
510 nop.m 999
511 (p8) fma.s1 acosf_d2z = acosf_dz,acosf_dz,f0
512 nop.i 999;;
513 }
516 { .mfi
517 nop.m 999
518 (p8) fnma.d.s1 acosf_sgn_x_piby2 = acosf_sgn_x,acosf_const_piby2,acosf_const_piby2
519 nop.i 999
520 }
521 { .mfi
522 nop.m 999
523 (p7) fma.s1 acosf_poly_Ax = acosf_x5,acosf_poly_p2,acosf_poly_p1a
524 nop.i 999;;
525 }
527 { .mfi
528 nop.m 999
529 (p7) fma.s1 acosf_poly_Bx = acosf_x4,acosf_poly_p7a,acosf_poly_p5
530 nop.i 999
531 }
532 { .mfi
533 nop.m 999
534 (p8) fma.s1 acosf_sgnx_2poly_p2 = acosf_sgn_x,acosf_2poly_p2a,f0
535 nop.i 999;;
536 }
538 { .mfi
539 nop.m 999
540 fcmp.eq.s0 p6,p0 = f8,f0 // Only purpose is to set D if x denormal
541 nop.i 999
542 }
543 { .mfi
544 nop.m 999
545 (p8) fma.s1 acosf_2poly_p4b = acosf_2poly_p8,acosf_t4,acosf_2poly_p4a
546 nop.i 999;;
547 }
550 { .mfi
551 nop.m 999
552 (p8) fma.s1 acosf_Fz = acosf_d2z,acosf_Sz,acosf_dz
553 nop.i 999;;
554 }
557 { .mfi
558 nop.m 999
559 (p8) fma.d.s1 acosf_Pt = acosf_2poly_p4b,acosf_sgnx_t4,acosf_sgnx_2poly_p2
560 nop.i 999;;
561 }
563 { .mfi
564 nop.m 999
565 (p8) fma.d.s1 acosf_z = acosf_Az,acosf_Fz,acosf_Az
566 nop.i 999 ;;
567 }
569 { .mfi
570 nop.m 999
571 (p7) fma.d.s1 acosf_sinf1 = acosf_x11,acosf_poly_Bx,acosf_poly_Ax
572 nop.i 999;;
573 }
575 .pred.rel "mutex",p8,p7 //acosf_pred_GTsqrt2by2,acosf_pred_LEsqrt2by2
576 { .mfi
577 nop.m 999
578 (p8) fma.s f8 = acosf_z,acosf_Pt,acosf_sgn_x_piby2
579 nop.i 999
580 }
582 { .mfb
583 nop.m 999
584 (p7) fms.s f8 = acosf_const_piby2,f1,acosf_sinf1
585 br.ret.sptk b0 ;;
586 }
588 L(ACOSF_ZERO):
589 // Here if x=0
590 { .mfb
591 nop.m 999
592 fma.s f8 = acosf_const_piby2,f1,f0 // acosf(0)=pi/2
593 br.ret.sptk b0 ;;
594 }
597 L(ACOSF_ABS_ONE):
598 .pred.rel "mutex",p11,p12
599 // Here if |x|=1
600 { .mfi
601 nop.m 999
602 (p11) fma.s f8 = acosf_const_piby2,f1,acosf_const_piby2 // acosf(-1)=pi
603 nop.i 999
604 }
605 { .mfb
606 nop.m 999
607 (p12) fma.s f8 = f1,f0,f0 // acosf(1)=0
608 br.ret.sptk b0 ;;
609 }
611 .endp acosf
612 ASM_SIZE_DIRECTIVE(acosf)
615 // Stack operations when calling error support.
616 // (1) (2)
617 // sp -> + psp -> +
618 // | |
619 // | | <- GR_Y
620 // | |
621 // | <-GR_Y Y2->|
622 // | |
623 // | | <- GR_X
624 // | |
625 // sp-64 -> + sp -> +
626 // save ar.pfs save b0
627 // save gp
630 // Stack operations when calling error support.
631 // (3) (call) (4)
632 // psp -> + sp -> +
633 // | |
634 // R3 ->| <- GR_RESULT | -> f8
635 // | |
636 // Y2 ->| <- GR_Y |
637 // | |
638 // X1 ->| |
639 // | |
640 // sp -> + +
641 // restore gp
642 // restore ar.pfs
645 .proc __libm_error_region
646 __libm_error_region:
647 .prologue
648 { .mfi
649 add GR_Parameter_Y=-32,sp // Parameter 2 value
650 nop.f 999
651 .save ar.pfs,GR_SAVE_PFS
652 mov GR_SAVE_PFS=ar.pfs // Save ar.pfs
653 }
654 { .mfi
655 .fframe 64
656 add sp=-64,sp // Create new stack
657 nop.f 0
658 mov GR_SAVE_GP=gp // Save gp
659 };;
660 { .mmi
661 stfs [GR_Parameter_Y] = f1,16 // Store Parameter 2 on stack
662 add GR_Parameter_X = 16,sp // Parameter 1 address
663 .save b0, GR_SAVE_B0
664 mov GR_SAVE_B0=b0 // Save b0
665 };;
667 .body
668 { .mfi
669 nop.m 0
670 frcpa.s0 f9,p0 = f0,f0
671 nop.i 0
672 };;
674 { .mib
675 stfs [GR_Parameter_X] = f8 // Store Parameter 1 on stack
676 add GR_Parameter_RESULT = 0,GR_Parameter_Y
677 nop.b 0 // Parameter 3 address
678 }
679 { .mib
680 stfs [GR_Parameter_Y] = f9 // Store Parameter 3 on stack
681 add GR_Parameter_Y = -16,GR_Parameter_Y
682 br.call.sptk b0=__libm_error_support# // Call error handling function
683 };;
684 { .mmi
685 nop.m 0
686 nop.m 0
687 add GR_Parameter_RESULT = 48,sp
688 };;
690 { .mmi
691 ldfs f8 = [GR_Parameter_RESULT] // Get return result off stack
692 .restore sp
693 add sp = 64,sp // Restore stack pointer
694 mov b0 = GR_SAVE_B0 // Restore return address
695 };;
696 { .mib
697 mov gp = GR_SAVE_GP // Restore gp
698 mov ar.pfs = GR_SAVE_PFS // Restore ar.pfs
699 br.ret.sptk b0 // Return
700 };;
702 .endp __libm_error_region
703 ASM_SIZE_DIRECTIVE(__libm_error_region)
705 .type __libm_error_support#,@function
706 .global __libm_error_support#