sysdeps/i386/memcmp.S

   1 /* Compare two memory blocks for differences in the first COUNT bytes.
   2    Copyright (C) 1995, 1996, 1997, 2000, 2004 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include "asm-syntax.h"
  22 #include "bp-sym.h"
  23 #include "bp-asm.h"
  24
  25 #define PARMS   LINKAGE+4       /* space for 1 saved reg */
  26 #define BLK1    PARMS
  27 #define BLK2    BLK1+PTR_SIZE
  28 #define LEN     BLK2+PTR_SIZE
  29
  30         .text
  31 ENTRY (BP_SYM (memcmp))
  32         ENTER
  33
  34         pushl %esi              /* Save callee-safe registers.  */
  35         movl %edi, %edx         /* Note that %edx is not used and can
  36                                    so be used to save %edi.  It's faster.  */
  37
  38         movl BLK1(%esp), %esi
  39         movl BLK2(%esp), %edi
  40         movl LEN(%esp), %ecx
  41         CHECK_BOUNDS_LOW (%esi, BLK1(%esp))
  42         CHECK_BOUNDS_LOW (%edi, BLK2(%esp))
  43
  44         cld                     /* Set direction of comparison.  */
  45
  46         xorl %eax, %eax         /* Default result.  */
  47
  48         repe                    /* Compare at most %ecx bytes.  */
  49         cmpsb
  50         jz L(1)                 /* If even last byte was equal we return 0.  */
  51
  52         /* The memory blocks are not equal.  So result of the last
  53            subtraction is present in the carry flag.  It is set when
  54            the byte in block #2 is bigger.  In this case we have to
  55            return -1 (=0xffffffff), else 1.  */
  56         sbbl %eax, %eax         /* This is tricky.  %eax == 0 and carry is set
  57                                    or not depending on last subtraction.  */
  58
  59         /* At this point %eax == 0, if the byte of block #1 was bigger, and
  60            0xffffffff if the last byte of block #2 was bigger.  The latter
  61            case is already correct but the former needs a little adjustment.
  62            Note that the following operation does not change 0xffffffff.  */
  63         orb $1, %al             /* Change 0 to 1.  */
  64
  65 L(1):   CHECK_BOUNDS_HIGH (%esi, BLK1(%esp), jbe)
  66         CHECK_BOUNDS_HIGH (%edi, BLK2(%esp), jbe)
  67         popl %esi               /* Restore registers.  */
  68         movl %edx, %edi
  69
  70         LEAVE
  71         ret
  72 END (BP_SYM (memcmp))
  73
  74 #undef bcmp
  75 weak_alias (BP_SYM (memcmp), BP_SYM (bcmp))
  76 libc_hidden_builtin_def (BP_SYM (memcmp))