sysdeps/i386/fpu/e_pow.S

   1 /* ix87 specific implementation of pow function.
   2    Copyright (C) 1996, 1997, 1998, 1999, 2001, 2004
   3    Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, write to the Free
  19    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20    02111-1307 USA.  */
  21
  22 #include <machine/asm.h>
  23
  24 #ifdef __ELF__
  25         .section .rodata
  26 #else
  27         .text
  28 #endif
  29
  30         .align ALIGNARG(4)
  31         ASM_TYPE_DIRECTIVE(infinity,@object)
  32 inf_zero:
  33 infinity:
  34         .byte 0, 0, 0, 0, 0, 0, 0xf0, 0x7f
  35         ASM_SIZE_DIRECTIVE(infinity)
  36         ASM_TYPE_DIRECTIVE(zero,@object)
  37 zero:   .double 0.0
  38         ASM_SIZE_DIRECTIVE(zero)
  39         ASM_TYPE_DIRECTIVE(minf_mzero,@object)
  40 minf_mzero:
  41 minfinity:
  42         .byte 0, 0, 0, 0, 0, 0, 0xf0, 0xff
  43 mzero:
  44         .byte 0, 0, 0, 0, 0, 0, 0, 0x80
  45         ASM_SIZE_DIRECTIVE(minf_mzero)
  46         ASM_TYPE_DIRECTIVE(one,@object)
  47 one:    .double 1.0
  48         ASM_SIZE_DIRECTIVE(one)
  49         ASM_TYPE_DIRECTIVE(limit,@object)
  50 limit:  .double 0.29
  51         ASM_SIZE_DIRECTIVE(limit)
  52         ASM_TYPE_DIRECTIVE(p63,@object)
  53 p63:    .byte 0, 0, 0, 0, 0, 0, 0xe0, 0x43
  54         ASM_SIZE_DIRECTIVE(p63)
  55
  56 #ifdef PIC
  57 #define MO(op) op##@GOTOFF(%ecx)
  58 #define MOX(op,x,f) op##@GOTOFF(%ecx,x,f)
  59 #else
  60 #define MO(op) op
  61 #define MOX(op,x,f) op(,x,f)
  62 #endif
  63
  64         .text
  65 ENTRY(__ieee754_pow)
  66         fldl    12(%esp)        // y
  67         fxam
  68
  69 #ifdef  PIC
  70         call    1f
  71 1:      popl    %ecx
  72         addl    $_GLOBAL_OFFSET_TABLE_+[.-1b], %ecx
  73 #endif
  74
  75         fnstsw
  76         movb    %ah, %dl
  77         andb    $0x45, %ah
  78         cmpb    $0x40, %ah      // is y == 0 ?
  79         je      11f
  80
  81         cmpb    $0x05, %ah      // is y == ±inf ?
  82         je      12f
  83
  84         cmpb    $0x01, %ah      // is y == NaN ?
  85         je      30f
  86
  87         fldl    4(%esp)         // x : y
  88
  89         subl    $8,%esp
  90
  91         fxam
  92         fnstsw
  93         movb    %ah, %dh
  94         andb    $0x45, %ah
  95         cmpb    $0x40, %ah
  96         je      20f             // x is ±0
  97
  98         cmpb    $0x05, %ah
  99         je      15f             // x is ±inf
 100
 101         fxch                    // y : x
 102
 103         /* fistpll raises invalid exception for |y| >= 1L<<63.  */
 104         fld     %st             // y : y : x
 105         fabs                    // |y| : y : x
 106         fcompl  MO(p63)         // y : x
 107         fnstsw
 108         sahf
 109         jnc     2f
 110
 111         /* First see whether `y' is a natural number.  In this case we
 112            can use a more precise algorithm.  */
 113         fld     %st             // y : y : x
 114         fistpll (%esp)          // y : x
 115         fildll  (%esp)          // int(y) : y : x
 116         fucomp  %st(1)          // y : x
 117         fnstsw
 118         sahf
 119         jne     2f
 120
 121         /* OK, we have an integer value for y.  */
 122         popl    %eax
 123         popl    %edx
 124         orl     $0, %edx
 125         fstp    %st(0)          // x
 126         jns     4f              // y >= 0, jump
 127         fdivrl  MO(one)         // 1/x          (now referred to as x)
 128         negl    %eax
 129         adcl    $0, %edx
 130         negl    %edx
 131 4:      fldl    MO(one)         // 1 : x
 132         fxch
 133
 134 6:      shrdl   $1, %edx, %eax
 135         jnc     5f
 136         fxch
 137         fmul    %st(1)          // x : ST*x
 138         fxch
 139 5:      fmul    %st(0), %st     // x*x : ST*x
 140         shrl    $1, %edx
 141         movl    %eax, %ecx
 142         orl     %edx, %ecx
 143         jnz     6b
 144         fstp    %st(0)          // ST*x
 145         ret
 146
 147         /* y is ±NAN */
 148 30:     fldl    4(%esp)         // x : y
 149         fldl    MO(one)         // 1.0 : x : y
 150         fucomp  %st(1)          // x : y
 151         fnstsw
 152         sahf
 153         je      31f
 154         fxch                    // y : x
 155 31:     fstp    %st(1)
 156         ret
 157
 158         .align ALIGNARG(4)
 159 2:      /* y is a real number.  */
 160         fxch                    // x : y
 161         fldl    MO(one)         // 1.0 : x : y
 162         fld     %st(1)          // x : 1.0 : x : y
 163         fsub    %st(1)          // x-1 : 1.0 : x : y
 164         fabs                    // |x-1| : 1.0 : x : y
 165         fcompl  MO(limit)       // 1.0 : x : y
 166         fnstsw
 167         fxch                    // x : 1.0 : y
 168         sahf
 169         ja      7f
 170         fsub    %st(1)          // x-1 : 1.0 : y
 171         fyl2xp1                 // log2(x) : y
 172         jmp     8f
 173
 174 7:      fyl2x                   // log2(x) : y
 175 8:      fmul    %st(1)          // y*log2(x) : y
 176         fst     %st(1)          // y*log2(x) : y*log2(x)
 177         frndint                 // int(y*log2(x)) : y*log2(x)
 178         fsubr   %st, %st(1)     // int(y*log2(x)) : fract(y*log2(x))
 179         fxch                    // fract(y*log2(x)) : int(y*log2(x))
 180         f2xm1                   // 2^fract(y*log2(x))-1 : int(y*log2(x))
 181         faddl   MO(one)         // 2^fract(y*log2(x)) : int(y*log2(x))
 182         fscale                  // 2^fract(y*log2(x))*2^int(y*log2(x)) : int(y*log2(x))
 183         addl    $8, %esp
 184         fstp    %st(1)          // 2^fract(y*log2(x))*2^int(y*log2(x))
 185         ret
 186
 187
 188         // pow(x,±0) = 1
 189         .align ALIGNARG(4)
 190 11:     fstp    %st(0)          // pop y
 191         fldl    MO(one)
 192         ret
 193
 194         // y == ±inf
 195         .align ALIGNARG(4)
 196 12:     fstp    %st(0)          // pop y
 197         fldl    4(%esp)         // x
 198         fabs
 199         fcompl  MO(one)         // < 1, == 1, or > 1
 200         fnstsw
 201         andb    $0x45, %ah
 202         cmpb    $0x45, %ah
 203         je      13f             // jump if x is NaN
 204
 205         cmpb    $0x40, %ah
 206         je      14f             // jump if |x| == 1
 207
 208         shlb    $1, %ah
 209         xorb    %ah, %dl
 210         andl    $2, %edx
 211         fldl    MOX(inf_zero, %edx, 4)
 212         ret
 213
 214         .align ALIGNARG(4)
 215 14:     fldl    MO(one)
 216         ret
 217
 218         .align ALIGNARG(4)
 219 13:     fldl    4(%esp)         // load x == NaN
 220         ret
 221
 222         .align ALIGNARG(4)
 223         // x is ±inf
 224 15:     fstp    %st(0)          // y
 225         testb   $2, %dh
 226         jz      16f             // jump if x == +inf
 227
 228         // We must find out whether y is an odd integer.
 229         fld     %st             // y : y
 230         fistpll (%esp)          // y
 231         fildll  (%esp)          // int(y) : y
 232         fucompp                 // <empty>
 233         fnstsw
 234         sahf
 235         jne     17f
 236
 237         // OK, the value is an integer, but is the number of bits small
 238         // enough so that all are coming from the mantissa?
 239         popl    %eax
 240         popl    %edx
 241         andb    $1, %al
 242         jz      18f             // jump if not odd
 243         movl    %edx, %eax
 244         orl     %edx, %edx
 245         jns     155f
 246         negl    %eax
 247 155:    cmpl    $0x00200000, %eax
 248         ja      18f             // does not fit in mantissa bits
 249         // It's an odd integer.
 250         shrl    $31, %edx
 251         fldl    MOX(minf_mzero, %edx, 8)
 252         ret
 253
 254         .align ALIGNARG(4)
 255 16:     fcompl  MO(zero)
 256         addl    $8, %esp
 257         fnstsw
 258         shrl    $5, %eax
 259         andl    $8, %eax
 260         fldl    MOX(inf_zero, %eax, 1)
 261         ret
 262
 263         .align ALIGNARG(4)
 264 17:     shll    $30, %edx       // sign bit for y in right position
 265         addl    $8, %esp
 266 18:     shrl    $31, %edx
 267         fldl    MOX(inf_zero, %edx, 8)
 268         ret
 269
 270         .align ALIGNARG(4)
 271         // x is ±0
 272 20:     fstp    %st(0)          // y
 273         testb   $2, %dl
 274         jz      21f             // y > 0
 275
 276         // x is ±0 and y is < 0.  We must find out whether y is an odd integer.
 277         testb   $2, %dh
 278         jz      25f
 279
 280         fld     %st             // y : y
 281         fistpll (%esp)          // y
 282         fildll  (%esp)          // int(y) : y
 283         fucompp                 // <empty>
 284         fnstsw
 285         sahf
 286         jne     26f
 287
 288         // OK, the value is an integer, but is the number of bits small
 289         // enough so that all are coming from the mantissa?
 290         popl    %eax
 291         popl    %edx
 292         andb    $1, %al
 293         jz      27f             // jump if not odd
 294         cmpl    $0xffe00000, %edx
 295         jbe     27f             // does not fit in mantissa bits
 296         // It's an odd integer.
 297         // Raise divide-by-zero exception and get minus infinity value.
 298         fldl    MO(one)
 299         fdivl   MO(zero)
 300         fchs
 301         ret
 302
 303 25:     fstp    %st(0)
 304 26:     addl    $8, %esp
 305 27:     // Raise divide-by-zero exception and get infinity value.
 306         fldl    MO(one)
 307         fdivl   MO(zero)
 308         ret
 309
 310         .align ALIGNARG(4)
 311         // x is ±0 and y is > 0.  We must find out whether y is an odd integer.
 312 21:     testb   $2, %dh
 313         jz      22f
 314
 315         fld     %st             // y : y
 316         fistpll (%esp)          // y
 317         fildll  (%esp)          // int(y) : y
 318         fucompp                 // <empty>
 319         fnstsw
 320         sahf
 321         jne     23f
 322
 323         // OK, the value is an integer, but is the number of bits small
 324         // enough so that all are coming from the mantissa?
 325         popl    %eax
 326         popl    %edx
 327         andb    $1, %al
 328         jz      24f             // jump if not odd
 329         cmpl    $0xffe00000, %edx
 330         jae     24f             // does not fit in mantissa bits
 331         // It's an odd integer.
 332         fldl    MO(mzero)
 333         ret
 334
 335 22:     fstp    %st(0)
 336 23:     addl    $8, %esp        // Don't use 2 x pop
 337 24:     fldl    MO(zero)
 338         ret
 339
 340 END(__ieee754_pow)