nptl/sysdeps/unix/sysv/linux/i386/i486/sem_trywait.S

   1 /* Copyright (C) 2002, 2003 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <shlib-compat.h>
  22 #include <pthread-errnos.h>
  23
  24 #ifndef UP
  25 # define LOCK lock
  26 #else
  27 # define
  28 #endif
  29
  30         .text
  31
  32         .globl  __new_sem_trywait
  33         .type   __new_sem_trywait,@function
  34         .align  16
  35 __new_sem_trywait:
  36         movl    4(%esp), %ecx
  37
  38         movl    (%ecx), %eax
  39 2:      testl   %eax, %eax
  40         jz      1f
  41
  42         leal    -1(%eax), %edx
  43         LOCK
  44         cmpxchgl %edx, (%ecx)
  45         jne,pn  2b
  46         xorl    %eax, %eax
  47         ret
  48
  49 1:
  50 #ifdef PIC
  51         call    __i686.get_pc_thunk.cx
  52 #else
  53         movl    $3f, %ecx
  54 3:
  55 #endif
  56         addl    $_GLOBAL_OFFSET_TABLE_, %ecx
  57 #if USE___THREAD
  58         movl    %gs:0, %edx
  59         subl    errno@gottpoff(%ecx), %edx
  60         movl    $EAGAIN, (%edx)
  61 #else
  62         call    __errno_location@plt
  63         movl    $EAGAIN, (%eax)
  64 #endif
  65         orl     $-1, %eax
  66         ret
  67         .size   __new_sem_trywait,.-__new_sem_trywait
  68         versioned_symbol(libpthread, __new_sem_trywait, sem_trywait, GLIBC_2_1)
  69 #if SHLIB_COMPAT(libpthread, GLIBC_2_0, GLIBC_2_1)
  70         .global __old_sem_trywait
  71 __old_sem_trywait = __new_sem_trywait
  72         compat_symbol(libpthread, __old_sem_trywait, sem_trywait, GLIBC_2_0)
  73 #endif
  74
  75
  76 #ifdef PIC
  77         .section .gnu.linkonce.t.__i686.get_pc_thunk.cx,"ax",@progbits
  78         .globl  __i686.get_pc_thunk.cx
  79         .hidden __i686.get_pc_thunk.cx
  80         .type   __i686.get_pc_thunk.cx,@function
  81 __i686.get_pc_thunk.cx:
  82         movl (%esp), %ecx;
  83         ret
  84         .size   __i686.get_pc_thunk.cx,.-__i686.get_pc_thunk.cx
  85 #endif