nptl/sysdeps/unix/sysv/linux/i386/i486/sem_post.S

   1 /* Copyright (C) 2002, 2003 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <shlib-compat.h>
  22 #include <pthread-errnos.h>
  23
  24 #ifndef UP
  25 # define LOCK lock
  26 #else
  27 # define
  28 #endif
  29
  30 #define SYS_futex               240
  31 #define FUTEX_WAKE              1
  32
  33
  34         .text
  35
  36         .globl  __new_sem_post
  37         .type   __new_sem_post,@function
  38         .align  16
  39 __new_sem_post:
  40         pushl   %ebx
  41
  42         movl    8(%esp), %ebx
  43         movl    $1, %edx
  44         LOCK
  45         xaddl   %edx, (%ebx)
  46
  47         movl    $SYS_futex, %eax
  48         movl    $FUTEX_WAKE, %ecx
  49         addl    $1, %edx
  50         ENTER_KERNEL
  51
  52         testl   %eax, %eax
  53         js      1f
  54
  55         xorl    %eax, %eax
  56         popl    %ebx
  57         ret
  58
  59 1:
  60 #ifdef PIC
  61         call    __i686.get_pc_thunk.bx
  62 #else
  63         movl    $4f, %ebx
  64 4:
  65 #endif
  66         addl    $_GLOBAL_OFFSET_TABLE_, %ebx
  67 #if USE___THREAD
  68         movl    %gs:0, %edx
  69         subl    errno@gottpoff(%ebx), %edx
  70         movl    $EINVAL, (%edx)
  71 #else
  72         call    __errno_location@plt
  73         movl    $EINVAL, (%eax)
  74 #endif
  75
  76         orl     $-1, %eax
  77         popl    %ebx
  78         ret
  79         .size   __new_sem_post,.-__new_sem_post
  80         versioned_symbol(libpthread, __new_sem_post, sem_post, GLIBC_2_1)
  81 #if SHLIB_COMPAT(libpthread, GLIBC_2_0, GLIBC_2_1)
  82         .global __old_sem_post
  83 __old_sem_post = __new_sem_post
  84         compat_symbol(libpthread, __old_sem_post, sem_post, GLIBC_2_0)
  85 #endif
  86
  87
  88 #ifdef PIC
  89         .section .gnu.linkonce.t.__i686.get_pc_thunk.bx,"ax",@progbits
  90         .globl  __i686.get_pc_thunk.bx
  91         .hidden __i686.get_pc_thunk.bx
  92         .type   __i686.get_pc_thunk.bx,@function
  93 __i686.get_pc_thunk.bx:
  94         movl (%esp), %ebx;
  95         ret
  96         .size   __i686.get_pc_thunk.bx,.-__i686.get_pc_thunk.bx
  97 #endif