| blob | 7de4b093d49e3155a28be99a6d6148afed6e6ea9 |
1 dnl Process this file with autoconf to produce a configure script.
2 AC_PREREQ(2.53)dnl dnl Minimum Autoconf version required.
3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
4 AC_CONFIG_SRCDIR([include/features.h])
5 AC_CONFIG_HEADERS([config.h])
6 AC_CONFIG_AUX_DIR([scripts])
8 # Glibc should not depend on any header files
9 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
10 [m4_divert_text([DEFAULTS],
11 [ac_includes_default='/* none */'])])
13 dnl This is here so we can set $subdirs directly based on configure fragments.
14 AC_CONFIG_SUBDIRS()
16 AC_CANONICAL_HOST
18 AC_PROG_CC
19 if test $host != $build; then
20 AC_CHECK_PROGS(BUILD_CC, gcc cc)
21 fi
22 AC_SUBST(cross_compiling)
23 AC_PROG_CPP
24 # We need the C++ compiler only for testing.
25 AC_PROG_CXX
27 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
28 AC_MSG_ERROR([you must configure in a separate build directory])
29 fi
31 # This will get text that should go into config.make.
32 config_vars=
34 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
35 AC_ARG_WITH([gd],
36 AC_HELP_STRING([--with-gd=DIR],
37 [find libgd include dir and library with prefix DIR]),
38 [dnl
39 case "$with_gd" in
40 yes|''|no) ;;
41 *) libgd_include="-I$withval/include"
42 libgd_ldflags="-L$withval/lib" ;;
43 esac
44 ])
45 AC_ARG_WITH([gd-include],
46 AC_HELP_STRING([--with-gd-include=DIR],
47 [find libgd include files in DIR]),
48 [dnl
49 case "$with_gd_include" in
50 ''|no) ;;
51 *) libgd_include="-I$withval" ;;
52 esac
53 ])
54 AC_ARG_WITH([gd-lib],
55 AC_HELP_STRING([--with-gd-lib=DIR],
56 [find libgd library files in DIR]),
57 [dnl
58 case "$with_gd_lib" in
59 ''|no) ;;
60 *) libgd_ldflags="-L$withval" ;;
61 esac
62 ])
64 if test -n "$libgd_include"; then
65 config_vars="$config_vars
66 CFLAGS-memusagestat.c = $libgd_include"
67 fi
68 if test -n "$libgd_ldflags"; then
69 config_vars="$config_vars
70 libgd-LDFLAGS = $libgd_ldflags"
71 fi
73 dnl Arguments to specify presence of other packages/features.
74 AC_ARG_WITH([fp],
75 AC_HELP_STRING([--with-fp],
76 [if using floating-point hardware @<:@default=yes@:>@]),
77 [with_fp=$withval],
78 [with_fp=yes])
79 AC_SUBST(with_fp)
80 AC_ARG_WITH([binutils],
81 AC_HELP_STRING([--with-binutils=PATH],
82 [specify location of binutils (as and ld)]),
83 [path_binutils=$withval],
84 [path_binutils=''])
85 AC_ARG_WITH([selinux],
86 AC_HELP_STRING([--with-selinux],
87 [if building with SELinux support]),
88 [with_selinux=$withval],
89 [with_selinux=auto])
91 AC_ARG_WITH([headers],
92 AC_HELP_STRING([--with-headers=PATH],
93 [location of system headers to use
94 (for example /usr/src/linux/include)
95 @<:@default=compiler default@:>@]),
96 [sysheaders=$withval],
97 [sysheaders=''])
98 AC_SUBST(sysheaders)
100 AC_SUBST(use_default_link)
101 AC_ARG_WITH([default-link],
102 AC_HELP_STRING([--with-default-link],
103 [do not use explicit linker scripts]),
104 [use_default_link=$withval],
105 [use_default_link=default])
107 AC_ARG_ENABLE([sanity-checks],
108 AC_HELP_STRING([--disable-sanity-checks],
109 [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
110 [enable_sanity=$enableval],
111 [enable_sanity=yes])
113 AC_ARG_ENABLE([shared],
114 AC_HELP_STRING([--enable-shared],
115 [build shared library @<:@default=yes if GNU ld@:>@]),
116 [shared=$enableval],
117 [shared=yes])
118 AC_ARG_ENABLE([profile],
119 AC_HELP_STRING([--enable-profile],
120 [build profiled library @<:@default=no@:>@]),
121 [profile=$enableval],
122 [profile=no])
123 AC_ARG_ENABLE([versioning],
124 AC_HELP_STRING([--disable-versioning],
125 [do not include versioning information in the library objects @<:@default=yes if supported@:>@]),
126 [enable_versioning=$enableval],
127 [enable_versioning=yes])
129 AC_ARG_ENABLE([oldest-abi],
130 AC_HELP_STRING([--enable-oldest-abi=ABI],
131 [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
132 [oldest_abi=$enableval],
133 [oldest_abi=no])
134 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
135 oldest_abi=default
136 else
137 AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
138 fi
139 AC_SUBST(oldest_abi)
141 AC_ARG_ENABLE([stackguard-randomization],
142 AC_HELP_STRING([--enable-stackguard-randomization],
143 [initialize __stack_chk_guard canary with a random number at program start]),
144 [enable_stackguard_randomize=$enableval],
145 [enable_stackguard_randomize=no])
146 if test "$enable_stackguard_randomize" = yes; then
147 AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
148 fi
150 dnl Generic infrastructure for drop-in additions to libc.
151 AC_ARG_ENABLE([add-ons],
152 AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
153 [configure and build add-ons in DIR1,DIR2,...
154 search for add-ons if no parameter given]),
155 , [enable_add_ons=yes])
157 AC_ARG_ENABLE([hidden-plt],
158 AC_HELP_STRING([--disable-hidden-plt],
159 [do not hide internal function calls to avoid PLT]),
160 [hidden=$enableval],
161 [hidden=yes])
162 if test "x$hidden" = xno; then
163 AC_DEFINE(NO_HIDDEN)
164 fi
166 AC_ARG_ENABLE([bind-now],
167 AC_HELP_STRING([--enable-bind-now],
168 [disable lazy relocations in DSOs]),
169 [bindnow=$enableval],
170 [bindnow=no])
171 AC_SUBST(bindnow)
173 dnl On some platforms we cannot use dynamic loading. We must provide
174 dnl static NSS modules.
175 AC_ARG_ENABLE([static-nss],
176 AC_HELP_STRING([--enable-static-nss],
177 [build static NSS modules @<:@default=no@:>@]),
178 [static_nss=$enableval],
179 [static_nss=no])
180 dnl Enable static NSS also if we build no shared objects.
181 if test x"$static_nss" = xyes || test x"$shared" = xno; then
182 static_nss=yes
183 AC_DEFINE(DO_STATIC_NSS)
184 fi
186 AC_ARG_ENABLE([force-install],
187 AC_HELP_STRING([--disable-force-install],
188 [don't force installation of files from this package, even if they are older than the installed files]),
189 [force_install=$enableval],
190 [force_install=yes])
191 AC_SUBST(force_install)
193 dnl On some platforms we allow dropping compatibility with all kernel
194 dnl versions.
195 AC_ARG_ENABLE([kernel],
196 AC_HELP_STRING([--enable-kernel=VERSION],
197 [compile for compatibility with kernel not older than VERSION]),
198 [minimum_kernel=$enableval],
199 [])
200 dnl Prevent unreasonable values.
201 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
202 # Better nothing than this.
203 minimum_kernel=""
204 else
205 if test "$minimum_kernel" = current; then
206 minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
207 fi
208 fi
210 dnl For the development we sometimes want gcc to issue even more warnings.
211 dnl This is not the default since many of the extra warnings are not
212 dnl appropriate.
213 AC_ARG_ENABLE([all-warnings],
214 AC_HELP_STRING([--enable-all-warnings],
215 [enable all useful warnings gcc can issue]),
216 [all_warnings=$enableval],
217 [])
218 AC_SUBST(all_warnings)
220 AC_ARG_ENABLE([multi-arch],
221 AC_HELP_STRING([--enable-multi-arch],
222 [enable single DSO with optimizations for multiple architectures]),
223 [multi_arch=$enableval],
224 [multi_arch=default])
226 AC_ARG_ENABLE([nss-crypt],
227 AC_HELP_STRING([--enable-nss-crypt],
228 [enable libcrypt to use nss]),
229 [nss_crypt=$enableval],
230 [nss_crypt=no])
231 if test x$nss_crypt = xyes; then
232 nss_includes=-I$(nss-config --includedir 2>/dev/null)
233 if test $? -ne 0; then
234 AC_MSG_ERROR([cannot find include directory with nss-config])
235 fi
236 old_CFLAGS="$CFLAGS"
237 CFLAGS="$CFLAGS $nss_includes"
238 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
239 #include <hasht.h>
240 #include <nsslowhash.h>
241 void f (void) { NSSLOW_Init (); }])],
242 libc_cv_nss_crypt=yes,
243 AC_MSG_ERROR([
244 cannot find NSS headers with lowlevel hash function interfaces]))
245 old_LIBS="$LIBS"
246 LIBS="$LIBS -lfreebl3"
247 AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
248 #include <hasht.h>
249 #include <nsslowhash.h>],
250 [NSSLOW_Init();])],
251 libc_cv_nss_crypt=yes,
252 AC_MSG_ERROR([
253 cannot link program using lowlevel NSS hash functions]))
254 CFLAGS="$old_CFLAGS"
255 LIBS="$old_LIBS"
256 else
257 libc_cv_nss_crypt=no
258 fi
259 AC_SUBST(libc_cv_nss_crypt)
262 AC_ARG_ENABLE([obsolete-rpc],
263 AC_HELP_STRING([--enable-obsolete-rpc],
264 [build and install the obsolete RPC code for link-time usage]),
265 [link_obsolete_rpc=$enableval],
266 [link_obsolete_rpc=no])
267 AC_SUBST(link_obsolete_rpc)
269 if test "$link_obsolete_rpc" = yes; then
270 AC_DEFINE(LINK_OBSOLETE_RPC)
271 fi
273 AC_ARG_ENABLE([systemtap],
274 [AS_HELP_STRING([--enable-systemtap],
275 [enable systemtap static probe points @<:@default=no@:>@])],
276 [systemtap=$enableval],
277 [systemtap=no])
278 if test "x$systemtap" != xno; then
279 AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
280 old_CFLAGS="$CFLAGS"
281 CFLAGS="-std=gnu99 $CFLAGS"
282 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
283 void foo (int i, void *p)
284 {
285 asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
286 :: STAP_PROBE_ASM_OPERANDS (2, i, p));
287 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
288 CFLAGS="$old_CFLAGS"])
289 if test $libc_cv_sdt = yes; then
290 AC_DEFINE([USE_STAP_PROBE])
291 elif test "x$systemtap" != xauto; then
292 AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
293 fi
294 fi
296 AC_ARG_ENABLE([build-nscd],
297 [AS_HELP_STRING([--disable-build-nscd],
298 [disable building and installing the nscd daemon])],
299 [build_nscd=$enableval],
300 [build_nscd=default])
301 AC_SUBST(build_nscd)
303 # Note the use of $use_nscd is near the bottom of the file.
304 AC_ARG_ENABLE([nscd],
305 [AS_HELP_STRING([--disable-nscd],
306 [library functions will not contact the nscd daemon])],
307 [use_nscd=$enableval],
308 [use_nscd=yes])
310 # The way shlib-versions is used to generate soversions.mk uses a
311 # fairly simplistic model for name recognition that can't distinguish
312 # i486-pc-linux-gnu fully from i486-pc-gnu. So we mutate a $host_os
313 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
314 # tell. This doesn't get used much beyond that, so it's fairly safe.
315 case "$host_os" in
316 linux*)
317 ;;
318 gnu*)
319 host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
320 ;;
321 esac
323 # We keep the original values in `$config_*' and never modify them, so we
324 # can write them unchanged into config.make. Everything else uses
325 # $machine, $vendor, and $os, and changes them whenever convenient.
326 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
328 # Don't allow vendor == "unknown"
329 test "$config_vendor" = unknown && config_vendor=
330 config_os="`echo $config_os | sed 's/^unknown-//'`"
332 # Some configurations imply other options.
333 elf=yes
335 # The configure fragment of an add-on port can modify these to supplement
336 # or override the table in the case statement below. No fragment should
337 # ever change the config_* variables, however.
338 machine=$config_machine
339 vendor=$config_vendor
340 os=$config_os
341 base_os=''
343 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
344 # Unify this here.
345 if test "$machine" = rs6000; then
346 machine="powerpc"
347 fi
349 # Braindead PowerPC box with absolutely no FPU.
350 case "$machine-$host_os" in
351 powerpc*-*soft)
352 with_fp=no
353 ;;
354 esac
356 submachine=
357 AC_ARG_WITH([cpu],
358 AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
359 [dnl
360 case "$withval" in
361 yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
362 no) ;;
363 *) submachine="$withval" ;;
364 esac
365 ])
367 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
368 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
370 # An add-on can set this when it wants to disable the sanity check below.
371 libc_config_ok=no
373 dnl Having this here, though empty, makes sure that if add-ons' fragments
374 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
375 dnl our AC_OUTPUT will actually use it.
376 AC_CONFIG_SUBDIRS()
378 case "$enable_add_ons" in
379 ''|no) add_ons= ;;
380 yes|'*')
381 add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
382 sed 's@/[[^/]]*$@@' | sort | uniq`
383 add_ons_automatic=yes
384 ;;
385 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
386 add_ons_automatic=no ;;
387 esac
389 configured_add_ons=
390 add_ons_sfx=
391 add_ons_pfx=
392 if test x"$add_ons" != x; then
393 for f in $add_ons; do
394 # Some sanity checks
395 case "$f" in
396 crypt)
397 AC_MSG_ERROR([
398 *** It seems that you're using an old \`crypt' add-on. crypt is now
399 *** part of glibc and using the old add-on will not work with this
400 *** release. Start again with fresh sources and without the old
401 *** \`crypt' add-on.])
402 ;;
403 localedata)
404 AC_MSG_ERROR([
405 *** It seems that you're using an old \`localedata' add-on. localedata
406 *** is now part of glibc and using the old add-on will not work with
407 *** this release. Start again with fresh sources and without the old
408 *** \`localedata' add-on.])
409 ;;
410 esac
411 done
413 # Now source each add-on's configure fragment.
414 # The fragments can use $srcdir/$libc_add_on to find themselves,
415 # and test $add_ons_automatic to see if they were explicitly requested.
416 # A fragment can clear (or even change) $libc_add_on to affect
417 # whether it goes into the list to be actually used in the build.
418 use_add_ons=
419 for libc_add_on in $add_ons; do
420 # Test whether such a directory really exists.
421 # It can be absolute, or relative to $srcdir, or relative to the build dir.
422 case "$libc_add_on" in
423 /*)
424 libc_add_on_srcdir=$libc_add_on
425 ;;
426 *)
427 test -d "$srcdir/$libc_add_on" || {
428 if test -d "$libc_add_on"; then
429 libc_add_on="`pwd`/$libc_add_on"
430 else
431 AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
432 fi
433 }
434 libc_add_on_srcdir=$srcdir/$libc_add_on
435 ;;
436 esac
438 libc_add_on_frag=$libc_add_on_srcdir/configure
439 libc_add_on_canonical=
440 libc_add_on_config_subdirs=
441 if test -r "$libc_add_on_frag"; then
442 AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
443 libc_add_on_canonical=unknown
444 libc_add_on_subdirs=
445 . "$libc_add_on_frag"
446 test -z "$libc_add_on" || {
447 configured_add_ons="$configured_add_ons $libc_add_on"
448 if test "x$libc_add_on_canonical" = xunknown; then
449 AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
450 fi
451 for d in $libc_add_on_subdirs; do
452 case "$libc_add_on" in
453 /*) subdir_srcdir="$libc_add_on" ;;
454 *) subdir_srcdir="\$(..)$libc_add_on" ;;
455 esac
456 case "$d" in
457 .)
458 d="${libc_add_on_canonical:-$libc_add_on}"
459 ;;
460 /*)
461 subdir_srcdir="$d"
462 ;;
463 *)
464 subdir_srcdir="$subdir_srcdir/$d"
465 ;;
466 esac
467 d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
468 add_on_subdirs="$add_on_subdirs $d"
469 test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
470 $d-srcdir = $subdir_srcdir"
471 done
472 for d in $libc_add_on_config_subdirs; do
473 case "$d" in
474 /*) AC_MSG_ERROR(dnl
475 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
476 esac
477 if test ! -d "$libc_add_on_srcdir/$d"; then
478 AC_MSG_ERROR(fragment wants to configure missing directory $d)
479 fi
480 case "$libc_add_on" in
481 /*) AC_MSG_ERROR(dnl
482 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
483 esac
484 subdirs="$subdirs $libc_add_on/$d"
485 done
486 }
487 fi
488 if test -n "$libc_add_on"; then
489 LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
490 use_add_ons="$use_add_ons $libc_add_on"
491 add_ons_pfx="$add_ons_pfx $libc_add_on/"
492 test -z "$libc_add_on_canonical" ||
493 add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
494 fi
495 done
496 # Use echo to strip excess whitespace.
497 add_ons="`echo $use_add_ons`"
498 fi
499 AC_SUBST(add_ons)
500 AC_SUBST(add_on_subdirs)
503 ###
504 ### I put this here to prevent those annoying emails from people who cannot
505 ### read and try to compile glibc on unsupported platforms. --drepper
506 ###
507 ### By using the undocumented --enable-hacker-mode option for configure
508 ### one can skip this test to make the configuration not fail for unsupported
509 ### platforms.
510 ###
511 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
512 case "$machine-$host_os" in
513 *-linux* | *-gnu*)
514 ;;
515 *)
516 echo "*** The GNU C library is currently not available for this platform."
517 echo "*** So far nobody cared to port it and if there is no volunteer it"
518 echo "*** might never happen. So, if you have interest to see glibc on"
519 echo "*** this platform visit"
520 echo "*** http://www.gnu.org/software/libc/porting.html"
521 echo "*** and join the group of porters"
522 exit 1
523 ;;
524 esac
525 fi
527 dnl We need to use [ and ] for other purposes for a while now.
528 changequote(,)dnl
529 # Expand the configuration machine name into a subdirectory by architecture
530 # type and particular chip. If an add-on configure fragment already set
531 # base_machine, we don't change it.
532 test -n "$base_machine" || case "$machine" in
533 i[34567]86) base_machine=i386 machine=i386/$machine ;;
534 powerpc) base_machine=powerpc machine=powerpc/powerpc32 ;;
535 powerpc64) base_machine=powerpc machine=powerpc/powerpc64 ;;
536 s390) base_machine=s390 machine=s390/s390-32 ;;
537 s390x) base_machine=s390 machine=s390/s390-64 ;;
538 sh3*) base_machine=sh machine=sh/sh3 ;;
539 sh4*) base_machine=sh machine=sh/sh4 ;;
540 sparc | sparcv[67])
541 base_machine=sparc machine=sparc/sparc32 ;;
542 sparcv8 | supersparc | hypersparc)
543 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
544 sparcv8plus | sparcv8plusa | sparcv9)
545 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
546 sparcv8plusb | sparcv9b)
547 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
548 sparcv9v)
549 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
550 sparcv9v2)
551 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
552 sparc64)
553 base_machine=sparc machine=sparc/sparc64 ;;
554 sparc64b)
555 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
556 sparc64v)
557 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
558 sparc64v2)
559 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
560 *) base_machine=$machine ;;
561 esac
562 changequote([,])dnl
563 AC_SUBST(base_machine)
565 if test "$base_machine" = "i386"; then
566 AC_DEFINE(USE_REGPARMS)
567 fi
569 # For the multi-arch option we need support in the assembler.
570 AC_CACHE_CHECK([for assembler gnu_indirect_function symbol type support],
571 libc_cv_asm_gnu_indirect_function, [dnl
572 cat > conftest.s <<EOF
573 .type foo,%gnu_indirect_function
574 EOF
575 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD;
576 then
577 libc_cv_asm_gnu_indirect_function=yes
578 else
579 libc_cv_asm_gnu_indirect_function=no
580 fi
581 rm -f conftest*])
583 AC_MSG_CHECKING(whether .text pseudo-op must be used)
584 AC_CACHE_VAL(libc_cv_dot_text, [dnl
585 cat > conftest.s <<EOF
586 .text
587 EOF
588 libc_cv_dot_text=
589 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
590 libc_cv_dot_text=.text
591 fi
592 rm -f conftest*])
593 if test -z "$libc_cv_dot_text"; then
594 AC_MSG_RESULT(no)
595 else
596 AC_MSG_RESULT(yes)
597 fi
599 if test x"$libc_cv_asm_gnu_indirect_function" != xyes; then
600 if test x"$multi_arch" = xyes; then
601 AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
602 else
603 multi_arch=no
604 fi
605 fi
606 if test x"$multi_arch" != xno; then
607 multi_arch_d=/multiarch
608 fi
610 # Compute the list of sysdep directories for this configuration.
611 # This can take a while to compute.
612 sysdep_dir=$srcdir/sysdeps
613 AC_MSG_CHECKING(sysdep dirs)
614 dnl We need to use [ and ] for other purposes for a while now.
615 changequote(,)dnl
616 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
617 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
619 test "x$base_os" != x || case "$os" in
620 gnu*)
621 base_os=mach/hurd ;;
622 linux*)
623 base_os=unix/sysv ;;
624 esac
626 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
627 tail=$os
628 ostry=$os
629 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
630 ostry="$ostry /$o"
631 tail=$o
632 done
633 o=`echo $tail | sed 's/[0-9]*$//'`
634 if test $o != $tail; then
635 ostry="$ostry /$o"
636 fi
637 # For linux-gnu, try linux-gnu, then linux.
638 o=`echo $tail | sed 's/-.*$//'`
639 if test $o != $tail; then
640 ostry="$ostry /$o"
641 fi
643 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
644 base=
645 tail=$base_os
646 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
647 set $b
648 base="$base /$1"
649 tail="$2"
650 done
652 # For sparc/sparc32, try sparc/sparc32 and then sparc.
653 mach=
654 tail=$machine${submachine:+/$submachine}
655 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
656 set $m
657 # Prepend the machine's FPU directory unless --without-fp.
658 if test "$with_fp" = yes; then
659 mach="$mach /$1/fpu"
660 else
661 mach="$mach /$1/nofpu"
662 fi
663 mach="$mach /$1"
664 tail="$2"
665 done
667 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
668 changequote([,])dnl
670 # Find what sysdep directories exist.
671 sysnames_add_ons=
672 sysnames=
673 for b in $base ''; do
674 for m0 in $mach ''; do
675 for v in /$vendor ''; do
676 test "$v" = / && continue
677 for o in /$ostry ''; do
678 test "$o" = / && continue
679 for m in $multi_arch_d $mach ''; do
680 for d in $add_ons_pfx ''; do
681 for a in $add_ons_sfx ''; do
682 if test -n "$m0$m0sub$b$v$o$m$msub"; then
683 try_srcdir="${srcdir}/"
684 case "$d" in
685 /*) try_srcdir= ;;
686 esac
687 try="${d}sysdeps$m0$m0sub$b$v$o$m$msub$a"
688 test -n "$enable_debug_configure" &&
689 echo "$0 [DEBUG]: try $try" >&2
690 if test -d "$try_srcdir$try"; then
691 sysnames="$sysnames $try"
692 { test -n "$o" || test -n "$b"; } && os_used=t
693 { test -n "$m" || test -n "$m0"; } && machine_used=t
694 case x${m0:-$m} in
695 x*/$submachine) submachine_used=t ;;
696 esac
697 if test -n "$d"; then
698 case "$sysnames_add_ons" in
699 *" $d "*) ;;
700 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
701 esac
702 fi
703 fi
704 fi
705 done
706 done
707 done
708 done
709 done
710 done
711 done
713 # If the assembler supports gnu_indirect_function symbol type and the
714 # architecture supports multi-arch, we enable multi-arch by default.
715 case $sysnames_add_ons$sysnames in
716 *"$multi_arch_d"*)
717 ;;
718 *)
719 test x"$multi_arch" = xdefault && multi_arch=no
720 ;;
721 esac
722 if test x"$multi_arch" != xno; then
723 AC_DEFINE(USE_MULTIARCH)
724 fi
725 AC_SUBST(multi_arch)
727 if test -z "$os_used" && test "$os" != none; then
728 AC_MSG_ERROR(Operating system $os is not supported.)
729 fi
730 if test -z "$machine_used" && test "$machine" != none; then
731 AC_MSG_ERROR(The $machine is not supported.)
732 fi
733 if test -z "$submachine_used" && test -n "$submachine"; then
734 AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
735 fi
736 AC_SUBST(submachine)
738 # We have now validated the configuration.
740 # Expand the list of system names into a full list of directories
741 # from each element's parent name and Implies file (if present).
742 set $sysnames
743 names=
744 while test $# -gt 0; do
745 name=$1
746 shift
748 case " $names " in *" $name "*)
749 # Already in the list.
750 continue
751 esac
753 # Report each name as we discover it, so there is no long pause in output.
754 echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
756 name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
758 case $name in
759 /*) xsrcdir= ;;
760 *) xsrcdir=$srcdir/ ;;
761 esac
762 test -n "$enable_debug_configure" &&
763 echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
765 for implies_file in Implies Implies-before Implies-after; do
766 implies_type=`echo $implies_file | sed s/-/_/`
767 eval ${implies_type}=
768 if test -f $xsrcdir$name/$implies_file; then
769 # Collect more names from the `Implies' file (removing comments).
770 implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
771 for x in $implied_candidate; do
772 found=no
773 if test -d $xsrcdir$name_base/$x; then
774 eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
775 found=yes
776 fi
777 for d in $add_ons_pfx ''; do
778 try="${d}sysdeps/$x"
779 case $d in
780 /*) try_srcdir= ;;
781 *) try_srcdir=$srcdir/ ;;
782 esac
783 test -n "$enable_debug_configure" &&
784 echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
785 if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
786 then
787 eval "${implies_type}=\"\$${implies_type} \$try\""
788 found=yes
789 case "$sysnames_add_ons" in
790 *" $d "*) ;;
791 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
792 esac
793 fi
794 done
795 if test $found = no; then
796 AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
797 fi
798 done
799 fi
800 done
802 # Add NAME to the list of names.
803 names="$names $name"
805 # Find the parent of NAME, using the empty string if it has none.
806 changequote(,)dnl
807 parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
808 changequote([,])dnl
810 test -n "$enable_debug_configure" &&
811 echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
812 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
814 # Add the names implied by NAME, and NAME's parent (if it has one), to
815 # the list of names to be processed (the argument list). We prepend the
816 # implied names to the list and append the parent. We want implied
817 # directories to come before further directories inferred from the
818 # configuration components; this ensures that for sysv4, unix/common
819 # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
820 # after sysv4).
821 sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
822 test -n "$sysnames" && set $sysnames
823 done
825 # Add the default directories.
826 default_sysnames="sysdeps/generic"
827 sysnames="$names $default_sysnames"
828 AC_SUBST(sysnames)
829 # The other names were emitted during the scan.
830 AC_MSG_RESULT($default_sysnames)
832 # Collect the list of add-ons that supply partial sysdeps trees.
833 sysdeps_add_ons=
834 for add_on in $add_ons; do
835 case "$add_on" in
836 /*) xsrcdir= ;;
837 *) xsrcdir="$srcdir/" ;;
838 esac
840 test -d "$xsrcdir$add_on/sysdeps" || {
841 case "$configured_add_ons " in
842 *" $add_on "*) ;;
843 *|'')
844 AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
845 ;;
846 esac
847 continue
848 }
850 sysdeps_add_ons="$sysdeps_add_ons $add_on"
851 case "$sysnames_add_ons" in
852 *" $add_on/ "*) ;;
853 *|'')
854 AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
855 continue ;;
856 esac
858 found=no
859 for d in $sysnames; do
860 case "$d" in
861 $add_on/sysdeps/*) ;;
862 *) continue ;;
863 esac
864 (cd "$xsrcdir$d" && for f in *[[!~]]; do
865 case "$f" in
866 sys|bits)
867 for ff in $f/*.h; do
868 test -d "$ff" || { test -e "$ff" && exit 88; }
869 done
870 ;;
871 *)
872 test -d "$f" || { test -e "$f" && exit 88; }
873 ;;
874 esac
875 done)
876 if test $? -eq 88; then
877 found=yes
878 break
879 fi
880 done
881 if test $found = no; then
882 AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
883 fi
884 done
885 AC_SUBST(sysdeps_add_ons)
888 ### Locate tools.
890 AC_PROG_INSTALL
891 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
892 # The makefiles need to use a different form to find it in $srcdir.
893 INSTALL='\$(..)./scripts/install-sh -c'
894 fi
895 AC_PROG_LN_S
897 LIBC_PROG_BINUTILS
898 AC_SUBST(MIG)dnl Needed by sysdeps/mach/configure.in
900 # Accept binutils 2.20 or newer.
901 AC_CHECK_PROG_VER(AS, $AS, --version,
902 [GNU assembler.* \([0-9]*\.[0-9.]*\)],
903 [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
904 AC_CHECK_PROG_VER(LD, $LD, --version,
905 [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
906 [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
908 # These programs are version sensitive.
909 AC_CHECK_TOOL_PREFIX
910 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
911 [version \([egcygnustpi-]*[0-9.]*\)], [4.[3-9].* | 4.[1-9][0-9].* | [5-9].* ],
912 critic_missing="$critic_missing gcc")
913 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
914 [GNU Make[^0-9]*\([0-9][0-9.]*\)],
915 [3.79* | 3.[89]*], critic_missing="$critic_missing make")
917 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
918 [GNU gettext.* \([0-9]*\.[0-9.]*\)],
919 [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
920 MSGFMT=: aux_missing="$aux_missing msgfmt")
921 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
922 [GNU texinfo.* \([0-9][0-9.]*\)],
923 [4.[5-9]*|4.[1-9][0-9]*|[5-9].*],
924 MAKEINFO=: aux_missing="$aux_missing makeinfo")
925 AC_CHECK_PROG_VER(SED, sed, --version,
926 [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
927 [3.0[2-9]*|3.[1-9]*|[4-9]*],
928 SED=: aux_missing="$aux_missing sed")
929 AC_CHECK_PROG_VER(AWK, gawk, --version,
930 [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
931 [[3-9].*], critic_missing="$critic_missing gawk")
933 AC_CHECK_TOOL(READELF, readelf, false)
934 AC_CHECK_TOOL(NM, nm, false)
936 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
937 case "x$AUTOCONF" in
938 xno|x|x:) AUTOCONF=no ;;
939 *)
940 AC_CACHE_CHECK(dnl
941 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
942 if (cd $srcdir; $AUTOCONF $ACFLAGS configure.in > /dev/null 2>&1); then
943 libc_cv_autoconf_works=yes
944 else
945 libc_cv_autoconf_works=no
946 fi])
947 test $libc_cv_autoconf_works = yes || AUTOCONF=no
948 ;;
949 esac
950 if test "x$AUTOCONF" = xno; then
951 aux_missing="$aux_missing autoconf"
952 fi
954 test -n "$critic_missing" && AC_MSG_ERROR([
955 *** These critical programs are missing or too old:$critic_missing
956 *** Check the INSTALL file for required versions.])
958 test -n "$aux_missing" && AC_MSG_WARN([
959 *** These auxiliary programs are missing or incompatible versions:$aux_missing
960 *** some features will be disabled.
961 *** Check the INSTALL file for required versions.])
963 # if using special system headers, find out the compiler's sekrit
964 # header directory and add that to the list. NOTE: Only does the right
965 # thing on a system that doesn't need fixincludes. (Not presently a problem.)
966 if test -n "$sysheaders"; then
967 SYSINCLUDES=-nostdinc
968 for d in include include-fixed; do
969 i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
970 SYSINCLUDES="$SYSINCLUDES -isystem $i"
971 done
972 SYSINCLUDES="$SYSINCLUDES \
973 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
974 if test -n "$CXX"; then
975 CXX_SYSINCLUDES=
976 cxxversion=`$CXX -dumpversion 2>&AS_MESSAGE_LOG_FD` &&
977 cxxmachine=`$CXX -dumpmachine 2>&AS_MESSAGE_LOG_FD` &&
978 for d in include "$cxxmachine/include"; do
979 i=../../../../$d/c++/$cxxversion
980 cxxheaders=`$CXX -print-file-name="$i"` &&
981 test "x$cxxheaders" != x && test "x$i" != "x$cxxheaders" &&
982 CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders \
983 -isystem $cxxheaders/$cxxmachine -isystem $cxxheaders/backward"
984 done
985 fi
986 fi
987 AC_SUBST(SYSINCLUDES)
988 AC_SUBST(CXX_SYSINCLUDES)
990 # Test if LD_LIBRARY_PATH contains the notation for the current directory
991 # since this would lead to problems installing/building glibc.
992 # LD_LIBRARY_PATH contains the current directory if one of the following
993 # is true:
994 # - one of the terminals (":" and ";") is the first or last sign
995 # - two terminals occur directly after each other
996 # - the path contains an element with a dot in it
997 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
998 changequote(,)dnl
999 case ${LD_LIBRARY_PATH} in
1000 [:\;]* | *[:\;] | *[:\;][:\;]* | *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1001 ld_library_path_setting="contains current directory"
1002 ;;
1003 *)
1004 ld_library_path_setting="ok"
1005 ;;
1006 esac
1007 changequote([,])dnl
1008 AC_MSG_RESULT($ld_library_path_setting)
1009 if test "$ld_library_path_setting" != "ok"; then
1010 AC_MSG_ERROR([
1011 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1012 *** building glibc. Please change the environment variable
1013 *** and run configure again.])
1014 fi
1016 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1017 if $CC -v -static-libgcc 2>&1 | grep -q 'unrecognized option.*static-libgcc'; then
1018 libc_cv_gcc_static_libgcc=
1019 else
1020 libc_cv_gcc_static_libgcc=-static-libgcc
1021 fi])
1022 AC_SUBST(libc_cv_gcc_static_libgcc)
1024 AC_PATH_PROG(BASH_SHELL, bash, no)
1025 if test "$BASH_SHELL" != no &&
1026 $BASH_SHELL -c 'test "$BASH_VERSINFO" \
1027 && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
1028 libc_cv_have_bash2=yes
1029 else
1030 libc_cv_have_bash2=no
1031 fi
1032 AC_SUBST(libc_cv_have_bash2)
1034 dnl We need a ksh compatible shell for tzselect.
1035 if test "$BASH_SHELL" = no; then
1036 AC_PATH_PROG(KSH, ksh, no)
1037 if test "$KSH" = no; then
1038 libc_cv_have_ksh=no
1039 else
1040 libc_cv_have_ksh=yes
1041 fi
1042 else
1043 KSH="$BASH_SHELL"
1044 AC_SUBST(KSH)
1045 libc_cv_have_ksh=yes
1046 fi
1047 AC_SUBST(libc_cv_have_ksh)
1049 AC_PATH_PROG(PERL, perl, no)
1050 if test "$PERL" != no &&
1051 (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1052 PERL=no
1053 fi
1054 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1055 $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1056 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1058 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1059 AC_TRY_COMPILE(dnl
1060 [#define __need_size_t
1061 #define __need_wchar_t
1062 #include <stddef.h>
1063 #define __need_NULL
1064 #include <stddef.h>], [size_t size; wchar_t wchar;
1065 #ifdef offsetof
1066 #error stddef.h ignored __need_*
1067 #endif
1068 if (&size == NULL || &wchar == NULL) abort ();],
1069 libc_cv_friendly_stddef=yes,
1070 libc_cv_friendly_stddef=no)])
1071 if test $libc_cv_friendly_stddef = yes; then
1072 config_vars="$config_vars
1073 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1074 fi
1076 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1077 libc_cv_need_minus_P, [dnl
1078 cat > conftest.S <<EOF
1079 #include "confdefs.h"
1080 /* Nothing whatsoever. */
1081 EOF
1082 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1083 libc_cv_need_minus_P=no
1084 else
1085 libc_cv_need_minus_P=yes
1086 fi
1087 rm -f conftest*])
1088 if test $libc_cv_need_minus_P = yes; then
1089 config_vars="$config_vars
1090 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1091 fi
1093 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1094 cat > conftest.s <<EOF
1095 ${libc_cv_dot_text}
1096 foo:
1097 .set glibc_conftest_frobozz,foo
1098 .globl glibc_conftest_frobozz
1099 EOF
1100 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1101 # (but it doesn't work), so we must do a linking check to be sure.
1102 cat > conftest1.c <<\EOF
1103 extern int glibc_conftest_frobozz;
1104 void _start() { glibc_conftest_frobozz = 1; }
1105 EOF
1106 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1107 -nostartfiles -nostdlib \
1108 -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1109 libc_cv_asm_set_directive=yes
1110 else
1111 libc_cv_asm_set_directive=no
1112 fi
1113 rm -f conftest*])
1114 if test $libc_cv_asm_set_directive = yes; then
1115 AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1116 fi
1118 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1119 libc_cv_asm_unique_object, [dnl
1120 cat > conftest.s <<EOF
1121 ${libc_cv_dot_text}
1122 _sym:
1123 .type _sym, %gnu_unique_object
1124 EOF
1125 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1126 libc_cv_asm_unique_object=yes
1127 else
1128 libc_cv_asm_unique_object=no
1129 fi
1130 rm -f conftest*])
1131 if test $libc_cv_asm_unique_object = yes; then
1132 AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1133 fi
1135 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
1136 [cat > conftest.s <<EOF
1137 ${libc_cv_dot_text}
1138 _sym:
1139 .symver _sym,sym@VERS
1140 EOF
1141 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1142 libc_cv_asm_symver_directive=yes
1143 else
1144 libc_cv_asm_symver_directive=no
1145 fi
1146 rm -f conftest*])
1147 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
1148 if test $libc_cv_asm_symver_directive = yes; then
1149 cat > conftest.s <<EOF
1150 ${libc_cv_dot_text}
1151 _sym:
1152 .symver _sym,sym@VERS
1153 EOF
1154 cat > conftest.map <<EOF
1155 VERS_1 {
1156 global: sym;
1157 };
1159 VERS_2 {
1160 global: sym;
1161 } VERS_1;
1162 EOF
1163 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1164 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $LDFLAGS -shared
1165 -o conftest.so conftest.o
1166 -nostartfiles -nostdlib
1167 -Wl,--version-script,conftest.map
1168 1>&AS_MESSAGE_LOG_FD]);
1169 then
1170 libc_cv_ld_version_script_option=yes
1171 else
1172 libc_cv_ld_version_script_option=no
1173 fi
1174 else
1175 libc_cv_ld_version_script_option=no
1176 fi
1177 else
1178 libc_cv_ld_version_script_option=no
1179 fi
1180 rm -f conftest*])
1181 if test $shared != no &&
1182 test $libc_cv_asm_symver_directive = yes &&
1183 test $libc_cv_ld_version_script_option = yes &&
1184 test $enable_versioning = yes; then
1185 VERSIONING=yes
1186 AC_DEFINE(DO_VERSIONING)
1187 else
1188 VERSIONING=no
1189 fi
1190 AC_SUBST(VERSIONING)
1192 if test $shared != no && test $VERSIONING = no; then
1193 echo "\
1194 *** WARNING: You should not compile GNU libc without versioning. Not using
1195 *** versioning will introduce incompatibilities so that old binaries
1196 *** will not run anymore.
1197 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
1198 fi
1199 AC_CACHE_CHECK(for .previous assembler directive,
1200 libc_cv_asm_previous_directive, [dnl
1201 cat > conftest.s <<EOF
1202 .section foo_section
1203 .previous
1204 EOF
1205 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1206 libc_cv_asm_previous_directive=yes
1207 else
1208 libc_cv_asm_previous_directive=no
1209 fi
1210 rm -f conftest*])
1211 if test $libc_cv_asm_previous_directive = yes; then
1212 AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1213 else
1214 AC_CACHE_CHECK(for .popsection assembler directive,
1215 libc_cv_asm_popsection_directive, [dnl
1216 cat > conftest.s <<EOF
1217 .pushsection foo_section
1218 .popsection
1219 EOF
1220 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1221 libc_cv_asm_popsection_directive=yes
1222 else
1223 libc_cv_asm_popsection_directive=no
1224 fi
1225 rm -f conftest*])
1226 if test $libc_cv_asm_popsection_directive = yes; then
1227 AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1228 fi
1229 fi
1230 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1231 libc_cv_asm_protected_directive, [dnl
1232 cat > conftest.s <<EOF
1233 .protected foo
1234 foo:
1235 .hidden bar
1236 bar:
1237 EOF
1238 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1239 libc_cv_asm_protected_directive=yes
1240 else
1241 AC_MSG_ERROR(assembler support for symbol visibility is required)
1242 fi
1243 rm -f conftest*])
1245 if test $libc_cv_asm_protected_directive = yes; then
1246 AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1247 libc_cv_visibility_attribute,
1248 [cat > conftest.c <<EOF
1249 int foo __attribute__ ((visibility ("hidden"))) = 1;
1250 int bar __attribute__ ((visibility ("protected"))) = 1;
1251 EOF
1252 libc_cv_visibility_attribute=no
1253 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1254 if grep '\.hidden.*foo' conftest.s >/dev/null; then
1255 if grep '\.protected.*bar' conftest.s >/dev/null; then
1256 libc_cv_visibility_attribute=yes
1257 fi
1258 fi
1259 fi
1260 rm -f conftest.{c,s}
1261 ])
1262 if test $libc_cv_visibility_attribute != yes; then
1263 AC_MSG_ERROR(compiler support for visibility attribute is required)
1264 fi
1265 fi
1267 if test $libc_cv_visibility_attribute = yes; then
1268 AC_CACHE_CHECK(for broken __attribute__((visibility())),
1269 libc_cv_broken_visibility_attribute,
1270 [cat > conftest.c <<EOF
1271 int foo (int x);
1272 int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1273 int bar (int x) { return x; }
1274 EOF
1275 libc_cv_broken_visibility_attribute=yes
1276 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1277 changequote(,)dnl
1278 if grep '\.hidden[ _]foo' conftest.s >/dev/null; then
1279 changequote([,])dnl
1280 libc_cv_broken_visibility_attribute=no
1281 fi
1282 fi
1283 rm -f conftest.c conftest.s
1284 ])
1285 if test $libc_cv_broken_visibility_attribute = yes; then
1286 AC_MSG_ERROR(working compiler support for visibility attribute is required)
1287 fi
1288 fi
1290 AC_CACHE_CHECK(for broken __attribute__((alias())),
1291 libc_cv_broken_alias_attribute,
1292 [cat > conftest.c <<EOF
1293 extern int foo (int x) __asm ("xyzzy");
1294 int bar (int x) { return x; }
1295 extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1296 extern int dfoo;
1297 extern __typeof (dfoo) dfoo __asm ("abccb");
1298 int dfoo = 1;
1299 EOF
1300 libc_cv_broken_alias_attribute=yes
1301 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1302 if grep 'xyzzy' conftest.s >/dev/null &&
1303 grep 'abccb' conftest.s >/dev/null; then
1304 libc_cv_broken_alias_attribute=no
1305 fi
1306 fi
1307 rm -f conftest.c conftest.s
1308 ])
1309 if test $libc_cv_broken_alias_attribute = yes; then
1310 AC_MSG_ERROR(working alias attribute support required)
1311 fi
1313 if test $libc_cv_visibility_attribute = yes; then
1314 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1315 libc_cv_have_sdata_section,
1316 [echo "int i;" > conftest.c
1317 libc_cv_have_sdata_section=no
1318 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1319 | grep '\.sdata' >/dev/null; then
1320 libc_cv_have_sdata_section=yes
1321 fi
1322 rm -f conftest.c conftest.so
1323 ])
1324 if test $libc_cv_have_sdata_section = yes; then
1325 AC_DEFINE(HAVE_SDATA_SECTION)
1326 fi
1327 fi
1329 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1330 libc_cv_initfini_array, [dnl
1331 LIBC_TRY_LINK_STATIC([
1332 int foo (void) { return 1; }
1333 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1334 ],
1335 [if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1336 libc_cv_initfini_array=yes
1337 else
1338 libc_cv_initfini_array=no
1339 fi],
1340 [libc_cv_initfini_array=no])
1341 ])
1342 if test $libc_cv_initfini_array != yes; then
1343 AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1344 fi
1346 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1347 libc_cv_ctors_header, [dnl
1348 libc_cv_ctors_header=yes
1349 LIBC_TRY_LINK_STATIC([
1350 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1351 __attribute__ ((destructor)) void dtor (void) { asm (""); }
1352 ],
1353 [dnl
1354 AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1355 { gsub(/\@<:@ */, "@<:@") }
1356 $2 == ".ctors" || $2 == ".dtors" {
1357 size = strtonum("0x" $6)
1358 align = strtonum("0x" $NF)
1359 seen@<:@$2@:>@ = 1
1360 stub@<:@$2@:>@ = size == align * 2
1361 }
1362 END {
1363 ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1364 dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1365 exit ((ctors_ok && dtors_ok) ? 0 : 1)
1366 }
1367 '], [libc_cv_ctors_header=no])
1368 ], [dnl
1369 AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1370 ])
1371 ])
1372 if test $libc_cv_ctors_header = no; then
1373 AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1374 fi
1376 AC_CACHE_CHECK(for libunwind-support in compiler,
1377 libc_cv_cc_with_libunwind, [
1378 cat > conftest.c <<EOF
1379 int main (void) { return 0; }
1380 EOF
1381 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1382 conftest.c -v 2>&1 >/dev/null | grep -q " -lunwind "; then
1383 libc_cv_cc_with_libunwind=yes
1384 else
1385 libc_cv_cc_with_libunwind=no
1386 fi
1387 rm -f conftest*])
1388 AC_SUBST(libc_cv_cc_with_libunwind)
1389 if test $libc_cv_cc_with_libunwind = yes; then
1390 AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1391 fi
1393 AC_CACHE_CHECK(for -z nodelete option,
1394 libc_cv_z_nodelete, [dnl
1395 cat > conftest.c <<EOF
1396 int _start (void) { return 42; }
1397 EOF
1398 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1399 -fPIC -shared -o conftest.so conftest.c
1400 -nostartfiles -nostdlib
1401 -Wl,--enable-new-dtags,-z,nodelete 1>&AS_MESSAGE_LOG_FD])
1402 then
1403 libc_cv_z_nodelete=yes
1404 else
1405 AC_MSG_ERROR(linker with -z nodelete support required)
1406 fi
1407 rm -f conftest*])
1409 AC_CACHE_CHECK(for -z nodlopen option,
1410 libc_cv_z_nodlopen, [dnl
1411 cat > conftest.c <<EOF
1412 int _start (void) { return 42; }
1413 EOF
1414 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1415 -fPIC -shared -o conftest.so conftest.c
1416 -nostartfiles -nostdlib
1417 -Wl,--enable-new-dtags,-z,nodlopen 1>&AS_MESSAGE_LOG_FD])
1418 then
1419 libc_cv_z_nodlopen=yes
1420 else
1421 AC_MSG_ERROR(linker with -z nodlopen support required)
1422 fi
1423 rm -f conftest*])
1425 AC_CACHE_CHECK(for -z initfirst option,
1426 libc_cv_z_initfirst, [dnl
1427 cat > conftest.c <<EOF
1428 int _start (void) { return 42; }
1429 EOF
1430 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1431 -fPIC -shared -o conftest.so conftest.c
1432 -nostartfiles -nostdlib
1433 -Wl,--enable-new-dtags,-z,initfirst 1>&AS_MESSAGE_LOG_FD])
1434 then
1435 libc_cv_z_initfirst=yes
1436 else
1437 AC_MSG_ERROR(linker with -z initfirst support required)
1438 fi
1439 rm -f conftest*])
1441 # Add-on fragments can set these for other machines.
1442 libc_commonpagesize=${libc_commonpagesize:-no}
1443 libc_relro_required=${libc_relro_required:-no}
1444 case "$base_machine" in
1445 i[[34567]]86 | x86_64 | powerpc* | s390*)
1446 libc_commonpagesize=0x1000
1447 libc_relro_required=yes
1448 ;;
1449 sparc*)
1450 libc_commonpagesize=0x2000
1451 libc_relro_required=yes
1452 ;;
1453 esac
1455 if test $libc_commonpagesize != no; then
1456 AC_CACHE_CHECK(for -z relro option,
1457 libc_cv_z_relro, [dnl
1458 libc_cv_z_relro=no
1459 AC_LANG_CONFTEST([AC_LANG_SOURCE([[
1460 int _start (void) { return 42; }
1461 extern void _exit (int);
1462 /* Since these pointers are const, they should go in rodata.
1463 Since they refer to functions that have to be resolved by
1464 dynamic linking, they should instead go in RELRO data. */
1465 const void *const relro[] = { &_start, &_exit, 0 };
1466 /* GNU ld fails to produce RELRO data when it's very small and there is no
1467 normal writable data following it, or if only uninitialized (.bss) data
1468 follows it, or only very small writable data. */
1469 int data[0x10000] = { 1, };
1470 ]])])
1471 cat > conftest.awk <<\EOF
1472 BEGIN {
1473 result = "no"
1474 commonpagesize = strtonum(commonpagesize)
1475 }
1476 { print "LINE:", $0 > "/dev/stderr" }
1477 $1 == "GNU_RELRO" {
1478 vaddr = strtonum($3)
1479 memsz = strtonum($6)
1480 end = vaddr + memsz
1481 printf "vaddr %#x memsz %#x end %#x commonpagesize %#x\n", \
1482 vaddr, memsz, end, commonpagesize > "/dev/stderr"
1483 result = (end % commonpagesize == 0) ? "yes" : "broken"
1484 }
1485 END { print result }
1486 EOF
1487 AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1488 -fPIC -shared -o conftest.so conftest.c
1489 -nostartfiles -nostdlib
1490 -Wl,-z,relro 1>&AS_MESSAGE_LOG_FD]) &&
1491 AC_TRY_COMMAND([$READELF -Wl conftest.so > conftest.ph]) &&
1492 AC_TRY_COMMAND([
1493 $AWK -v commonpagesize=$libc_commonpagesize -f conftest.awk
1494 conftest.ph > conftest.cps
1495 ]) &&
1496 libc_cv_z_relro=`cat conftest.cps 2>&AS_MESSAGE_LOG_FD`
1497 rm -f conftest*])
1498 if { test "x$libc_relro_required" = xyes &&
1499 test "x$libc_cv_z_relro" != xyes
1500 }
1501 then
1502 AC_MSG_ERROR(linker with -z relro support required)
1503 fi
1504 else
1505 AC_MSG_WARN([missing architecture parameter to check for working -z relro])
1506 fi
1508 AC_CACHE_CHECK(for -Bgroup option,
1509 libc_cv_Bgroup, [dnl
1510 cat > conftest.c <<EOF
1511 int _start (void) { return 42; }
1512 EOF
1513 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1514 -fPIC -shared -o conftest.so conftest.c
1515 -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1516 then
1517 libc_cv_Bgroup=yes
1518 else
1519 libc_cv_Bgroup=no
1520 fi
1521 rm -f conftest*])
1522 AC_SUBST(libc_cv_Bgroup)
1524 ASFLAGS_config=
1525 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1526 libc_cv_as_noexecstack, [dnl
1527 cat > conftest.c <<EOF
1528 void foo (void) { }
1529 EOF
1530 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1531 -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1532 && grep -q .note.GNU-stack conftest.s \
1533 && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1534 -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1535 then
1536 libc_cv_as_noexecstack=yes
1537 else
1538 libc_cv_as_noexecstack=no
1539 fi
1540 rm -f conftest*])
1541 if test $libc_cv_as_noexecstack = yes; then
1542 ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1543 fi
1544 AC_SUBST(ASFLAGS_config)
1546 AC_CACHE_CHECK(for -z combreloc,
1547 libc_cv_z_combreloc, [dnl
1548 cat > conftest.c <<EOF
1549 extern int bar (int);
1550 extern int mumble;
1551 int foo (void) { return bar (mumble); }
1552 EOF
1553 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1554 -fPIC -shared -o conftest.so conftest.c
1555 -nostdlib -nostartfiles
1556 -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1557 then
1558 dnl The following test is a bit weak. We must use a tool which can test
1559 dnl cross-platform since the gcc used can be a cross compiler. Without
1560 dnl introducing new options this is not easily doable. Instead use a tool
1561 dnl which always is cross-platform: readelf. To detect whether -z combreloc
1562 dnl look for a section named .rel.dyn.
1563 if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1564 libc_cv_z_combreloc=yes
1565 else
1566 libc_cv_z_combreloc=no
1567 fi
1568 else
1569 libc_cv_z_combreloc=no
1570 fi
1571 rm -f conftest*])
1572 if test "$libc_cv_z_combreloc" = yes; then
1573 AC_DEFINE(HAVE_Z_COMBRELOC)
1574 fi
1575 AC_SUBST(libc_cv_z_combreloc)
1577 AC_CACHE_CHECK(for -z execstack,
1578 libc_cv_z_execstack, [dnl
1579 cat > conftest.c <<EOF
1580 int _start (void) { return 42; }
1581 EOF
1582 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1583 -fPIC -shared -o conftest.so conftest.c
1584 -Wl,-z,execstack -nostdlib
1585 1>&AS_MESSAGE_LOG_FD])
1586 then
1587 libc_cv_z_execstack=yes
1588 else
1589 libc_cv_z_execstack=no
1590 fi
1591 rm -f conftest*])
1592 AC_SUBST(libc_cv_z_execstack)
1594 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1595 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1596 ])
1598 AC_SUBST(libc_cv_fpie)
1600 AC_CACHE_CHECK(for --hash-style option,
1601 libc_cv_hashstyle, [dnl
1602 cat > conftest.c <<EOF
1603 int _start (void) { return 42; }
1604 EOF
1605 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1606 -fPIC -shared -o conftest.so conftest.c
1607 -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1608 then
1609 libc_cv_hashstyle=yes
1610 else
1611 libc_cv_hashstyle=no
1612 fi
1613 rm -f conftest*])
1614 AC_SUBST(libc_cv_hashstyle)
1616 # The linker's default -shared behavior is good enough if it
1617 # does these things that our custom linker scripts ensure that
1618 # all allocated NOTE sections come first.
1619 if test "$use_default_link" = default; then
1620 AC_CACHE_CHECK([for sufficient default -shared layout],
1621 libc_cv_use_default_link, [dnl
1622 libc_cv_use_default_link=no
1623 cat > conftest.s <<\EOF
1624 .section .note.a,"a",%note
1625 .balign 4
1626 .long 4,4,9
1627 .string "GNU"
1628 .string "foo"
1629 .section .note.b,"a",%note
1630 .balign 4
1631 .long 4,4,9
1632 .string "GNU"
1633 .string "bar"
1634 EOF
1635 if AC_TRY_COMMAND([dnl
1636 ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1637 ac_try=`$READELF -S conftest.so | sed -n \
1638 ['${x;p;}
1639 s/^ *\[ *[1-9][0-9]*\] *\([^ ][^ ]*\) *\([^ ][^ ]*\) .*$/\2 \1/
1640 t a
1641 b
1642 : a
1643 H']`
1644 then
1645 libc_seen_a=no libc_seen_b=no
1646 set -- $ac_try
1647 while test $# -ge 2 -a "$1" = NOTE; do
1648 case "$2" in
1649 .note.a) libc_seen_a=yes ;;
1650 .note.b) libc_seen_b=yes ;;
1651 esac
1652 shift 2
1653 done
1654 case "$libc_seen_a$libc_seen_b" in
1655 yesyes)
1656 libc_cv_use_default_link=yes
1657 ;;
1658 *)
1659 echo >&AS_MESSAGE_LOG_FD "\
1660 $libc_seen_a$libc_seen_b from:
1661 $ac_try"
1662 ;;
1663 esac
1664 fi
1665 rm -f conftest*])
1666 use_default_link=$libc_cv_use_default_link
1667 fi
1669 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1670 if libc_cv_output_format=`
1671 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1672 then
1673 :
1674 else
1675 libc_cv_output_format=
1676 fi
1677 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1678 AC_SUBST(libc_cv_output_format)
1680 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1681 cat > conftest.c <<EOF
1682 int foo;
1683 EOF
1684 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1685 conftest.c 1>&AS_MESSAGE_LOG_FD])
1686 then
1687 libc_cv_fno_toplevel_reorder=yes
1688 else
1689 libc_cv_fno_toplevel_reorder=no
1690 fi
1691 rm -f conftest*])
1692 if test $libc_cv_fno_toplevel_reorder = yes; then
1693 fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1694 else
1695 fno_unit_at_a_time=-fno-unit-at-a-time
1696 fi
1697 AC_SUBST(fno_unit_at_a_time)
1699 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1700 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1701 [libc_cv_ssp=yes],
1702 [libc_cv_ssp=no])
1703 ])
1704 AC_SUBST(libc_cv_ssp)
1706 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1707 cat > conftest.c <<EOF
1708 int foo;
1709 #ifdef __GNUC_GNU_INLINE__
1710 main () { return 0;}
1711 #else
1712 #error
1713 #endif
1714 EOF
1715 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1716 -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1717 then
1718 libc_cv_gnu89_inline=yes
1719 else
1720 libc_cv_gnu89_inline=no
1721 fi
1722 rm -f conftest*])
1723 if test $libc_cv_gnu89_inline = yes; then
1724 gnu89_inline=-fgnu89-inline
1725 else
1726 gnu89_inline=
1727 fi
1728 AC_SUBST(gnu89_inline)
1730 AC_CACHE_CHECK(whether cc puts quotes around section names,
1731 libc_cv_have_section_quotes,
1732 [cat > conftest.c <<EOF
1733 static const int foo
1734 __attribute__ ((section ("bar"))) = 1;
1735 EOF
1736 if ${CC-cc} -S conftest.c -o conftest.s; then
1737 if grep '\.section.*"bar"' conftest.s >/dev/null; then
1738 libc_cv_have_section_quotes=yes
1739 else
1740 libc_cv_have_section_quotes=no
1741 fi
1742 else
1743 libc_cv_have_section_quotes=unknown
1744 fi
1745 rm -f conftest.{c,s}
1746 ])
1747 if test $libc_cv_have_section_quotes = yes; then
1748 AC_DEFINE(HAVE_SECTION_QUOTES)
1749 fi
1751 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1752 [dnl
1753 cat > conftest.s <<EOF
1754 ${libc_cv_dot_text}
1755 .globl foo
1756 foo:
1757 .weak foo
1758 .weak bar; bar = foo
1759 EOF
1760 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1761 libc_cv_asm_weak_directive=yes
1762 else
1763 libc_cv_asm_weak_directive=no
1764 fi
1765 rm -f conftest*])
1767 if test $libc_cv_asm_weak_directive = no; then
1768 AC_CACHE_CHECK(for assembler .weakext directive,
1769 libc_cv_asm_weakext_directive,
1770 [dnl
1771 cat > conftest.s <<EOF
1772 ${libc_cv_dot_text}
1773 .globl foo
1774 foo:
1775 .weakext bar foo
1776 .weakext baz
1777 .globl baz
1778 baz:
1779 EOF
1780 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1781 libc_cv_asm_weakext_directive=yes
1782 else
1783 libc_cv_asm_weakext_directive=no
1784 fi
1785 rm -f conftest*])
1787 fi # no .weak
1789 if test $libc_cv_asm_weak_directive = yes; then
1790 AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1791 elif test $libc_cv_asm_weakext_directive = yes; then
1792 AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1793 fi
1795 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1796 case $machine in
1797 sparc/sparc64*) cfi_offset=2047;;
1798 *) cfi_offset=0;;
1799 esac
1800 cat > conftest.s <<EOF
1801 .text
1802 .type func,%function
1803 func:
1804 .cfi_startproc
1805 .cfi_remember_state
1806 .cfi_rel_offset 1, $cfi_offset
1807 .cfi_endproc
1808 EOF
1809 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1810 libc_cv_asm_cfi_directives=yes
1811 else
1812 libc_cv_asm_cfi_directives=no
1813 fi
1814 rm -f conftest*])
1815 if test $libc_cv_asm_cfi_directives = yes; then
1816 AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1817 fi
1819 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1820 cat > conftest.c <<\EOF
1821 _start () {}
1822 int __eh_pc;
1823 __throw () {}
1824 EOF
1825 dnl No \ in command here because it ends up inside ''.
1826 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1827 -nostdlib -nostartfiles -Wl,--no-whole-archive
1828 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1829 libc_cv_ld_no_whole_archive=yes
1830 else
1831 libc_cv_ld_no_whole_archive=no
1832 fi
1833 rm -f conftest*])
1834 if test $libc_cv_ld_no_whole_archive = no; then
1835 AC_MSG_ERROR([support for --no-whole-archive is needed])
1836 fi
1838 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1839 cat > conftest.c <<\EOF
1840 _start () {}
1841 int __eh_pc;
1842 __throw () {}
1843 EOF
1844 dnl No \ in command here because it ends up inside ''.
1845 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1846 -nostdlib -nostartfiles -fexceptions
1847 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1848 libc_cv_gcc_exceptions=yes
1849 else
1850 libc_cv_gcc_exceptions=no
1851 fi
1852 rm -f conftest*])
1853 if test $libc_cv_gcc_exceptions = yes; then
1854 exceptions=-fexceptions
1855 fi
1856 AC_SUBST(exceptions)dnl
1858 if test "$host_cpu" = powerpc ; then
1859 # Check for a bug present in at least versions 2.8.x of GCC
1860 # and versions 1.0.x of EGCS.
1861 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1862 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1863 libc_cv_c_asmcr0_bug='no',
1864 libc_cv_c_asmcr0_bug='yes')])
1865 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1866 AC_DEFINE(BROKEN_PPC_ASM_CR0)
1867 fi
1868 fi
1870 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1871 cat > conftest.c <<\EOF
1872 void zero (void *x)
1873 {
1874 __builtin_memset (x, 0, 1000);
1875 }
1876 EOF
1877 dnl
1878 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1879 then
1880 libc_cv_gcc_builtin_memset=no
1881 else
1882 libc_cv_gcc_builtin_memset=yes
1883 fi
1884 rm -f conftest* ])
1885 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1886 AC_DEFINE(HAVE_BUILTIN_MEMSET)
1887 fi
1889 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1890 cat > conftest.c <<\EOF
1891 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1892 char *foo (const char *a, const char *b)
1893 {
1894 return __builtin_strstr (a, b);
1895 }
1896 EOF
1897 dnl
1898 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1899 then
1900 libc_cv_gcc_builtin_redirection=yes
1901 else
1902 libc_cv_gcc_builtin_redirection=no
1903 fi
1904 rm -f conftest* ])
1905 if test "$libc_cv_gcc_builtin_redirection" = no; then
1906 AC_MSG_ERROR([support for the symbol redirection needed])
1907 fi
1909 dnl Check whether the compiler supports the __thread keyword.
1910 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1911 [cat > conftest.c <<\EOF
1912 __thread int a = 42;
1913 EOF
1914 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1915 libc_cv_gcc___thread=yes
1916 else
1917 libc_cv_gcc___thread=no
1918 fi
1919 rm -f conftest*])
1920 if test "$libc_cv_gcc___thread" = no; then
1921 AC_MSG_ERROR([support for the __thread keyword is required])
1922 fi
1924 dnl Check whether the compiler supports the tls_model attribute.
1925 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1926 cat > conftest.c <<\EOF
1927 extern __thread int a __attribute__((tls_model ("initial-exec")));
1928 EOF
1929 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
1930 libc_cv_gcc_tls_model_attr=yes
1931 else
1932 libc_cv_gcc_tls_model_attr=no
1933 fi
1934 rm -f conftest*])
1935 if test "$libc_cv_gcc_tls_model_attr" = no; then
1936 AC_MSG_ERROR([support for the tls_model attribute is required])
1937 fi
1939 dnl Determine how to disable generation of FMA instructions.
1940 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1941 libc_cv_cc_nofma, [dnl
1942 libc_cv_cc_nofma=
1943 for opt in -ffp-contract=off -mno-fused-madd; do
1944 LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1945 done])
1947 if test -n "$submachine"; then
1948 AC_CACHE_CHECK([for compiler option for CPU variant],
1949 libc_cv_cc_submachine, [dnl
1950 libc_cv_cc_submachine=no
1951 for opt in "-march=$submachine" "-mcpu=$submachine"; do
1952 LIBC_TRY_CC_OPTION([$opt], [
1953 libc_cv_cc_submachine="$opt"
1954 break], [])
1955 done])
1956 if test "x$libc_cv_cc_submachine" = xno; then
1957 AC_MSG_ERROR([${CC-cc} does not support $submachine])
1958 fi
1959 fi
1960 AC_SUBST(libc_cv_cc_submachine)
1962 dnl Check whether we have the gd library available.
1963 AC_MSG_CHECKING(for libgd)
1964 if test "$with_gd" != "no"; then
1965 old_CFLAGS="$CFLAGS"
1966 CFLAGS="$CFLAGS $libgd_include"
1967 old_LDFLAGS="$LDFLAGS"
1968 LDFLAGS="$LDFLAGS $libgd_ldflags"
1969 old_LIBS="$LIBS"
1970 LIBS="$LIBS -lgd -lpng -lz -lm"
1971 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1972 CFLAGS="$old_CFLAGS"
1973 LDFLAGS="$old_LDFLAGS"
1974 LIBS="$old_LIBS"
1975 else
1976 LIBGD=no
1977 fi
1978 AC_MSG_RESULT($LIBGD)
1979 AC_SUBST(LIBGD)
1981 # SELinux detection
1982 if test x$with_selinux = xno ; then
1983 have_selinux=no;
1984 else
1985 # See if we have the SELinux library
1986 AC_CHECK_LIB(selinux, is_selinux_enabled,
1987 have_selinux=yes, have_selinux=no)
1988 # See if we have the SELinux header with the NSCD permissions in it.
1989 if test x$have_selinux = xyes ; then
1990 AC_MSG_CHECKING([for NSCD Flask permissions in selinux/av_permissions.h])
1991 AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
1992 [#ifdef NSCD__SHMEMHOST
1993 return 0;
1994 #else
1995 #error NSCD__SHMEMHOST not defined
1996 #endif],
1997 have_selinux=yes, have_selinux=no)
1998 AC_MSG_RESULT($have_selinux)
1999 fi
2001 if test x$with_selinux = xyes ; then
2002 if test x$have_selinux = xno ; then
2003 AC_MSG_ERROR([SELinux explicitly required, but sufficiently recent SELinux library not found])
2004 fi
2005 fi
2006 fi
2007 # Check if we're building with SELinux support.
2008 if test "x$have_selinux" = xyes; then
2009 AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
2011 # See if we have the libaudit library
2012 AC_CHECK_LIB(audit, audit_log_user_avc_message,
2013 have_libaudit=yes, have_libaudit=no)
2014 if test "x$have_libaudit" = xyes; then
2015 AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
2016 fi
2017 AC_SUBST(have_libaudit)
2019 # See if we have the libcap library
2020 AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
2021 if test "x$have_libcap" = xyes; then
2022 AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
2023 fi
2024 AC_SUBST(have_libcap)
2025 fi
2026 AC_SUBST(have_selinux)
2028 dnl check for the size of 'long double'.
2029 AC_CHECK_SIZEOF(long double, 0)
2030 sizeof_long_double=$ac_cv_sizeof_long_double
2031 AC_SUBST(sizeof_long_double)
2033 CPPUNDEFS=
2034 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
2035 dnl Since we are building the implementations of the fortified functions here,
2036 dnl having the macro defined interacts very badly.
2037 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
2038 [AC_TRY_COMPILE([], [
2039 #ifdef _FORTIFY_SOURCE
2040 # error bogon
2041 #endif],
2042 [libc_cv_predef_fortify_source=no],
2043 [libc_cv_predef_fortify_source=yes])])
2044 if test $libc_cv_predef_fortify_source = yes; then
2045 CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
2046 fi
2047 AC_SUBST(CPPUNDEFS)
2049 dnl Check for silly hacked compilers inserting -fstack-protector.
2050 dnl This breaks badly for the early startup code we compile, since
2051 dnl the compiled code can refer to a magic machine-dependent location
2052 dnl for the canary value before we have sufficient setup for that to
2053 dnl work. It's also questionable to build all of libc with this flag
2054 dnl even when you're doing that for most applications you build, since
2055 dnl libc's code is so heavily-used and performance-sensitive. If we
2056 dnl ever really want to make that work, it should be enabled explicitly
2057 dnl in the libc build, not inherited from implicit compiler settings.
2058 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
2059 libc_cv_predef_stack_protector, [
2060 AC_TRY_COMPILE([extern void foobar (char *);],
2061 [char large_array[2048]; foobar (large_array);], [
2062 libc_undefs=`$NM -u conftest.o |
2063 LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
2064 2>&AS_MESSAGE_LOG_FD` || {
2065 AC_MSG_ERROR([confusing output from $NM -u])
2066 }
2067 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
2068 # On some architectures, there are architecture-specific undefined
2069 # symbols (resolved by the linker), so filter out unknown symbols.
2070 # This will fail to produce the correct result if the compiler
2071 # defaults to -fstack-protector but this produces an undefined symbol
2072 # other than __stack_chk_fail. However, compilers like that have not
2073 # been encountered in practice.
2074 libc_undefs=`echo "$libc_undefs" | egrep '^(foobar|__stack_chk_fail)$'`
2075 case "$libc_undefs" in
2076 foobar) libc_cv_predef_stack_protector=no ;;
2077 '__stack_chk_fail
2078 foobar') libc_cv_predef_stack_protector=yes ;;
2079 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
2080 esac],
2081 [AC_MSG_ERROR([test compilation failed])])
2082 ])
2083 libc_extra_cflags=
2084 if test $libc_cv_predef_stack_protector = yes; then
2085 libc_extra_cflags=-fno-stack-protector
2086 fi
2087 AC_SUBST(libc_extra_cflags)
2089 ### End of automated tests.
2090 ### Now run sysdeps configure fragments.
2092 # They also can set these variables.
2093 use_ldconfig=no
2094 ldd_rewrite_script=no
2095 libc_cv_sysconfdir=$sysconfdir
2096 libc_cv_localstatedir=$localstatedir
2097 libc_cv_gcc_unwind_find_fde=no
2098 libc_cv_idn=no
2100 # Iterate over all the sysdep directories we will use, running their
2101 # configure fragments.
2102 for dir in $sysnames; do
2103 case $dir in
2104 /*) dest=$dir ;;
2105 *) dest=$srcdir/$dir ;;
2106 esac
2107 if test -r $dest/configure; then
2108 AC_MSG_RESULT(running configure fragment for $dir)
2109 . $dest/configure
2110 fi
2111 done
2113 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2114 AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2115 fi
2116 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2118 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
2119 # configure fragment can override the value to prevent this AC_DEFINE.
2120 AC_SUBST(use_nscd)
2121 if test "x$use_nscd" != xno; then
2122 AC_DEFINE([USE_NSCD])
2123 fi
2124 if test "x$build_nscd" = xdefault; then
2125 build_nscd=$use_nscd
2126 fi
2128 # Test for old glibc 2.0.x headers so that they can be removed properly
2129 # Search only in includedir.
2130 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2131 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2132 then
2133 old_glibc_headers=yes
2134 else
2135 old_glibc_headers=no
2136 fi
2137 AC_MSG_RESULT($old_glibc_headers)
2138 if test ${old_glibc_headers} = yes; then
2139 AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2140 AC_MSG_WARN(*** be removed.)
2141 fi
2142 AC_SUBST(old_glibc_headers)
2144 AC_SUBST(libc_cv_slibdir)
2145 AC_SUBST(libc_cv_localedir)
2146 AC_SUBST(libc_cv_sysconfdir)
2147 AC_SUBST(libc_cv_localstatedir)
2148 AC_SUBST(libc_cv_rootsbindir)
2149 AC_SUBST(libc_cv_forced_unwind)
2151 dnl sysdeps/CPU/configure.in checks set this via arch-specific asm tests
2152 AC_SUBST(libc_cv_cpp_asm_debuginfo)
2153 AC_SUBST(libc_cv_cc_sse4)
2154 AC_SUBST(libc_cv_cc_avx)
2155 AC_SUBST(libc_cv_cc_sse2avx)
2156 AC_SUBST(libc_cv_cc_novzeroupper)
2157 AC_SUBST(libc_cv_cc_fma4)
2158 AC_SUBST(libc_cv_cc_nofma)
2159 AC_SUBST(libc_cv_as_i686)
2160 AC_SUBST(libc_cv_sparc_as_vis3)
2162 AC_SUBST(use_ldconfig)
2163 AC_SUBST(ldd_rewrite_script)
2165 AC_SUBST(static)
2166 AC_SUBST(shared)
2168 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2169 [libc_cv_pic_default=yes
2170 cat > conftest.c <<EOF
2171 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2172 # error PIC is default.
2173 #endif
2174 EOF
2175 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2176 libc_cv_pic_default=no
2177 fi
2178 rm -f conftest.*])
2179 AC_SUBST(libc_cv_pic_default)
2181 AC_SUBST(profile)
2182 AC_SUBST(static_nss)
2184 AC_SUBST(DEFINES)
2186 dnl See sysdeps/mach/configure.in for this variable.
2187 AC_SUBST(mach_interface_list)
2189 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
2190 config_makefile=
2191 else
2192 config_makefile=Makefile
2193 fi
2195 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2196 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2197 AC_SUBST(VERSION)
2198 AC_SUBST(RELEASE)
2200 AC_CONFIG_FILES([config.make ${config_makefile}])
2201 AC_CONFIG_COMMANDS([default],[[
2202 case $CONFIG_FILES in *config.make*)
2203 echo "$config_vars" >> config.make;;
2204 esac
2205 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2206 AC_OUTPUT