sysdeps/x86_64/nptl/pthread_spin_lock.S

   1 /* Copyright (C) 2012-2024 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, see
  16    <https://www.gnu.org/licenses/>.  */
  17
  18 #include <sysdep.h>
  19 #include <shlib-compat.h>
  20
  21 ENTRY(__pthread_spin_lock)
  22         /* Always return zero.  */
  23         xor     %eax, %eax
  24         LOCK
  25         decl    0(%rdi)
  26         jne     1f
  27         ret
  28
  29         .align  16
  30 1:
  31         /* `rep nop` == `pause`.  */
  32         rep
  33         nop
  34         cmpl    %eax, 0(%rdi)
  35         jle     1b
  36         /* Just repeat the `lock decl` logic here.  The code size save
  37            of jumping back to entry doesn't change how many 16-byte
  38            chunks (default function alignment) that the code fits in.  */
  39         LOCK
  40         decl    0(%rdi)
  41         jne     1b
  42         ret
  43 END(__pthread_spin_lock)
  44 versioned_symbol (libc, __pthread_spin_lock, pthread_spin_lock, GLIBC_2_34)
  45
  46 #if OTHER_SHLIB_COMPAT (libpthread, GLIBC_2_2, GLIBC_2_34)
  47 compat_symbol (libpthread, __pthread_spin_lock, pthread_spin_lock, GLIBC_2_2)
  48 #endif