sysdeps/unix/sysv/linux/s390/s390-64/setcontext.S

   1 /* Copyright (C) 2001-2024 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, see
  16    <https://www.gnu.org/licenses/>.  */
  17
  18 #include <sysdep.h>
  19 #include <features.h>
  20
  21 #include "ucontext_i.h"
  22
  23 /*  __setcontext (const ucontext_t *ucp)
  24
  25   Restores the machine context in UCP and thereby resumes execution
  26   in that context.
  27
  28   This implementation is intended to be used for *synchronous* context
  29   switches only.  Therefore, it does not have to restore anything
  30   other than the PRESERVED state.  */
  31
  32 ENTRY(__setcontext)
  33         lgr     %r0,%r2
  34
  35         /* sigprocmask (SIG_SETMASK, &sc->sc_mask, NULL).  */
  36         la      %r3,SC_MASK(%r2)
  37         la      %r2,SIG_SETMASK
  38         slgr    %r4,%r4
  39         lghi    %r5,_NSIG8
  40         lghi    %r1,SYS_ify(rt_sigprocmask)
  41         svc     0
  42
  43         /* Load fpu context.  */
  44         lgr     %r1,%r0
  45         lfpc    SC_FPC(%r1)
  46         ld      %f0,SC_FPRS(%r1)
  47         ld      %f1,SC_FPRS+8(%r1)
  48         ld      %f2,SC_FPRS+16(%r1)
  49         ld      %f3,SC_FPRS+24(%r1)
  50         ld      %f4,SC_FPRS+32(%r1)
  51         ld      %f5,SC_FPRS+40(%r1)
  52         ld      %f6,SC_FPRS+48(%r1)
  53         ld      %f7,SC_FPRS+56(%r1)
  54         ld      %f8,SC_FPRS+64(%r1)
  55         ld      %f9,SC_FPRS+72(%r1)
  56         ld      %f10,SC_FPRS+80(%r1)
  57         ld      %f11,SC_FPRS+88(%r1)
  58         ld      %f12,SC_FPRS+96(%r1)
  59         ld      %f13,SC_FPRS+104(%r1)
  60         ld      %f14,SC_FPRS+112(%r1)
  61         ld      %f15,SC_FPRS+120(%r1)
  62
  63         /* Don't touch %a0 and %a1, used for thread purposes.  */
  64         lam     %a2,%a15,SC_ACRS+8(%r1)
  65
  66         /* Load general purpose registers.  */
  67         lmg     %r0,%r15,SC_GPRS(%r1)
  68
  69         /* Return.  */
  70         br      %r14
  71 END(__setcontext)
  72
  73 weak_alias (__setcontext, setcontext)