sysdeps/sparc/sparc64/fpu/s_nearbyint.S

   1 /* Round float to int floating-point values without generating
   2    an inexact exception, sparc64 version.
   3
   4    Copyright (C) 2013-2024 Free Software Foundation, Inc.
   5    This file is part of the GNU C Library.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, see
  19    <https://www.gnu.org/licenses/>.  */
  20
  21 #include <sysdep.h>
  22 #include <libm-alias-double.h>
  23
  24         /* We pop constants into the FPU registers using the incoming
  25            argument stack slots, since this avoid having to use any PIC
  26            references.  We also thus avoid having to allocate a register
  27            window.
  28
  29            VIS instructions are used to facilitate the formation of
  30            easier constants, and the propagation of the sign bit.  */
  31
  32 #define TWO_FIFTYTWO    0x43300000              /* 2**52 */
  33
  34 #define ZERO            %f10                    /* 0.0 */
  35 #define SIGN_BIT        %f12                    /* -0.0 */
  36
  37 ENTRY (__nearbyint)
  38         fcmpd   %fcc3, %f0, %f0                 /* Check for sNaN */
  39         stx     %fsr, [%sp + STACK_BIAS + 144]
  40         sethi   %hi(TWO_FIFTYTWO), %o2
  41         sllx    %o2, 32, %o2
  42         ldx     [%sp + STACK_BIAS + 144], %o4
  43         sethi   %hi(0xf8003e0), %o5
  44         fzero   ZERO
  45         or      %o5, %lo(0xf8003e0), %o5
  46         fnegd   ZERO, SIGN_BIT
  47         andn    %o4, %o5, %o4
  48         stx     %o2, [%sp + STACK_BIAS + 128]
  49         stx     %o4, [%sp + STACK_BIAS + 136]
  50         ldx     [%sp + STACK_BIAS + 136], %fsr
  51         fabsd   %f0, %f14
  52         ldd     [%sp + STACK_BIAS + 128], %f16
  53         fcmpd   %fcc3, %f14, %f16
  54         fmovduge %fcc3, ZERO, %f16
  55         fand    %f0, SIGN_BIT, SIGN_BIT
  56         for     %f16, SIGN_BIT, %f16
  57         faddd   %f0, %f16, %f6
  58         fsubd   %f6, %f16, %f0
  59         fabsd   %f0, %f0
  60         for     %f0, SIGN_BIT, %f0
  61         retl
  62          ldx    [%sp + STACK_BIAS + 144], %fsr
  63 END (__nearbyint)
  64 libm_alias_double (__nearbyint, nearbyint)