sysdeps/i386/bsd-setjmp.S

   1 /* BSD `setjmp' entry point to `sigsetjmp (..., 1)'.  i386 version.
   2    Copyright (C) 1994-2024 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <https://www.gnu.org/licenses/>.  */
  18
  19 /* This just does a tail-call to `__sigsetjmp (ARG, 1)'.
  20    We cannot do it in C because it must be a tail-call, so frame-unwinding
  21    in setjmp doesn't clobber the state restored by longjmp.  */
  22
  23 #include <sysdep.h>
  24 #include <pointer_guard.h>
  25 #include <jmpbuf-offsets.h>
  26 #include <stap-probe.h>
  27
  28 #define PARMS  4                /* no space for saved regs */
  29 #define JMPBUF PARMS
  30 #define SIGMSK JMPBUF+4
  31
  32 ENTRY (setjmp)
  33         /* Note that we have to use a non-exported symbol in the next
  34            jump since otherwise gas will emit it as a jump through the
  35            PLT which is what we cannot use here.  */
  36
  37         movl JMPBUF(%esp), %eax
  38
  39         /* Save registers.  */
  40         movl %ebx, (JB_BX*4)(%eax)
  41         movl %esi, (JB_SI*4)(%eax)
  42         movl %edi, (JB_DI*4)(%eax)
  43         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
  44 #ifdef PTR_MANGLE
  45         PTR_MANGLE (%ecx)
  46 #endif
  47         movl %ecx, (JB_SP*4)(%eax)
  48         movl 0(%esp), %ecx      /* Save PC we are returning to now.  */
  49         LIBC_PROBE (setjmp, 3, 4@%eax, -4@$1, 4@%ecx)
  50 #ifdef PTR_MANGLE
  51         PTR_MANGLE (%ecx)
  52 #endif
  53         movl %ecx, (JB_PC*4)(%eax)
  54         movl %ebp, (JB_BP*4)(%eax) /* Save caller's frame pointer.  */
  55
  56         /* Call __sigjmp_save.  */
  57         pushl $1
  58         cfi_adjust_cfa_offset (4)
  59         pushl 8(%esp)
  60         cfi_adjust_cfa_offset (4)
  61         call __sigjmp_save
  62         popl %ecx
  63         cfi_adjust_cfa_offset (-4)
  64         popl %edx
  65         cfi_adjust_cfa_offset (-4)
  66         ret
  67 END (setjmp)