sysdeps/i386/fpu/e_expl.S

   1 /*
   2  * Written by J.T. Conklin <jtc@netbsd.org>.
   3  * Public domain.
   4  *
   5  * Adapted for `long double' by Ulrich Drepper <drepper@cygnus.com>.
   6  */
   7
   8 /*
   9  * The 8087 method for the exponential function is to calculate
  10  *   exp(x) = 2^(x log2(e))
  11  * after separating integer and fractional parts
  12  *   x log2(e) = i + f, |f| <= .5
  13  * 2^i is immediate but f needs to be precise for long double accuracy.
  14  * Suppress range reduction error in computing f by the following.
  15  * Separate x into integer and fractional parts
  16  *   x = xi + xf, |xf| <= .5
  17  * Separate log2(e) into the sum of an exact number c0 and small part c1.
  18  *   c0 + c1 = log2(e) to extra precision
  19  * Then
  20  *   f = (c0 xi - i) + c0 xf + c1 x
  21  * where c0 xi is exact and so also is (c0 xi - i).
  22  * -- moshier@na-net.ornl.gov
  23  */
  24
  25 #include <machine/asm.h>
  26 #include <i386-math-asm.h>
  27
  28 #ifdef USE_AS_EXP10L
  29 # define IEEE754_EXPL __ieee754_exp10l
  30 # define EXPL_FINITE __exp10l_finite
  31 # define FLDLOG fldl2t
  32 #elif defined USE_AS_EXPM1L
  33 # define IEEE754_EXPL __expm1l
  34 # undef EXPL_FINITE
  35 # define FLDLOG fldl2e
  36 #else
  37 # define IEEE754_EXPL __ieee754_expl
  38 # define EXPL_FINITE __expl_finite
  39 # define FLDLOG fldl2e
  40 #endif
  41
  42         .section .rodata.cst16,"aM",@progbits,16
  43
  44         .p2align 4
  45 #ifdef USE_AS_EXP10L
  46         .type c0,@object
  47 c0:     .byte 0, 0, 0, 0, 0, 0, 0x9a, 0xd4, 0x00, 0x40
  48         .byte 0, 0, 0, 0, 0, 0
  49         ASM_SIZE_DIRECTIVE(c0)
  50         .type c1,@object
  51 c1:     .byte 0x58, 0x92, 0xfc, 0x15, 0x37, 0x9a, 0x97, 0xf0, 0xef, 0x3f
  52         .byte 0, 0, 0, 0, 0, 0
  53         ASM_SIZE_DIRECTIVE(c1)
  54 #else
  55         .type c0,@object
  56 c0:     .byte 0, 0, 0, 0, 0, 0, 0xaa, 0xb8, 0xff, 0x3f
  57         .byte 0, 0, 0, 0, 0, 0
  58         ASM_SIZE_DIRECTIVE(c0)
  59         .type c1,@object
  60 c1:     .byte 0x20, 0xfa, 0xee, 0xc2, 0x5f, 0x70, 0xa5, 0xec, 0xed, 0x3f
  61         .byte 0, 0, 0, 0, 0, 0
  62         ASM_SIZE_DIRECTIVE(c1)
  63 #endif
  64 #ifndef USE_AS_EXPM1L
  65         .type csat,@object
  66 csat:   .byte 0, 0, 0, 0, 0, 0, 0, 0x80, 0x0e, 0x40
  67         .byte 0, 0, 0, 0, 0, 0
  68         ASM_SIZE_DIRECTIVE(csat)
  69 DEFINE_LDBL_MIN
  70 #endif
  71
  72 #ifdef PIC
  73 # define MO(op) op##@GOTOFF(%ecx)
  74 #else
  75 # define MO(op) op
  76 #endif
  77
  78         .text
  79 ENTRY(IEEE754_EXPL)
  80 #ifdef USE_AS_EXPM1L
  81         movzwl  4+8(%esp), %eax
  82         xorb    $0x80, %ah      // invert sign bit (now 1 is "positive")
  83         cmpl    $0xc006, %eax   // is num positive and exp >= 6 (number is >= 128.0)?
  84         jae     HIDDEN_JUMPTARGET (__expl) // (if num is denormal, it is at least >= 64.0)
  85 #endif
  86         fldt    4(%esp)
  87 /* I added the following ugly construct because expl(+-Inf) resulted
  88    in NaN.  The ugliness results from the bright minds at Intel.
  89    For the i686 the code can be written better.
  90    -- drepper@cygnus.com.  */
  91         fxam                    /* Is NaN or +-Inf?  */
  92 #ifdef PIC
  93         LOAD_PIC_REG (cx)
  94 #endif
  95 #ifdef USE_AS_EXPM1L
  96         xorb    $0x80, %ah
  97         cmpl    $0xc006, %eax
  98         fstsw   %ax
  99         movb    $0x45, %dh
 100         jb      4f
 101
 102         /* Below -64.0 (may be -NaN or -Inf). */
 103         andb    %ah, %dh
 104         cmpb    $0x01, %dh
 105         je      6f              /* Is +-NaN, jump.  */
 106         jmp     1f              /* -large, possibly -Inf.  */
 107
 108 4:      /* In range -64.0 to 64.0 (may be +-0 but not NaN or +-Inf).  */
 109         /* Test for +-0 as argument.  */
 110         andb    %ah, %dh
 111         cmpb    $0x40, %dh
 112         je      2f
 113
 114         /* Test for arguments that are small but not subnormal.  */
 115         movzwl  4+8(%esp), %eax
 116         andl    $0x7fff, %eax
 117         cmpl    $0x3fbf, %eax
 118         jge     3f
 119         /* Argument's exponent below -64; avoid spurious underflow if
 120            normal.  */
 121         cmpl    $0x0001, %eax
 122         jge     2f
 123         /* Force underflow and return the argument, to avoid wrong signs
 124            of zero results from the code below in some rounding modes.  */
 125         fld     %st
 126         fmul    %st
 127         fstp    %st
 128         jmp     2f
 129 #else
 130         movzwl  4+8(%esp), %eax
 131         andl    $0x7fff, %eax
 132         cmpl    $0x400d, %eax
 133         jg      5f
 134         cmpl    $0x3fbc, %eax
 135         jge     3f
 136         /* Argument's exponent below -67, result rounds to 1.  */
 137         fld1
 138         faddp
 139         jmp     2f
 140 5:      /* Overflow, underflow or infinity or NaN as argument.  */
 141         fstsw   %ax
 142         movb    $0x45, %dh
 143         andb    %ah, %dh
 144         cmpb    $0x05, %dh
 145         je      1f              /* Is +-Inf, jump.    */
 146         cmpb    $0x01, %dh
 147         je      6f              /* Is +-NaN, jump.    */
 148         /* Overflow or underflow; saturate.  */
 149         fstp    %st
 150         fldt    MO(csat)
 151         andb    $2, %ah
 152         jz      3f
 153         fchs
 154 #endif
 155 3:      FLDLOG                  /* 1  log2(base)      */
 156         fmul    %st(1), %st     /* 1  x log2(base)    */
 157         /* Set round-to-nearest temporarily.  */
 158         subl    $8, %esp
 159         cfi_adjust_cfa_offset (8)
 160         fstcw   4(%esp)
 161         movl    $0xf3ff, %edx
 162         andl    4(%esp), %edx
 163         movl    %edx, (%esp)
 164         fldcw   (%esp)
 165         frndint                 /* 1  i               */
 166         fld     %st(1)          /* 2  x               */
 167         frndint                 /* 2  xi              */
 168         fldcw   4(%esp)
 169         addl    $8, %esp
 170         cfi_adjust_cfa_offset (-8)
 171         fld     %st(1)          /* 3  i               */
 172         fldt    MO(c0)          /* 4  c0              */
 173         fld     %st(2)          /* 5  xi              */
 174         fmul    %st(1), %st     /* 5  c0 xi           */
 175         fsubp   %st, %st(2)     /* 4  f = c0 xi  - i  */
 176         fld     %st(4)          /* 5  x               */
 177         fsub    %st(3), %st     /* 5  xf = x - xi     */
 178         fmulp   %st, %st(1)     /* 4  c0 xf           */
 179         faddp   %st, %st(1)     /* 3  f = f + c0 xf   */
 180         fldt    MO(c1)          /* 4                  */
 181         fmul    %st(4), %st     /* 4  c1 * x          */
 182         faddp   %st, %st(1)     /* 3  f = f + c1 * x  */
 183         f2xm1                   /* 3 2^(fract(x * log2(base))) - 1 */
 184 #ifdef USE_AS_EXPM1L
 185         fstp    %st(1)          /* 2                  */
 186         fscale                  /* 2 scale factor is st(1); base^x - 2^i */
 187         fxch                    /* 2 i                */
 188         fld1                    /* 3 1.0              */
 189         fscale                  /* 3 2^i              */
 190         fld1                    /* 4 1.0              */
 191         fsubrp  %st, %st(1)     /* 3 2^i - 1.0        */
 192         fstp    %st(1)          /* 2                  */
 193         faddp   %st, %st(1)     /* 1 base^x - 1.0     */
 194 #else
 195         fld1                    /* 4 1.0              */
 196         faddp                   /* 3 2^(fract(x * log2(base))) */
 197         fstp    %st(1)          /* 2  */
 198         fscale                  /* 2 scale factor is st(1); base^x */
 199         fstp    %st(1)          /* 1  */
 200         LDBL_CHECK_FORCE_UFLOW_NONNEG
 201 #endif
 202         fstp    %st(1)          /* 0  */
 203         jmp     2f
 204 1:
 205 #ifdef USE_AS_EXPM1L
 206         /* For expm1l, only negative sign gets here.  */
 207         fstp    %st
 208         fld1
 209         fchs
 210 #else
 211         testl   $0x200, %eax    /* Test sign.  */
 212         jz      2f              /* If positive, jump.  */
 213         fstp    %st
 214         fldz                    /* Set result to 0.  */
 215 #endif
 216 2:      ret
 217 6:      /* NaN argument.  */
 218         fadd    %st
 219         ret
 220 END(IEEE754_EXPL)
 221 #ifdef USE_AS_EXPM1L
 222 libm_hidden_def (__expm1l)
 223 weak_alias (__expm1l, expm1l)
 224 #else
 225 strong_alias (IEEE754_EXPL, EXPL_FINITE)
 226 #endif