sysdeps/unix/sysv/linux/powerpc/powerpc32/brk.S

   1 /* brk system call for Linux/ppc.
   2    Copyright (C) 1995, 1996, 1997, 1999, 2000 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #define _ERRNO_H        1
  22 #include <bits/errno.h>
  23 #include <bp-sym.h>
  24 #include <bp-asm.h>
  25
  26         .comm   __curbrk,4,4
  27         .section ".text"
  28 ENTRY (BP_SYM (__brk))
  29         DISCARD_BOUNDS (r3)     /* the bounds are meaningless, so toss 'em */
  30
  31         stwu    r1,-16(r1)
  32         stw     r3,8(r1)
  33         DO_CALL(SYS_ify(brk))
  34         lwz     r6,8(r1)
  35 #ifdef PIC
  36         mflr    r4
  37 # ifdef HAVE_ASM_PPC_REL16
  38         bcl     20,31,1f
  39 1:      mflr    r5
  40         addis   r5,r5,__curbrk-1b@ha
  41         mtlr    r4
  42         stw     r3,__curbrk-1b@l(r5)
  43 # else
  44         bl      _GLOBAL_OFFSET_TABLE_@local-4
  45         mflr    r5
  46         lwz     r5,__curbrk@got(r5)
  47         mtlr    r4
  48         stw     r3,0(r5)
  49 # endif
  50 #else
  51         lis     r4,__curbrk@ha
  52         stw     r3,__curbrk@l(r4)
  53 #endif
  54         cmplw   r6,r3
  55         addi    r1,r1,16
  56         li      r3,0
  57         blelr+
  58         li      r3,ENOMEM
  59         b       __syscall_error@local
  60 END (BP_SYM (__brk))
  61
  62 weak_alias (BP_SYM (__brk), BP_SYM (brk))