sysdeps/powerpc/powerpc32/fpu/s_rintf.S

   1 /* Round float to int floating-point values.  PowerPC32 version.
   2    Copyright (C) 2004 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21
  22         .section        .rodata.cst4,"aM",@progbits,4
  23         .align  2
  24 .LC0:   /* 2**23 */
  25         .long 0x4b000000
  26
  27         .section        ".text"
  28 ENTRY (__rintf)
  29 #ifdef SHARED
  30         mflr    r11
  31 # ifdef HAVE_ASM_PPC_REL16
  32         bcl     20,31,1f
  33 1:      mflr    r9
  34         addis   r9,r9,.LC0-1b@ha
  35         mtlr    r11
  36         lfs     fp13,.LC0-1b@l(r9)
  37 # else
  38         bl      _GLOBAL_OFFSET_TABLE_@local-4
  39         mflr    r10
  40         lwz     r9,.LC0@got(10)
  41         mtlr    r11
  42         lfs     fp13,0(r9)
  43 # endif
  44 #else
  45         lis     r9,.LC0@ha
  46         lfs     fp13,.LC0@l(r9)
  47 #endif
  48         fabs    fp0,fp1
  49         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  50         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  51         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  52         bnllr-  cr7
  53         bng-    cr6,.L4
  54         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  55         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  56         fabs    fp1,fp1         /* if (x == 0.0)  */
  57         blr                     /* x = 0.0; */
  58 .L4:
  59         bnllr-  cr6             /* if (x < 0.0)  */
  60         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  61         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  62         fnabs   fp1,fp1         /* if (x == 0.0)  */
  63         blr                     /* x = -0.0; */
  64         END (__rintf)
  65
  66 weak_alias (__rintf, rintf)
  67