sysdeps/powerpc/powerpc32/fpu/s_lround.S

   1 /* lround function.  PowerPC32 version.
   2    Copyright (C) 2004 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21
  22         .section        .rodata.cst8,"aM",@progbits,8
  23         .align  2
  24 .LC0:   /* 0.0 */
  25         .long 0x00000000
  26 .LC1:   /* 0.5 */
  27         .long 0x3f000000
  28
  29         .section        ".text"
  30
  31 /* long [r3] lround (float x [fp1])
  32    IEEE 1003.1 lround function.  IEEE specifies "round to the nearest
  33    integer value, rounding halfway cases away from zero, regardless of
  34    the current rounding mode."  However PowerPC Architecture defines
  35    "round to Nearest" as "Choose the best approximation. In case of a
  36    tie, choose the one that is even (least significant bit o).".
  37    So we can't use the PowerPC "round to Nearest" mode. Instead we set
  38    "round toward Zero" mode and round by adding +-0.5 before rounding
  39    to the integer value.  */
  40
  41 ENTRY (__lround)
  42 #ifdef SHARED
  43         mflr    r11
  44 # ifdef HAVE_ASM_PPC_REL16
  45         bcl     20,31,1f
  46 1:      mflr    r9
  47         addis   r9,r9,.LC0-1b@ha
  48         addi    r9,r9,.LC0-1b@l
  49 # else
  50         bl      _GLOBAL_OFFSET_TABLE_@local-4
  51         mflr    r10
  52         lwz     r9,.LC0@got(10)
  53 # endif
  54         mtlr    r11
  55         lfs     fp12,0(r9)
  56 #else
  57         lis     r9,.LC0@ha
  58         lfs     fp12,.LC0@l(r9)
  59 #endif
  60 #ifdef SHARED
  61         lfs     fp10,.LC1-.LC0(r9)
  62 #else
  63         lis     r9,.LC1@ha
  64         lfs     fp10,.LC1@l(r9)
  65 #endif
  66         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  67         ble-    cr6,.L4
  68         fadd    fp1,fp1,fp10    /* x+= 0.5;  */
  69 .L9:
  70         fctiwz  fp2,fp1         /* Convert To Integer DW lround toward 0.  */
  71         stfd    fp2,-8(r1)
  72         nop     /* Ensure the following load is in a different dispatch  */
  73         nop     /* group to avoid pipe stall on POWER4&5.  */
  74         nop
  75         lwz     r3,-4(r1)
  76         blr
  77 .L4:
  78         fsub    fp1,fp1,fp10    /* x-= 0.5;  */
  79         b       .L9
  80         END (__lround)
  81
  82 strong_alias (__lround, __lround)
  83 weak_alias (__lround, lround)
  84
  85 strong_alias (__lround, __lroundf)
  86 weak_alias (__lround, lroundf)
  87
  88 #ifdef NO_LONG_DOUBLE
  89 weak_alias (__lround, lroundl)
  90 strong_alias (__lround, __lroundl)
  91 #endif