sysdeps/powerpc/powerpc32/fpu/s_floor.S

   1 /* Floor function.  PowerPC32 version.
   2    Copyright (C) 2004 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21
  22         .section        .rodata.cst4,"aM",@progbits,4
  23         .align  2
  24 .LC0:   /* 2**52 */
  25         .long 0x59800000
  26
  27         .section        ".text"
  28 ENTRY (__floor)
  29         mffs    fp11            /* Save current FPU rounding mode.  */
  30 #ifdef SHARED
  31         mflr    r11
  32 # ifdef HAVE_ASM_PPC_REL16
  33         bcl     20,31,1f
  34 1:      mflr    r9
  35         addis   r9,r9,.LC0-1b@ha
  36         mtlr    r11
  37         lfs     fp13,.LC0-1b@l(r9)
  38 # else
  39         bl      _GLOBAL_OFFSET_TABLE_@local-4
  40         mflr    r10
  41         lwz     r9,.LC0@got(10)
  42         mtlr    r11
  43         lfs     fp13,0(r9)
  44 # endif
  45 #else
  46         lis     r9,.LC0@ha
  47         lfs     fp13,.LC0@l(r9)
  48 #endif
  49         fabs    fp0,fp1
  50         fsub    fp12,fp13,fp13  /* generate 0.0  */
  51         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  52         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  53         bnllr-  cr7
  54         mtfsfi  7,3             /* Set rounding mode toward -inf.  */
  55         ble-    cr6,.L4
  56         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  57         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  58         fabs    fp1,fp1         /* if (x == 0.0)  */
  59                                 /* x = 0.0; */
  60         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  61         blr
  62 .L4:
  63         bge-    cr6,.L9         /* if (x < 0.0)  */
  64         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  65         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  66         fnabs   fp1,fp1         /* if (x == 0.0)  */
  67                                 /* x = -0.0; */
  68 .L9:
  69         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  70         blr
  71         END (__floor)
  72
  73 weak_alias (__floor, floor)
  74
  75 #ifdef NO_LONG_DOUBLE
  76 weak_alias (__floor, floorl)
  77 strong_alias (__floor, __floorl)
  78 #endif