| blob | e69c88c543521923e3af9b25b85af2edbb6dc162 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Note we do not use AC_PREREQ here! See aclocal.m4 for what we use instead.
3 AC_INIT([GNU C Library], [(see version.h)], [https://sourceware.org/bugzilla/],
4 [glibc], [https://www.gnu.org/software/glibc/])
5 AC_CONFIG_SRCDIR([include/features.h])
6 AC_CONFIG_HEADERS([config.h])
7 AC_CONFIG_AUX_DIR([scripts])
9 ACX_PKGVERSION([GNU libc])
10 ACX_BUGURL([https://www.gnu.org/software/libc/bugs.html])
11 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
12 [Package description])
13 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
14 [Bug reporting address])
16 # Glibc should not depend on any header files
17 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
18 [m4_divert_text([DEFAULTS],
19 [ac_includes_default='/* none */'])])
21 # We require GCC, and by default use its preprocessor. Override AC_PROG_CPP
22 # here to work around the Autoconf issue discussed in
23 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
24 AC_DEFUN([AC_PROG_CPP],
25 [AC_REQUIRE([AC_PROG_CC])dnl
26 AC_ARG_VAR([CPP], [C preprocessor])dnl
27 _AC_ARG_VAR_CPPFLAGS()dnl
28 # On Suns, sometimes $CPP names a directory.
29 if test -n "$CPP" && test -d "$CPP"; then
30 CPP=
31 fi
32 if test -z "$CPP"; then
33 CPP="$CC -E"
34 fi
35 AC_SUBST(CPP)dnl
36 ])# AC_PROG_CPP
38 # We require GCC. Override _AC_PROG_CC_C89 here to work around the Autoconf
39 # issue discussed in
40 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
41 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
43 dnl This is here so we can set $subdirs directly based on configure fragments.
44 AC_CONFIG_SUBDIRS()
46 AC_CANONICAL_HOST
48 AC_PROG_CC
49 if test $host != $build; then
50 AC_CHECK_PROGS(BUILD_CC, gcc cc)
51 fi
52 AC_SUBST(cross_compiling)
53 AC_PROG_CPP
54 AC_CHECK_TOOL(READELF, readelf, false)
56 # We need the C++ compiler only for testing.
57 AC_PROG_CXX
58 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
59 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
60 AC_LANG_PUSH([C++])
61 # Default, dynamic case.
62 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
63 [libc_cv_cxx_link_ok=yes],
64 [libc_cv_cxx_link_ok=no])
65 # Static case.
66 old_LDFLAGS="$LDFLAGS"
67 LDFLAGS="$LDFLAGS -static"
68 AC_LINK_IFELSE([AC_LANG_SOURCE([
69 #include <iostream>
71 int
72 main()
73 {
74 std::cout << "Hello, world!";
75 return 0;
76 }
77 ])],
78 [],
79 [libc_cv_cxx_link_ok=no])
80 LDFLAGS="$old_LDFLAGS"
81 AC_LANG_POP([C++])])
82 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
84 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
85 AC_MSG_ERROR([you must configure in a separate build directory])
86 fi
88 # This will get text that should go into config.make.
89 config_vars=
91 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
92 AC_ARG_WITH([gd],
93 AC_HELP_STRING([--with-gd=DIR],
94 [find libgd include dir and library with prefix DIR]),
95 [dnl
96 case "$with_gd" in
97 yes|''|no) ;;
98 *) libgd_include="-I$withval/include"
99 libgd_ldflags="-L$withval/lib" ;;
100 esac
101 ])
102 AC_ARG_WITH([gd-include],
103 AC_HELP_STRING([--with-gd-include=DIR],
104 [find libgd include files in DIR]),
105 [dnl
106 case "$with_gd_include" in
107 ''|no) ;;
108 *) libgd_include="-I$withval" ;;
109 esac
110 ])
111 AC_ARG_WITH([gd-lib],
112 AC_HELP_STRING([--with-gd-lib=DIR],
113 [find libgd library files in DIR]),
114 [dnl
115 case "$with_gd_lib" in
116 ''|no) ;;
117 *) libgd_ldflags="-L$withval" ;;
118 esac
119 ])
121 if test -n "$libgd_include"; then
122 config_vars="$config_vars
123 CFLAGS-memusagestat.c = $libgd_include"
124 fi
125 if test -n "$libgd_ldflags"; then
126 config_vars="$config_vars
127 libgd-LDFLAGS = $libgd_ldflags"
128 fi
130 dnl Arguments to specify presence of other packages/features.
131 AC_ARG_WITH([binutils],
132 AC_HELP_STRING([--with-binutils=PATH],
133 [specify location of binutils (as and ld)]),
134 [path_binutils=$withval],
135 [path_binutils=''])
136 AC_ARG_WITH([selinux],
137 AC_HELP_STRING([--with-selinux],
138 [if building with SELinux support]),
139 [with_selinux=$withval],
140 [with_selinux=auto])
142 AC_ARG_WITH([headers],
143 AC_HELP_STRING([--with-headers=PATH],
144 [location of system headers to use
145 (for example /usr/src/linux/include)
146 @<:@default=compiler default@:>@]),
147 [sysheaders=$withval],
148 [sysheaders=''])
149 AC_SUBST(sysheaders)
151 AC_SUBST(use_default_link)
152 AC_ARG_WITH([default-link],
153 AC_HELP_STRING([--with-default-link],
154 [do not use explicit linker scripts]),
155 [use_default_link=$withval],
156 [use_default_link=default])
158 dnl Additional build flags injection.
159 AC_ARG_WITH([nonshared-cflags],
160 AC_HELP_STRING([--with-nonshared-cflags=CFLAGS],
161 [build nonshared libraries with additional CFLAGS]),
162 [extra_nonshared_cflags=$withval],
163 [extra_nonshared_cflags=])
164 AC_SUBST(extra_nonshared_cflags)
166 AC_ARG_ENABLE([sanity-checks],
167 AC_HELP_STRING([--disable-sanity-checks],
168 [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
169 [enable_sanity=$enableval],
170 [enable_sanity=yes])
172 AC_ARG_ENABLE([shared],
173 AC_HELP_STRING([--enable-shared],
174 [build shared library @<:@default=yes if GNU ld@:>@]),
175 [shared=$enableval],
176 [shared=yes])
177 AC_ARG_ENABLE([profile],
178 AC_HELP_STRING([--enable-profile],
179 [build profiled library @<:@default=no@:>@]),
180 [profile=$enableval],
181 [profile=no])
182 AC_ARG_ENABLE([static-pie],
183 AC_HELP_STRING([--enable-static-pie],
184 [enable static PIE support and use it in the testsuite @<:@default=no@:>@]),
185 [static_pie=$enableval],
186 [static_pie=no])
187 AC_ARG_ENABLE([timezone-tools],
188 AC_HELP_STRING([--disable-timezone-tools],
189 [do not install timezone tools @<:@default=install@:>@]),
190 [enable_timezone_tools=$enableval],
191 [enable_timezone_tools=yes])
192 AC_SUBST(enable_timezone_tools)
194 AC_ARG_ENABLE([hardcoded-path-in-tests],
195 AC_HELP_STRING([--enable-hardcoded-path-in-tests],
196 [hardcode newly built glibc path in tests @<:@default=no@:>@]),
197 [hardcoded_path_in_tests=$enableval],
198 [hardcoded_path_in_tests=no])
199 AC_SUBST(hardcoded_path_in_tests)
201 AC_ARG_ENABLE([stackguard-randomization],
202 AC_HELP_STRING([--enable-stackguard-randomization],
203 [initialize __stack_chk_guard canary with a random number at program start]),
204 [enable_stackguard_randomize=$enableval],
205 [enable_stackguard_randomize=no])
206 if test "$enable_stackguard_randomize" = yes; then
207 AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
208 fi
210 AC_ARG_ENABLE([hidden-plt],
211 AC_HELP_STRING([--disable-hidden-plt],
212 [do not hide internal function calls to avoid PLT]),
213 [hidden=$enableval],
214 [hidden=yes])
215 if test "x$hidden" = xno; then
216 AC_DEFINE(NO_HIDDEN)
217 fi
219 AC_ARG_ENABLE([bind-now],
220 AC_HELP_STRING([--enable-bind-now],
221 [disable lazy relocations in DSOs]),
222 [bindnow=$enableval],
223 [bindnow=no])
224 AC_SUBST(bindnow)
225 if test "x$bindnow" = xyes; then
226 AC_DEFINE(BIND_NOW)
227 fi
229 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
230 dnl -fstack-protector-strong.
231 AC_ARG_ENABLE([stack-protector],
232 AC_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
233 [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
234 [enable_stack_protector=$enableval],
235 [enable_stack_protector=no])
236 case "$enable_stack_protector" in
237 all|yes|no|strong) ;;
238 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
239 esac
241 dnl On some platforms we cannot use dynamic loading. We must provide
242 dnl static NSS modules.
243 AC_ARG_ENABLE([static-nss],
244 AC_HELP_STRING([--enable-static-nss],
245 [build static NSS modules @<:@default=no@:>@]),
246 [static_nss=$enableval],
247 [static_nss=no])
248 dnl Enable static NSS also if we build no shared objects.
249 if test x"$static_nss" = xyes || test x"$shared" = xno; then
250 static_nss=yes
251 AC_DEFINE(DO_STATIC_NSS)
252 fi
254 AC_ARG_ENABLE([force-install],
255 AC_HELP_STRING([--disable-force-install],
256 [don't force installation of files from this package, even if they are older than the installed files]),
257 [force_install=$enableval],
258 [force_install=yes])
259 AC_SUBST(force_install)
261 AC_ARG_ENABLE([maintainer-mode],
262 AC_HELP_STRING([--enable-maintainer-mode],
263 [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
264 [maintainer=$enableval],
265 [maintainer=no])
267 dnl On some platforms we allow dropping compatibility with all kernel
268 dnl versions.
269 AC_ARG_ENABLE([kernel],
270 AC_HELP_STRING([--enable-kernel=VERSION],
271 [compile for compatibility with kernel not older than VERSION]),
272 [minimum_kernel=$enableval],
273 [])
274 dnl Prevent unreasonable values.
275 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
276 # Better nothing than this.
277 minimum_kernel=""
278 else
279 if test "$minimum_kernel" = current; then
280 minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
281 fi
282 fi
284 dnl For the development we sometimes want gcc to issue even more warnings.
285 dnl This is not the default since many of the extra warnings are not
286 dnl appropriate.
287 AC_ARG_ENABLE([all-warnings],
288 AC_HELP_STRING([--enable-all-warnings],
289 [enable all useful warnings gcc can issue]),
290 [all_warnings=$enableval],
291 [])
292 AC_SUBST(all_warnings)
294 AC_ARG_ENABLE([werror],
295 AC_HELP_STRING([--disable-werror],
296 [do not build with -Werror]),
297 [enable_werror=$enableval],
298 [enable_werror=yes])
299 AC_SUBST(enable_werror)
301 AC_ARG_ENABLE([multi-arch],
302 AC_HELP_STRING([--enable-multi-arch],
303 [enable single DSO with optimizations for multiple architectures]),
304 [multi_arch=$enableval],
305 [multi_arch=default])
307 AC_ARG_ENABLE([experimental-malloc],
308 AC_HELP_STRING([--disable-experimental-malloc],
309 [disable experimental malloc features]),
310 [experimental_malloc=$enableval],
311 [experimental_malloc=yes])
312 AC_SUBST(experimental_malloc)
314 AC_ARG_ENABLE([crypt],
315 AC_HELP_STRING([--disable-crypt],
316 [do not build nor install the passphrase hashing library, libcrypt]),
317 [build_crypt=$enableval],
318 [build_crypt=yes])
319 AC_SUBST(build_crypt)
321 AC_ARG_ENABLE([nss-crypt],
322 AC_HELP_STRING([--enable-nss-crypt],
323 [enable libcrypt to use nss]),
324 [nss_crypt=$enableval],
325 [nss_crypt=no])
326 if test x$build_libcrypt = xno && test x$nss_crypt = xyes; then
327 AC_MSG_WARN([--enable-nss-crypt has no effect when libcrypt is disabled])
328 nss_crypt=no
329 fi
330 if test x$nss_crypt = xyes; then
331 nss_includes=-I$(nss-config --includedir 2>/dev/null)
332 if test $? -ne 0; then
333 AC_MSG_ERROR([cannot find include directory with nss-config])
334 fi
335 nspr_includes=-I$(nspr-config --includedir 2>/dev/null)
336 if test $? -ne 0; then
337 AC_MSG_ERROR([cannot find include directory with nspr-config])
338 fi
339 old_CFLAGS="$CFLAGS"
340 CFLAGS="$CFLAGS $nss_includes $nspr_includes"
341 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
342 #include <hasht.h>
343 #include <nsslowhash.h>
344 void f (void) { NSSLOW_Init (); }])],
345 libc_cv_nss_crypt=yes,
346 AC_MSG_ERROR([
347 cannot find NSS headers with lowlevel hash function interfaces]))
348 old_LIBS="$LIBS"
349 old_LDFLAGS="$LDFLAGS"
350 LIBS="$LIBS -lfreebl3"
351 AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
352 #include <hasht.h>
353 #include <nsslowhash.h>],
354 [NSSLOW_Init();])],
355 libc_cv_nss_crypt=yes,
356 AC_MSG_ERROR([
357 cannot link program using lowlevel NSS hash functions]))
358 # Check to see if there is a static NSS cryptographic library.
359 # If there isn't then we can't link anything with libcrypt.a,
360 # and that might mean disabling some static tests.
361 LDFLAGS="$LDFLAGS -static"
362 AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
363 #include <hasht.h>
364 #include <nsslowhash.h>],
365 [NSSLOW_Init();])],
366 libc_cv_static_nss_crypt=yes,
367 libc_cv_static_nss_crypt=no)
368 LDFLAGS="$old_LDFLAGS"
369 CFLAGS="$old_CFLAGS"
370 LIBS="$old_LIBS"
371 else
372 libc_cv_nss_crypt=no
373 libc_cv_static_nss_crypt=no
374 fi
375 AC_SUBST(libc_cv_nss_crypt)
376 AC_SUBST(libc_cv_static_nss_crypt)
379 AC_ARG_ENABLE([obsolete-rpc],
380 AC_HELP_STRING([--enable-obsolete-rpc],
381 [build and install the obsolete RPC code for link-time usage]),
382 [link_obsolete_rpc=$enableval],
383 [link_obsolete_rpc=no])
384 AC_SUBST(link_obsolete_rpc)
386 if test "$link_obsolete_rpc" = yes; then
387 AC_DEFINE(LINK_OBSOLETE_RPC)
388 fi
390 AC_ARG_ENABLE([obsolete-nsl],
391 AC_HELP_STRING([--enable-obsolete-nsl],
392 [build and install the obsolete libnsl library and depending NSS modules]),
393 [build_obsolete_nsl=$enableval],
394 [build_obsolete_nsl=no])
395 AC_SUBST(build_obsolete_nsl)
397 if test "$build_obsolete_nsl" = yes; then
398 AC_DEFINE(LINK_OBSOLETE_NSL)
399 fi
401 AC_ARG_ENABLE([systemtap],
402 [AS_HELP_STRING([--enable-systemtap],
403 [enable systemtap static probe points @<:@default=no@:>@])],
404 [systemtap=$enableval],
405 [systemtap=no])
406 if test "x$systemtap" != xno; then
407 AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
408 old_CFLAGS="$CFLAGS"
409 CFLAGS="-std=gnu11 $CFLAGS"
410 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
411 void foo (int i, void *p)
412 {
413 asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
414 :: STAP_PROBE_ASM_OPERANDS (2, i, p));
415 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
416 CFLAGS="$old_CFLAGS"])
417 if test $libc_cv_sdt = yes; then
418 AC_DEFINE([USE_STAP_PROBE])
419 elif test "x$systemtap" != xauto; then
420 AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
421 fi
422 fi
424 AC_ARG_ENABLE([build-nscd],
425 [AS_HELP_STRING([--disable-build-nscd],
426 [disable building and installing the nscd daemon])],
427 [build_nscd=$enableval],
428 [build_nscd=default])
429 AC_SUBST(build_nscd)
431 # Note the use of $use_nscd is near the bottom of the file.
432 AC_ARG_ENABLE([nscd],
433 [AS_HELP_STRING([--disable-nscd],
434 [library functions will not contact the nscd daemon])],
435 [use_nscd=$enableval],
436 [use_nscd=yes])
438 AC_ARG_ENABLE([pt_chown],
439 [AS_HELP_STRING([--enable-pt_chown],
440 [Enable building and installing pt_chown])],
441 [build_pt_chown=$enableval],
442 [build_pt_chown=no])
443 AC_SUBST(build_pt_chown)
444 if test "$build_pt_chown" = yes; then
445 AC_DEFINE(HAVE_PT_CHOWN)
446 fi
448 AC_ARG_ENABLE([tunables],
449 [AS_HELP_STRING([--enable-tunables],
450 [Enable tunables support. Known values are 'yes', 'no' and 'valstring'])],
451 [have_tunables=$enableval],
452 [have_tunables=yes])
453 AC_SUBST(have_tunables)
454 if test "$have_tunables" = yes; then
455 AC_DEFINE(HAVE_TUNABLES)
456 fi
458 # The abi-tags file uses a fairly simplistic model for name recognition that
459 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu. So we mutate a
460 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
461 # This doesn't get used much beyond that, so it's fairly safe.
462 case "$host_os" in
463 linux*)
464 ;;
465 gnu*)
466 host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
467 ;;
468 esac
470 AC_ARG_ENABLE([mathvec],
471 [AS_HELP_STRING([--enable-mathvec],
472 [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
473 [build_mathvec=$enableval],
474 [build_mathvec=notset])
476 AC_ARG_ENABLE([cet],
477 AC_HELP_STRING([--enable-cet],
478 [enable Intel Control-flow Enforcement Technology (CET), x86 only]),
479 [enable_cet=$enableval],
480 [enable_cet=no])
482 # We keep the original values in `$config_*' and never modify them, so we
483 # can write them unchanged into config.make. Everything else uses
484 # $machine, $vendor, and $os, and changes them whenever convenient.
485 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
487 # Don't allow vendor == "unknown"
488 test "$config_vendor" = unknown && config_vendor=
489 config_os="`echo $config_os | sed 's/^unknown-//'`"
491 # Some configurations imply other options.
492 elf=yes
494 # The configure fragment of a port can modify these to supplement
495 # or override the table in the case statement below. No fragment should
496 # ever change the config_* variables, however.
497 machine=$config_machine
498 vendor=$config_vendor
499 os=$config_os
500 base_os=''
502 submachine=
503 AC_ARG_WITH([cpu],
504 AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
505 [dnl
506 case "$withval" in
507 yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
508 no) ;;
509 *) submachine="$withval" ;;
510 esac
511 ])
513 # An preconfigure script can set this when it wants to disable the sanity
514 # check below.
515 libc_config_ok=no
517 # A preconfigure script for a system that may or may not use fpu
518 # sysdeps directories sets this to a preprocessor conditional for
519 # whether to use such directories.
520 with_fp_cond=1
522 dnl Let sysdeps/*/preconfigure act here.
523 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
526 ###
527 ### By using the undocumented --enable-hacker-mode option for configure
528 ### one can skip this test to make the configuration not fail for unsupported
529 ### platforms.
530 ###
531 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
532 case "$machine-$host_os" in
533 *-linux* | *-gnu*)
534 ;;
535 *)
536 AC_MSG_ERROR([
537 *** The GNU C library is currently unavailable for this platform.
538 *** If you are interested in seeing glibc on this platform visit
539 *** the "How to submit a new port" in the wiki:
540 *** https://sourceware.org/glibc/wiki/#Development
541 *** and join the community!])
542 ;;
543 esac
544 fi
546 # Set base_machine if not set by a preconfigure fragment.
547 test -n "$base_machine" || base_machine=$machine
548 AC_SUBST(base_machine)
550 # Determine whether to use fpu or nofpu sysdeps directories.
551 AC_CACHE_CHECK([for use of fpu sysdeps directories],
552 libc_cv_with_fp, [dnl
553 cat > conftest.c <<EOF
554 #if $with_fp_cond
555 int dummy;
556 #else
557 # error "no hardware floating point"
558 #endif
559 EOF
560 libc_cv_with_fp=no
561 if ${CC-cc} $CFLAGS $CPPFLAGS -S conftest.c -o conftest.s \
562 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
563 libc_cv_with_fp=yes
564 fi
565 rm -f conftest*])
566 AC_SUBST(libc_cv_with_fp)
568 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
569 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
570 [libc_cv_ssp=yes],
571 [libc_cv_ssp=no])
572 ])
574 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
575 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
576 [libc_cv_ssp_strong=yes],
577 [libc_cv_ssp_strong=no])
578 ])
580 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
581 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
582 [libc_cv_ssp_all=yes],
583 [libc_cv_ssp_all=no])
584 ])
586 stack_protector=
587 no_stack_protector=
588 if test "$libc_cv_ssp" = yes; then
589 no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
590 AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
591 fi
593 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
594 stack_protector="-fstack-protector"
595 AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
596 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
597 stack_protector="-fstack-protector-all"
598 AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
599 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
600 stack_protector="-fstack-protector-strong"
601 AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
602 else
603 stack_protector="-fno-stack-protector"
604 AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
605 fi
606 AC_SUBST(libc_cv_ssp)
607 AC_SUBST(stack_protector)
608 AC_SUBST(no_stack_protector)
610 if test -n "$stack_protector"; then
611 dnl Don't run configure tests with stack-protection on, to avoid problems with
612 dnl bootstrapping.
613 no_ssp=-fno-stack-protector
614 else
615 no_ssp=
617 if test "$enable_stack_protector" != no; then
618 AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
619 fi
620 fi
622 # For the multi-arch option we need support in the assembler & linker.
623 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
624 libc_cv_ld_gnu_indirect_function, [dnl
625 cat > conftest.S <<EOF
626 .type foo,%gnu_indirect_function
627 foo:
628 .globl _start
629 _start:
630 .globl __start
631 __start:
632 .data
633 #ifdef _LP64
634 .quad foo
635 #else
636 .long foo
637 #endif
638 EOF
639 libc_cv_ld_gnu_indirect_function=no
640 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
641 -nostartfiles -nostdlib $no_ssp \
642 -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
643 # Do a link to see if the backend supports IFUNC relocs.
644 $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
645 LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
646 libc_cv_ld_gnu_indirect_function=yes
647 }
648 fi
649 rm -f conftest*])
651 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
652 AC_CACHE_CHECK([for gcc attribute ifunc support],
653 libc_cv_gcc_indirect_function, [dnl
654 cat > conftest.c <<EOF
655 extern int func (int);
656 int used_func (int a)
657 {
658 return a;
659 }
660 static void *resolver ()
661 {
662 return &used_func;
663 }
664 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
665 EOF
666 libc_cv_gcc_indirect_function=no
667 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
668 2>&AS_MESSAGE_LOG_FD ; then
669 if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
670 libc_cv_gcc_indirect_function=yes
671 fi
672 fi
673 rm -f conftest*])
675 # Check if linker supports textrel relocation with ifunc (used on elf/tests).
676 # Note that it relies on libc_cv_ld_gnu_indirect_function test above.
677 AC_CACHE_CHECK([whether the linker supports textrels along with ifunc],
678 libc_cv_textrel_ifunc, [dnl
679 cat > conftest.S <<EOF
680 .type foo,%gnu_indirect_function
681 foo:
682 .globl _start
683 _start:
684 .globl __start
685 __start:
686 .data
687 #ifdef _LP64
688 .quad foo
689 #else
690 .long foo
691 #endif
692 .text
693 .globl address
694 address:
695 #ifdef _LP64
696 .quad address
697 #else
698 .long address
699 #endif
700 EOF
701 libc_cv_textrel_ifunc=no
702 if test $libc_cv_ld_gnu_indirect_function = yes; then
703 if AC_TRY_COMMAND(${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -nostartfiles -nostdlib $no_ssp -pie -o conftest conftest.S); then
704 libc_cv_textrel_ifunc=yes
705 fi
706 fi
707 rm -f conftest*])
708 AC_SUBST(libc_cv_textrel_ifunc)
710 # Check if gcc warns about alias for function with incompatible types.
711 AC_CACHE_CHECK([if compiler warns about alias for function with incompatible types],
712 libc_cv_gcc_incompatible_alias, [dnl
713 cat > conftest.c <<EOF
714 int __redirect_foo (const void *s, int c);
716 __typeof (__redirect_foo) *foo_impl (void) __asm__ ("foo");
717 __typeof (__redirect_foo) *foo_impl (void)
718 {
719 return 0;
720 }
722 extern __typeof (__redirect_foo) foo_alias __attribute__ ((alias ("foo")));
723 EOF
724 libc_cv_gcc_incompatible_alias=yes
725 if ${CC-cc} -Werror -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
726 libc_cv_gcc_incompatible_alias=no
727 fi
728 rm -f conftest*])
730 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
731 if test x"$multi_arch" = xyes; then
732 AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
733 else
734 multi_arch=no
735 fi
736 fi
737 if test x"$libc_cv_gcc_indirect_function" != xyes; then
738 # GCC 8+ emits a warning for alias with incompatible types and it might
739 # fail to build ifunc resolvers aliases to either weak or internal
740 # symbols. Disables multiarch build in this case.
741 if test x"$libc_cv_gcc_incompatible_alias" == xyes; then
742 AC_MSG_WARN([gcc emits a warning for alias between functions of incompatible types])
743 if test x"$multi_arch" = xyes; then
744 AC_MSG_ERROR([--enable-multi-arch support requires a gcc with gnu-indirect-function support])
745 fi
746 AC_MSG_WARN([Multi-arch is disabled.])
747 multi_arch=no
748 elif test x"$multi_arch" = xyes; then
749 AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
750 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
751 fi
752 fi
753 multi_arch_d=
754 if test x"$multi_arch" != xno; then
755 multi_arch_d=/multiarch
756 fi
758 # Compute the list of sysdep directories for this configuration.
759 # This can take a while to compute.
760 sysdep_dir=$srcdir/sysdeps
761 AC_MSG_CHECKING(sysdep dirs)
762 dnl We need to use [ and ] for other purposes for a while now.
763 changequote(,)dnl
764 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
765 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
767 test "x$base_os" != x || case "$os" in
768 gnu*)
769 base_os=mach/hurd ;;
770 linux*)
771 base_os=unix/sysv ;;
772 esac
774 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
775 tail=$os
776 ostry=$os
777 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
778 ostry="$ostry /$o"
779 tail=$o
780 done
781 o=`echo $tail | sed 's/[0-9]*$//'`
782 if test $o != $tail; then
783 ostry="$ostry /$o"
784 fi
785 # For linux-gnu, try linux-gnu, then linux.
786 o=`echo $tail | sed 's/-.*$//'`
787 if test $o != $tail; then
788 ostry="$ostry /$o"
789 fi
791 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
792 base=
793 tail=$base_os
794 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
795 set $b
796 base="$base /$1"
797 tail="$2"
798 done
800 # For sparc/sparc32, try sparc/sparc32 and then sparc.
801 mach=
802 tail=$machine${submachine:+/$submachine}
803 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
804 set $m
805 # Prepend the machine's FPU directory unless --without-fp.
806 if test "$libc_cv_with_fp" = yes; then
807 maybe_fpu=/fpu
808 else
809 maybe_fpu=/nofpu
810 fi
811 # For each machine term, try it with and then without /multiarch.
812 for try_fpu in $maybe_fpu ''; do
813 for try_multi in $multi_arch_d ''; do
814 mach="$mach /$1$try_fpu$try_multi"
815 done
816 done
817 tail="$2"
818 done
820 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
821 changequote([,])dnl
823 # Find what sysdep directories exist.
824 sysnames=
825 for b in $base ''; do
826 for m0 in $mach ''; do
827 for v in /$vendor ''; do
828 test "$v" = / && continue
829 for o in /$ostry ''; do
830 test "$o" = / && continue
831 for m in $mach ''; do
832 try_suffix="$m0$b$v$o$m"
833 if test -n "$try_suffix"; then
834 try_srcdir="${srcdir}/"
835 try="sysdeps$try_suffix"
836 test -n "$enable_debug_configure" &&
837 echo "$0 [DEBUG]: try $try" >&2
838 if test -d "$try_srcdir$try"; then
839 sysnames="$sysnames $try"
840 { test -n "$o" || test -n "$b"; } && os_used=t
841 { test -n "$m" || test -n "$m0"; } && machine_used=t
842 case x${m0:-$m} in
843 x*/$submachine) submachine_used=t ;;
844 esac
845 fi
846 fi
847 done
848 done
849 done
850 done
851 done
853 # If the assembler supports gnu_indirect_function symbol type and the
854 # architecture supports multi-arch, we enable multi-arch by default.
855 case $sysnames in
856 *"$multi_arch_d"*)
857 ;;
858 *)
859 test x"$multi_arch" = xdefault && multi_arch=no
860 ;;
861 esac
862 if test x"$multi_arch" != xno; then
863 AC_DEFINE(USE_MULTIARCH)
864 fi
865 AC_SUBST(multi_arch)
867 if test -z "$os_used" && test "$os" != none; then
868 AC_MSG_ERROR(Operating system $os is not supported.)
869 fi
870 if test -z "$machine_used" && test "$machine" != none; then
871 AC_MSG_ERROR(The $machine is not supported.)
872 fi
873 if test -z "$submachine_used" && test -n "$submachine"; then
874 AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
875 fi
876 AC_SUBST(submachine)
878 # We have now validated the configuration.
880 # Expand the list of system names into a full list of directories
881 # from each element's parent name and Implies file (if present).
882 set $sysnames
883 names=
884 while test $# -gt 0; do
885 name=$1
886 shift
888 case " $names " in *" $name "*)
889 # Already in the list.
890 continue
891 esac
893 # Report each name as we discover it, so there is no long pause in output.
894 echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
896 name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
898 case $name in
899 /*) xsrcdir= ;;
900 *) xsrcdir=$srcdir/ ;;
901 esac
902 test -n "$enable_debug_configure" &&
903 echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
905 for implies_file in Implies Implies-before Implies-after; do
906 implies_type=`echo $implies_file | sed s/-/_/`
907 eval ${implies_type}=
908 if test -f $xsrcdir$name/$implies_file; then
909 # Collect more names from the `Implies' file (removing comments).
910 implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
911 for x in $implied_candidate; do
912 found=no
913 if test -d $xsrcdir$name_base/$x; then
914 eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
915 found=yes
916 fi
917 try="sysdeps/$x"
918 try_srcdir=$srcdir/
919 test -n "$enable_debug_configure" &&
920 echo "[DEBUG]: $name $implies_file $x try() {$try_srcdir}$try" >&2
921 if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
922 then
923 eval "${implies_type}=\"\$${implies_type} \$try\""
924 found=yes
925 fi
926 if test $found = no; then
927 AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
928 fi
929 done
930 fi
931 done
933 # Add NAME to the list of names.
934 names="$names $name"
936 # Find the parent of NAME, using the empty string if it has none.
937 changequote(,)dnl
938 parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
939 changequote([,])dnl
941 test -n "$enable_debug_configure" &&
942 echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
943 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
945 # Add the names implied by NAME, and NAME's parent (if it has one), to
946 # the list of names to be processed (the argument list). We prepend the
947 # implied names to the list and append the parent. We want implied
948 # directories to come before further directories inferred from the
949 # configuration components; this ensures that for sysv4, unix/common
950 # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
951 # after sysv4).
952 sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
953 test -n "$sysnames" && set $sysnames
954 done
956 # Add the default directories.
957 default_sysnames="sysdeps/generic"
958 sysnames="$names $default_sysnames"
959 AC_SUBST(sysnames)
960 # The other names were emitted during the scan.
961 AC_MSG_RESULT($default_sysnames)
964 ### Locate tools.
966 AC_PROG_INSTALL
967 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
968 # The makefiles need to use a different form to find it in $srcdir.
969 INSTALL='\$(..)./scripts/install-sh -c'
970 fi
971 AC_PROG_LN_S
973 LIBC_PROG_BINUTILS
975 # Accept binutils 2.25 or newer.
976 AC_CHECK_PROG_VER(AS, $AS, --version,
977 [GNU assembler.* \([0-9]*\.[0-9.]*\)],
978 [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
979 AS=: critic_missing="$critic_missing as")
981 if test -n "`$LD --version | sed -n 's/^GNU \(gold\).*$/\1/p'`"; then
982 # Accept gold 1.14 or higher
983 AC_CHECK_PROG_VER(LD, $LD, --version,
984 [GNU gold.* \([0-9][0-9]*\.[0-9.]*\)],
985 [1.1[4-9]*|1.[2-9][0-9]*|1.1[0-9][0-9]*|[2-9].*|[1-9][0-9]*],
986 LD=: critic_missing="$critic_missing GNU gold")
987 else
988 AC_CHECK_PROG_VER(LD, $LD, --version,
989 [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
990 [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
991 LD=: critic_missing="$critic_missing GNU ld")
992 fi
994 # These programs are version sensitive.
995 AC_CHECK_TOOL_PREFIX
996 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
997 [GNU Make[^0-9]*\([0-9][0-9.]*\)],
998 [[4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
1000 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
1001 [GNU gettext.* \([0-9]*\.[0-9.]*\)],
1002 [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
1003 MSGFMT=: aux_missing="$aux_missing msgfmt")
1004 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1005 [GNU texinfo.* \([0-9][0-9.]*\)],
1006 [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
1007 MAKEINFO=: aux_missing="$aux_missing makeinfo")
1008 AC_CHECK_PROG_VER(SED, sed, --version,
1009 [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
1010 [3.0[2-9]*|3.[1-9]*|[4-9]*],
1011 SED=: aux_missing="$aux_missing sed")
1012 AC_CHECK_PROG_VER(AWK, gawk, --version,
1013 [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
1014 [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
1015 AC_CHECK_PROG_VER(BISON, bison, --version,
1016 [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1017 [2.7*|[3-9].*|[1-9][0-9]*], critic_missing="$critic_missing bison")
1019 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
1020 AC_TRY_COMPILE([], [
1021 #if !defined __GNUC__ || __GNUC__ < 6 || (__GNUC__ == 6 && __GNUC_MINOR__ < 2)
1022 #error insufficient compiler
1023 #endif],
1024 [libc_cv_compiler_ok=yes],
1025 [libc_cv_compiler_ok=no])])
1026 AS_IF([test $libc_cv_compiler_ok != yes],
1027 [critic_missing="$critic_missing compiler"])
1029 AC_CHECK_TOOL(NM, nm, false)
1031 if test "x$maintainer" = "xyes"; then
1032 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1033 case "x$AUTOCONF" in
1034 xno|x|x:) AUTOCONF=no ;;
1035 *)
1036 AC_CACHE_CHECK(dnl
1037 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1038 if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
1039 libc_cv_autoconf_works=yes
1040 else
1041 libc_cv_autoconf_works=no
1042 fi])
1043 test $libc_cv_autoconf_works = yes || AUTOCONF=no
1044 ;;
1045 esac
1046 if test "x$AUTOCONF" = xno; then
1047 aux_missing="$aux_missing autoconf"
1048 fi
1049 else
1050 AUTOCONF=no
1051 fi
1053 # Check for python3 if available, or else python.
1054 AC_CHECK_PROG_VER(PYTHON_PROG, python3 python, --version,
1055 [Python \([0-9][0-9.]*\)],
1056 [3.[4-9]*|3.[1-9][0-9]*|[4-9].*|[1-9][0-9]*],
1057 critic_missing="$critic_missing python")
1058 PYTHON="$PYTHON_PROG -B"
1059 AC_SUBST(PYTHON)
1061 test -n "$critic_missing" && AC_MSG_ERROR([
1062 *** These critical programs are missing or too old:$critic_missing
1063 *** Check the INSTALL file for required versions.])
1065 test -n "$aux_missing" && AC_MSG_WARN([
1066 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1067 *** some features or tests will be disabled.
1068 *** Check the INSTALL file for required versions.])
1070 # if using special system headers, find out the compiler's sekrit
1071 # header directory and add that to the list. NOTE: Only does the right
1072 # thing on a system that doesn't need fixincludes. (Not presently a problem.)
1073 if test -n "$sysheaders"; then
1074 SYSINCLUDES=-nostdinc
1075 for d in include include-fixed; do
1076 i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1077 SYSINCLUDES="$SYSINCLUDES -isystem $i"
1078 done
1079 SYSINCLUDES="$SYSINCLUDES \
1080 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1081 if test -n "$CXX"; then
1082 CXX_SYSINCLUDES=
1083 for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1084 | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1085 test "x$cxxheaders" != x &&
1086 CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1087 done
1088 fi
1089 fi
1090 AC_SUBST(SYSINCLUDES)
1091 AC_SUBST(CXX_SYSINCLUDES)
1093 # Obtain some C++ header file paths. This is used to make a local
1094 # copy of those headers in Makerules.
1095 if test -n "$CXX"; then
1096 find_cxx_header () {
1097 echo "#include <$1>" | $CXX -M -MP -x c++ - 2>/dev/null \
1098 | sed -n "\,$1:,{s/:\$//;p}"
1099 }
1100 CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1101 CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1102 CXX_BITS_STD_ABS_H="$(find_cxx_header bits/std_abs.h)"
1103 fi
1104 AC_SUBST(CXX_CSTDLIB_HEADER)
1105 AC_SUBST(CXX_CMATH_HEADER)
1106 AC_SUBST(CXX_BITS_STD_ABS_H)
1108 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1109 # since this would lead to problems installing/building glibc.
1110 # LD_LIBRARY_PATH contains the current directory if one of the following
1111 # is true:
1112 # - one of the terminals (":" and ";") is the first or last sign
1113 # - two terminals occur directly after each other
1114 # - the path contains an element with a dot in it
1115 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1116 changequote(,)dnl
1117 case ${LD_LIBRARY_PATH} in
1118 [:\;]* | *[:\;] | *[:\;][:\;]* | *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1119 ld_library_path_setting="contains current directory"
1120 ;;
1121 *)
1122 ld_library_path_setting="ok"
1123 ;;
1124 esac
1125 changequote([,])dnl
1126 AC_MSG_RESULT($ld_library_path_setting)
1127 if test "$ld_library_path_setting" != "ok"; then
1128 AC_MSG_ERROR([
1129 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1130 *** building glibc. Please change the environment variable
1131 *** and run configure again.])
1132 fi
1134 AC_PATH_PROG(BASH_SHELL, bash, no)
1136 AC_PATH_PROG(PERL, perl, no)
1137 if test "$PERL" != no &&
1138 (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1139 PERL=no
1140 fi
1141 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1142 $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1144 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1145 cat > conftest.s <<EOF
1146 .text
1147 foo:
1148 .set glibc_conftest_frobozz,foo
1149 .globl glibc_conftest_frobozz
1150 EOF
1151 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1152 # (but it doesn't work), so we must do a linking check to be sure.
1153 cat > conftest1.c <<\EOF
1154 extern int glibc_conftest_frobozz;
1155 void _start() { glibc_conftest_frobozz = 1; }
1156 EOF
1157 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1158 -nostartfiles -nostdlib $no_ssp \
1159 -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1160 libc_cv_asm_set_directive=yes
1161 else
1162 libc_cv_asm_set_directive=no
1163 fi
1164 rm -f conftest*])
1165 if test $libc_cv_asm_set_directive = yes; then
1166 AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1167 fi
1169 AC_CACHE_CHECK(linker support for protected data symbol,
1170 libc_cv_protected_data,
1171 [cat > conftest.c <<EOF
1172 int bar __attribute__ ((visibility ("protected"))) = 1;
1173 EOF
1174 libc_cv_protected_data=no
1175 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1176 cat > conftest.c <<EOF
1177 extern int bar;
1178 int main (void) { return bar; }
1179 EOF
1180 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1181 libc_cv_protected_data=yes
1182 fi
1183 fi
1184 rm -f conftest.*
1185 ])
1186 AC_SUBST(libc_cv_protected_data)
1188 AC_CACHE_CHECK(linker support for INSERT in linker script,
1189 libc_cv_insert,
1190 [cat > conftest.c <<EOF
1191 const int __attribute__ ((section(".bar"))) bar = 0x12345678;
1192 int test (void) { return bar; }
1193 EOF
1194 cat > conftest.t <<EOF
1195 SECTIONS
1196 {
1197 .bar : { *(.bar) }
1198 }
1199 INSERT AFTER .rela.dyn;
1200 EOF
1201 libc_cv_insert=no
1202 if AC_TRY_COMMAND([${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -Wl,-T,conftest.t -o conftest.so]); then
1203 libc_cv_insert=yes
1204 fi
1205 rm -f conftest.*
1206 ])
1207 AC_SUBST(libc_cv_insert)
1209 AC_CACHE_CHECK(for broken __attribute__((alias())),
1210 libc_cv_broken_alias_attribute,
1211 [cat > conftest.c <<EOF
1212 extern int foo (int x) __asm ("xyzzy");
1213 int bar (int x) { return x; }
1214 extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1215 extern int dfoo;
1216 extern __typeof (dfoo) dfoo __asm ("abccb");
1217 int dfoo = 1;
1218 EOF
1219 libc_cv_broken_alias_attribute=yes
1220 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1221 if grep 'xyzzy' conftest.s >/dev/null &&
1222 grep 'abccb' conftest.s >/dev/null; then
1223 libc_cv_broken_alias_attribute=no
1224 fi
1225 fi
1226 rm -f conftest.c conftest.s
1227 ])
1228 if test $libc_cv_broken_alias_attribute = yes; then
1229 AC_MSG_ERROR(working alias attribute support required)
1230 fi
1232 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1233 libc_cv_have_sdata_section,
1234 [echo "int i;" > conftest.c
1235 libc_cv_have_sdata_section=no
1236 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1237 | grep '\.sdata' >/dev/null; then
1238 libc_cv_have_sdata_section=yes
1239 fi
1240 rm -f conftest.c conftest.so
1241 ])
1242 if test $libc_cv_have_sdata_section = yes; then
1243 AC_DEFINE(HAVE_SDATA_SECTION)
1244 fi
1246 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1247 libc_cv_ctors_header, [dnl
1248 libc_cv_ctors_header=yes
1249 LIBC_TRY_LINK_STATIC([
1250 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1251 __attribute__ ((destructor)) void dtor (void) { asm (""); }
1252 ],
1253 [dnl
1254 AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1255 { gsub(/\@<:@ */, "@<:@") }
1256 $2 == ".ctors" || $2 == ".dtors" {
1257 size = strtonum("0x" $6)
1258 align = strtonum("0x" $NF)
1259 seen@<:@$2@:>@ = 1
1260 stub@<:@$2@:>@ = size == align * 2
1261 }
1262 END {
1263 ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1264 dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1265 exit ((ctors_ok && dtors_ok) ? 0 : 1)
1266 }
1267 '], [libc_cv_ctors_header=no])
1268 ], [dnl
1269 AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1270 ])
1271 ])
1272 if test $libc_cv_ctors_header = no; then
1273 AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1274 fi
1276 AC_CACHE_CHECK(for libunwind-support in compiler,
1277 libc_cv_cc_with_libunwind, [
1278 cat > conftest.c <<EOF
1279 int main (void) { return 0; }
1280 EOF
1281 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1282 conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1283 libc_cv_cc_with_libunwind=yes
1284 else
1285 libc_cv_cc_with_libunwind=no
1286 fi
1287 rm -f conftest*])
1288 AC_SUBST(libc_cv_cc_with_libunwind)
1289 if test $libc_cv_cc_with_libunwind = yes; then
1290 AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1291 fi
1293 ASFLAGS_config=
1294 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1295 libc_cv_as_noexecstack, [dnl
1296 cat > conftest.c <<EOF
1297 void foo (void) { }
1298 EOF
1299 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1300 -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1301 && grep .note.GNU-stack conftest.s >/dev/null \
1302 && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1303 -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1304 then
1305 libc_cv_as_noexecstack=yes
1306 else
1307 libc_cv_as_noexecstack=no
1308 fi
1309 rm -f conftest*])
1310 if test $libc_cv_as_noexecstack = yes; then
1311 ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1312 fi
1313 AC_SUBST(ASFLAGS_config)
1315 AC_CACHE_CHECK(for -z combreloc,
1316 libc_cv_z_combreloc, [dnl
1317 cat > conftest.c <<EOF
1318 extern int bar (int);
1319 extern int mumble;
1320 int foo (void) { return bar (mumble); }
1321 EOF
1322 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1323 -fPIC -shared $no_ssp -o conftest.so conftest.c
1324 -nostdlib -nostartfiles
1325 -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1326 then
1327 dnl The following test is a bit weak. We must use a tool which can test
1328 dnl cross-platform since the gcc used can be a cross compiler. Without
1329 dnl introducing new options this is not easily doable. Instead use a tool
1330 dnl which always is cross-platform: readelf. To detect whether -z combreloc
1331 dnl look for a section named .rel.dyn or .rela.dyn.
1332 if $READELF -S conftest.so | grep -E '.rela?.dyn' > /dev/null; then
1333 libc_cv_z_combreloc=yes
1334 else
1335 libc_cv_z_combreloc=no
1336 fi
1337 else
1338 libc_cv_z_combreloc=no
1339 fi
1340 rm -f conftest*])
1341 if test "$libc_cv_z_combreloc" = yes; then
1342 AC_DEFINE(HAVE_Z_COMBRELOC)
1343 fi
1344 AC_SUBST(libc_cv_z_combreloc)
1346 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1347 [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1348 AC_SUBST(libc_cv_z_execstack)
1350 LIBC_LINKER_FEATURE([--no-dynamic-linker],
1351 [-Wl,--no-dynamic-linker],
1352 [libc_cv_no_dynamic_linker=yes],
1353 [libc_cv_no_dynamic_linker=no])
1354 LIBC_CONFIG_VAR([have-no-dynamic-linker], [$libc_cv_no_dynamic_linker])
1356 AC_CACHE_CHECK(for -static-pie, libc_cv_static_pie, [dnl
1357 LIBC_TRY_CC_OPTION([-static-pie],
1358 [libc_cv_static_pie=yes],
1359 [libc_cv_static_pie=no])
1360 ])
1361 LIBC_CONFIG_VAR([have-static-pie], [$libc_cv_static_pie])
1363 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1364 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1365 ])
1367 AC_SUBST(libc_cv_fpie)
1369 AC_CACHE_CHECK(for --hash-style option,
1370 libc_cv_hashstyle, [dnl
1371 cat > conftest.c <<EOF
1372 int _start (void) { return 42; }
1373 EOF
1374 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1375 -fPIC -shared -o conftest.so conftest.c
1376 -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1377 then
1378 libc_cv_hashstyle=yes
1379 else
1380 libc_cv_hashstyle=no
1381 fi
1382 rm -f conftest*])
1383 AC_SUBST(libc_cv_hashstyle)
1385 # The linker's default -shared behavior is good enough if it
1386 # does these things that our custom linker scripts ensure that
1387 # all allocated NOTE sections come first.
1388 if test "$use_default_link" = default; then
1389 AC_CACHE_CHECK([for sufficient default -shared layout],
1390 libc_cv_use_default_link, [dnl
1391 libc_cv_use_default_link=no
1392 cat > conftest.s <<\EOF
1393 .section .note.a,"a",%note
1394 .balign 4
1395 .long 4,4,9
1396 .string "GNU"
1397 .string "foo"
1398 .section .note.b,"a",%note
1399 .balign 4
1400 .long 4,4,9
1401 .string "GNU"
1402 .string "bar"
1403 EOF
1404 if AC_TRY_COMMAND([dnl
1405 ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1406 ac_try=`$READELF -S conftest.so | sed -n \
1407 ['${x;p;}
1408 s/^ *\[ *[1-9][0-9]*\] *\([^ ][^ ]*\) *\([^ ][^ ]*\) .*$/\2 \1/
1409 t a
1410 b
1411 : a
1412 H']`
1413 then
1414 libc_seen_a=no libc_seen_b=no
1415 set -- $ac_try
1416 while test $# -ge 2 -a "$1" = NOTE; do
1417 case "$2" in
1418 .note.a) libc_seen_a=yes ;;
1419 .note.b) libc_seen_b=yes ;;
1420 esac
1421 shift 2
1422 done
1423 case "$libc_seen_a$libc_seen_b" in
1424 yesyes)
1425 libc_cv_use_default_link=yes
1426 ;;
1427 *)
1428 echo >&AS_MESSAGE_LOG_FD "\
1429 $libc_seen_a$libc_seen_b from:
1430 $ac_try"
1431 ;;
1432 esac
1433 fi
1434 rm -f conftest*])
1435 use_default_link=$libc_cv_use_default_link
1436 fi
1438 AC_CACHE_CHECK(for GLOB_DAT reloc,
1439 libc_cv_has_glob_dat, [dnl
1440 cat > conftest.c <<EOF
1441 extern int mumble;
1442 int foo (void) { return mumble; }
1443 EOF
1444 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1445 -fPIC -shared -o conftest.so conftest.c
1446 -nostdlib -nostartfiles $no_ssp
1447 1>&AS_MESSAGE_LOG_FD])
1448 then
1449 dnl look for GLOB_DAT relocation.
1450 if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1451 libc_cv_has_glob_dat=yes
1452 else
1453 libc_cv_has_glob_dat=no
1454 fi
1455 else
1456 libc_cv_has_glob_dat=no
1457 fi
1458 rm -f conftest*])
1459 AC_SUBST(libc_cv_has_glob_dat)
1461 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1462 if libc_cv_output_format=`
1463 ${CC-cc} -nostartfiles -nostdlib $no_ssp -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1464 then
1465 :
1466 else
1467 libc_cv_output_format=
1468 fi
1469 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1470 AC_SUBST(libc_cv_output_format)
1472 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1473 cat > conftest.c <<EOF
1474 int foo;
1475 EOF
1476 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1477 conftest.c 1>&AS_MESSAGE_LOG_FD])
1478 then
1479 libc_cv_fno_toplevel_reorder=yes
1480 else
1481 libc_cv_fno_toplevel_reorder=no
1482 fi
1483 rm -f conftest*])
1484 if test $libc_cv_fno_toplevel_reorder = yes; then
1485 fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1486 else
1487 fno_unit_at_a_time=-fno-unit-at-a-time
1488 fi
1489 AC_SUBST(fno_unit_at_a_time)
1491 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1492 [dnl
1493 cat > conftest.c <<EOF
1494 __thread int i;
1495 void foo (void)
1496 {
1497 i = 10;
1498 }
1499 EOF
1500 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1501 conftest.c 1>&AS_MESSAGE_LOG_FD])
1502 then
1503 libc_cv_mtls_dialect_gnu2=yes
1504 else
1505 libc_cv_mtls_dialect_gnu2=no
1506 fi
1507 rm -f conftest*])
1508 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1509 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1511 AC_CACHE_CHECK(whether cc puts quotes around section names,
1512 libc_cv_have_section_quotes,
1513 [cat > conftest.c <<EOF
1514 static const int foo
1515 __attribute__ ((section ("bar"))) = 1;
1516 EOF
1517 if ${CC-cc} -S conftest.c -o conftest.s; then
1518 if grep '\.section.*"bar"' conftest.s >/dev/null; then
1519 libc_cv_have_section_quotes=yes
1520 else
1521 libc_cv_have_section_quotes=no
1522 fi
1523 else
1524 libc_cv_have_section_quotes=unknown
1525 fi
1526 rm -f conftest.{c,s}
1527 ])
1528 if test $libc_cv_have_section_quotes = yes; then
1529 AC_DEFINE(HAVE_SECTION_QUOTES)
1530 fi
1532 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1533 cat > conftest.c <<\EOF
1534 void zero (void *x)
1535 {
1536 __builtin_memset (x, 0, 1000);
1537 }
1538 EOF
1539 dnl
1540 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "memset" > /dev/null]);
1541 then
1542 libc_cv_gcc_builtin_memset=no
1543 else
1544 libc_cv_gcc_builtin_memset=yes
1545 fi
1546 rm -f conftest* ])
1547 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1548 AC_DEFINE(HAVE_BUILTIN_MEMSET)
1549 fi
1551 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1552 cat > conftest.c <<\EOF
1553 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1554 char *foo (const char *a, const char *b)
1555 {
1556 return __builtin_strstr (a, b);
1557 }
1558 EOF
1559 dnl
1560 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "my_strstr" > /dev/null]);
1561 then
1562 libc_cv_gcc_builtin_redirection=yes
1563 else
1564 libc_cv_gcc_builtin_redirection=no
1565 fi
1566 rm -f conftest* ])
1567 if test "$libc_cv_gcc_builtin_redirection" = no; then
1568 AC_MSG_ERROR([support for the symbol redirection needed])
1569 fi
1571 dnl Determine how to disable generation of FMA instructions.
1572 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1573 libc_cv_cc_nofma, [dnl
1574 libc_cv_cc_nofma=
1575 for opt in -ffp-contract=off -mno-fused-madd; do
1576 LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1577 done])
1578 AC_SUBST(libc_cv_cc_nofma)
1580 if test -n "$submachine"; then
1581 AC_CACHE_CHECK([for compiler option for CPU variant],
1582 libc_cv_cc_submachine, [dnl
1583 libc_cv_cc_submachine=no
1584 for opt in "-march=$submachine" "-mcpu=$submachine"; do
1585 LIBC_TRY_CC_OPTION([$opt], [
1586 libc_cv_cc_submachine="$opt"
1587 break], [])
1588 done])
1589 if test "x$libc_cv_cc_submachine" = xno; then
1590 AC_MSG_ERROR([${CC-cc} does not support $submachine])
1591 fi
1592 fi
1593 AC_SUBST(libc_cv_cc_submachine)
1595 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1596 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1597 cat > conftest.c <<EOF
1598 void
1599 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1600 foo (void) {}
1601 EOF
1602 libc_cv_cc_loop_to_function=no
1603 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1604 then
1605 libc_cv_cc_loop_to_function=yes
1606 fi
1607 rm -f conftest*])
1608 if test $libc_cv_cc_loop_to_function = yes; then
1609 AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1610 fi
1611 AC_SUBST(libc_cv_cc_loop_to_function)
1613 dnl Check whether we have the gd library available.
1614 AC_MSG_CHECKING(for libgd)
1615 if test "$with_gd" != "no"; then
1616 old_CFLAGS="$CFLAGS"
1617 CFLAGS="$CFLAGS $libgd_include"
1618 old_LDFLAGS="$LDFLAGS"
1619 LDFLAGS="$LDFLAGS $libgd_ldflags"
1620 old_LIBS="$LIBS"
1621 LIBS="$LIBS -lgd -lpng -lz -lm"
1622 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1623 CFLAGS="$old_CFLAGS"
1624 LDFLAGS="$old_LDFLAGS"
1625 LIBS="$old_LIBS"
1626 else
1627 LIBGD=no
1628 fi
1629 AC_MSG_RESULT($LIBGD)
1630 AC_SUBST(LIBGD)
1632 # SELinux detection
1633 if test x$with_selinux = xno ; then
1634 have_selinux=no;
1635 else
1636 # See if we have the SELinux library
1637 AC_CHECK_LIB(selinux, is_selinux_enabled,
1638 have_selinux=yes, have_selinux=no)
1639 if test x$with_selinux = xyes ; then
1640 if test x$have_selinux = xno ; then
1641 AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1642 fi
1643 fi
1644 fi
1645 # Check if we're building with SELinux support.
1646 if test "x$have_selinux" = xyes; then
1647 AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1649 # See if we have the libaudit library
1650 AC_CHECK_LIB(audit, audit_log_user_avc_message,
1651 have_libaudit=yes, have_libaudit=no)
1652 if test "x$have_libaudit" = xyes; then
1653 AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1654 fi
1655 AC_SUBST(have_libaudit)
1657 # See if we have the libcap library
1658 AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1659 if test "x$have_libcap" = xyes; then
1660 AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1661 fi
1662 AC_SUBST(have_libcap)
1663 fi
1664 AC_SUBST(have_selinux)
1666 CPPUNDEFS=
1667 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1668 dnl Since we are building the implementations of the fortified functions here,
1669 dnl having the macro defined interacts very badly.
1670 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1671 [AC_TRY_COMPILE([], [
1672 #ifdef _FORTIFY_SOURCE
1673 # error bogon
1674 #endif],
1675 [libc_cv_predef_fortify_source=no],
1676 [libc_cv_predef_fortify_source=yes])])
1677 if test $libc_cv_predef_fortify_source = yes; then
1678 CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1679 fi
1680 AC_SUBST(CPPUNDEFS)
1682 # Some linkers on some architectures support __ehdr_start but with
1683 # bugs. Make sure usage of it does not create relocations in the
1684 # output (as the linker should resolve them all for us).
1685 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1686 libc_cv_ehdr_start, [
1687 old_CFLAGS="$CFLAGS"
1688 old_LDFLAGS="$LDFLAGS"
1689 old_LIBS="$LIBS"
1690 CFLAGS="$CFLAGS -fPIC"
1691 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared $no_ssp"
1692 LIBS=
1693 AC_LINK_IFELSE([AC_LANG_SOURCE([
1694 typedef struct {
1695 char foo;
1696 long val;
1697 } Ehdr;
1698 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1699 long ehdr (void) { return __ehdr_start.val; }
1700 ])],
1701 [if $READELF -r conftest | grep -F __ehdr_start >/dev/null; then
1702 libc_cv_ehdr_start=broken
1703 else
1704 libc_cv_ehdr_start=yes
1705 fi], [libc_cv_ehdr_start=no])
1706 CFLAGS="$old_CFLAGS"
1707 LDFLAGS="$old_LDFLAGS"
1708 LIBS="$old_LIBS"
1709 ])
1710 if test "$libc_cv_ehdr_start" = yes; then
1711 AC_DEFINE([HAVE_EHDR_START])
1712 elif test "$libc_cv_ehdr_start" = broken; then
1713 AC_MSG_WARN([linker is broken -- you should upgrade])
1714 fi
1716 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1717 libc_cv_builtin_trap, [dnl
1718 libc_cv_builtin_trap=no
1719 AC_TRY_COMPILE([], [__builtin_trap ()], [
1720 libc_undefs=`$NM -u conftest.o |
1721 LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1722 2>&AS_MESSAGE_LOG_FD` || {
1723 AC_MSG_ERROR([confusing output from $NM -u])
1724 }
1725 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1726 if test -z "$libc_undefs"; then
1727 libc_cv_builtin_trap=yes
1728 fi])])
1729 if test $libc_cv_builtin_trap = yes; then
1730 AC_DEFINE([HAVE_BUILTIN_TRAP])
1731 fi
1733 dnl C++ feature tests.
1734 AC_LANG_PUSH([C++])
1736 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1737 libc_cv_cxx_thread_local, [
1738 old_CXXFLAGS="$CXXFLAGS"
1739 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1740 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1741 #include <thread>
1743 // Compiler support.
1744 struct S
1745 {
1746 S ();
1747 ~S ();
1748 };
1749 thread_local S s;
1750 S * get () { return &s; }
1752 // libstdc++ support.
1753 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1754 #error __cxa_thread_atexit_impl not supported
1755 #endif
1756 ])],
1757 [libc_cv_cxx_thread_local=yes],
1758 [libc_cv_cxx_thread_local=no])
1759 CXXFLAGS="$old_CXXFLAGS"
1760 ])
1761 AC_SUBST(libc_cv_cxx_thread_local)
1763 AC_LANG_POP([C++])
1764 dnl End of C++ feature tests.
1766 ### End of automated tests.
1767 ### Now run sysdeps configure fragments.
1769 # They also can set these variables.
1770 use_ldconfig=no
1771 ldd_rewrite_script=no
1772 libc_cv_sysconfdir=$sysconfdir
1773 libc_cv_localstatedir=$localstatedir
1774 libc_cv_gcc_unwind_find_fde=no
1775 libc_cv_idn=no
1777 # Iterate over all the sysdep directories we will use, running their
1778 # configure fragments.
1779 for dir in $sysnames; do
1780 case $dir in
1781 /*) dest=$dir ;;
1782 *) dest=$srcdir/$dir ;;
1783 esac
1784 if test -r $dest/configure; then
1785 AC_MSG_RESULT(running configure fragment for $dir)
1786 . $dest/configure
1787 fi
1788 done
1790 if test x"$build_mathvec" = xnotset; then
1791 build_mathvec=no
1792 fi
1793 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1795 AC_SUBST(libc_extra_cflags)
1796 AC_SUBST(libc_extra_cppflags)
1798 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1799 AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1800 fi
1801 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1803 # A sysdeps configure fragment can reset this if IFUNC is not actually
1804 # usable even though the assembler knows how to generate the symbol type.
1805 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1806 AC_DEFINE(HAVE_IFUNC)
1807 fi
1808 LIBC_CONFIG_VAR([have-ifunc], [$libc_cv_ld_gnu_indirect_function])
1810 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1811 AC_DEFINE(HAVE_GCC_IFUNC)
1812 fi
1814 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1815 # configure fragment can override the value to prevent this AC_DEFINE.
1816 AC_SUBST(use_nscd)
1817 if test "x$use_nscd" != xno; then
1818 AC_DEFINE([USE_NSCD])
1819 fi
1820 if test "x$build_nscd" = xdefault; then
1821 build_nscd=$use_nscd
1822 fi
1824 AC_SUBST(libc_cv_slibdir)
1825 AC_SUBST(libc_cv_rtlddir)
1826 AC_SUBST(libc_cv_complocaledir)
1827 AC_SUBST(libc_cv_sysconfdir)
1828 AC_SUBST(libc_cv_localstatedir)
1829 AC_SUBST(libc_cv_rootsbindir)
1831 if test x$use_ldconfig = xyes; then
1832 AC_DEFINE(USE_LDCONFIG)
1833 fi
1834 AC_SUBST(use_ldconfig)
1835 AC_SUBST(ldd_rewrite_script)
1837 AC_SUBST(static)
1838 AC_SUBST(shared)
1840 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1841 [libc_cv_pic_default=yes
1842 cat > conftest.c <<EOF
1843 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1844 # error PIC is default.
1845 #endif
1846 EOF
1847 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1848 libc_cv_pic_default=no
1849 fi
1850 rm -f conftest.*])
1851 AC_SUBST(libc_cv_pic_default)
1853 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_cc_pie_default,
1854 [libc_cv_cc_pie_default=yes
1855 cat > conftest.c <<EOF
1856 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1857 # error PIE is default.
1858 #endif
1859 EOF
1860 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1861 libc_cv_cc_pie_default=no
1862 fi
1863 rm -f conftest.*])
1864 libc_cv_pie_default=$libc_cv_cc_pie_default
1865 AC_SUBST(libc_cv_cc_pie_default)
1866 AC_SUBST(libc_cv_pie_default)
1868 # Set the `multidir' variable by grabbing the variable from the compiler.
1869 # We do it once and save the result in a generated makefile.
1870 libc_cv_multidir=`${CC-cc} $CFLAGS $CPPFLAGS -print-multi-directory`
1871 AC_SUBST(libc_cv_multidir)
1873 if test "$static_pie" = yes; then
1874 # The linker must support --no-dynamic-linker.
1875 if test "$libc_cv_no_dynamic_linker" != yes; then
1876 AC_MSG_ERROR([linker support for --no-dynamic-linker needed])
1877 fi
1878 # Default to PIE.
1879 libc_cv_pie_default=yes
1880 AC_DEFINE(ENABLE_STATIC_PIE)
1881 fi
1882 LIBC_CONFIG_VAR([enable-static-pie], [$static_pie])
1884 AC_SUBST(profile)
1885 AC_SUBST(static_nss)
1887 AC_SUBST(DEFINES)
1889 dnl See sysdeps/mach/configure.ac for this variable.
1890 AC_SUBST(mach_interface_list)
1892 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1893 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1894 AC_SUBST(VERSION)
1895 AC_SUBST(RELEASE)
1897 AC_CONFIG_FILES([config.make Makefile])
1898 AC_CONFIG_COMMANDS([default],[[
1899 case $CONFIG_FILES in *config.make*)
1900 echo "$config_vars" >> config.make;;
1901 esac
1902 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1903 AC_OUTPUT