sysdeps/libm-i387/s_asinhf.S

   1 /* ix87 specific implementation of arcsinh.
   2    Copyright (C) 1996, 1997 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Library General Public License as
   8    published by the Free Software Foundation; either version 2 of the
   9    License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Library General Public License for more details.
  15
  16    You should have received a copy of the GNU Library General Public
  17    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  18    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  19    Boston, MA 02111-1307, USA.  */
  20
  21 #include <machine/asm.h>
  22
  23 #ifdef __ELF__
  24         .section .rodata
  25 #else
  26         .text
  27 #endif
  28
  29         .align ALIGNARG(4)
  30         ASM_TYPE_DIRECTIVE(huge,@object)
  31 huge:   .double 1e+36
  32         ASM_SIZE_DIRECTIVE(huge)
  33         ASM_TYPE_DIRECTIVE(one,@object)
  34 one:    .double 1.0
  35         ASM_SIZE_DIRECTIVE(one)
  36         ASM_TYPE_DIRECTIVE(limit,@object)
  37 limit:  .double 0.29
  38         ASM_SIZE_DIRECTIVE(limit)
  39
  40 #ifdef PIC
  41 #define MO(op) op##@GOTOFF(%edx)
  42 #else
  43 #define MO(op) op
  44 #endif
  45
  46         .text
  47 ENTRY(__asinhf)
  48         movl    4(%esp), %ecx
  49         movl    $0x7fffffff, %eax
  50         andl    %ecx, %eax
  51         andl    $0x80000000, %ecx
  52         xorl    %ecx, 8(%esp)
  53         flds    4(%esp)                 // |x|
  54         movl    %eax, %edx
  55         cmpl    $0x38000000, %eax
  56         jb      2f                      // |x| < 2^-14
  57         orl     $0x807fffff, %edx
  58         incl    %edx
  59         jz      4f                      // x in ±Inf or NaN
  60         fldln2                          // log(2) : |x|
  61         cmpl    $0x47000000, %eax
  62         fxch                            // |x| : log(2)
  63         ja      3f                      // |x| > 2^14
  64 #ifdef  PIC
  65         call    1f
  66 1:      popl    %edx
  67         addl    $_GLOBAL_OFFSET_TABLE_+[.-1b], %edx
  68 #endif
  69         cmpl    $0x40000000, %eax
  70         ja      5f                      // |x| > 2
  71
  72         // 2^-14 <= |x| <= 2 => y = sign(x)*log1p(|x|+|x|^2/(1+sqrt(1+|x|^2)))
  73         fld     %st                     // |x| : |x| : log(2)
  74         fmul    %st(1)                  // |x|^2 : |x| : log(2)
  75         fld     %st                     // |x|^2 : |x|^2 : |x| : log(2)
  76         faddl   MO(one)                 // 1+|x|^2 : |x|^2 : |x| : log(2)
  77         fsqrt                           // sqrt(1+|x|^2) : |x|^2 : |x| : log(2)
  78         faddl   MO(one)                 // 1+sqrt(1+|x|^2) : |x|^2 : |x| : log(2)
  79         fdivrp                          // |x|^2/(1+sqrt(1+|x|^2)) : |x| : log(2)
  80         faddp                           // |x|+|x|^2/(1+sqrt(1+|x|^2)) : log(2)
  81         fcoml   MO(limit)
  82         fnstsw
  83         sahf
  84         ja      6f
  85         fyl2xp1
  86         jecxz   4f
  87         fchs
  88 4:      ret
  89
  90 6:      faddl   MO(one)
  91         fyl2x
  92         jecxz   4f
  93         fchs
  94 4:      ret
  95
  96         // |x| < 2^-14 => y = x (inexact iff |x| != 0.0)
  97         .align ALIGNARG(4)
  98 2:
  99 #ifdef  PIC
 100         call    1f
 101 1:      popl    %edx
 102         addl    $_GLOBAL_OFFSET_TABLE_+[.-1b], %edx
 103 #endif
 104         jecxz   4f
 105         fchs                            // x
 106 4:      fld     %st                     // x : x
 107         faddl   MO(huge)                // huge+x : x
 108         fstp    %st(0)                  // x
 109         ret
 110
 111         // |x| > 2^14 => y = sign(x) * (log(|x|) + log(2))
 112         .align ALIGNARG(4)
 113 3:      fyl2x                           // log(|x|)
 114         fldln2                          // log(2) : log(|x|)
 115         faddp                           // log(|x|)+log(2)
 116         jecxz   4f
 117         fchs
 118 4:      ret
 119
 120         // |x| > 2 => y = sign(x) * log(2*|x| + 1/(|x|+sqrt(x*x+1)))
 121         .align ALIGNARG(4)
 122 5:      fld     %st                     // |x| : |x| : log(2)
 123         fadd    %st, %st(1)             // |x| : 2*|x| : log(2)
 124         fld     %st                     // |x| : |x| : 2*|x| : log(2)
 125         fmul    %st(1)                  // |x|^2 : |x| : 2*|x| : log(2)
 126         faddl   MO(one)                 // 1+|x|^2 : |x| : 2*|x| : log(2)
 127         fsqrt                           // sqrt(1+|x|^2) : |x| : 2*|x| : log(2)
 128         faddp                           // |x|+sqrt(1+|x|^2) : 2*|x| : log(2)
 129         fdivrl  MO(one)                 // 1/(|x|+sqrt(1+|x|^2)) : 2*|x| : log(2)
 130         faddp                           // 2*|x|+1/(|x|+sqrt(1+|x|^2)) : log(2)
 131         fyl2x                           // log(2*|x|+1/(|x|+sqrt(1+|x|^2)))
 132         jecxz   4f
 133         fchs
 134 4:      ret
 135 END(__asinhf)
 136 weak_alias (__asinhf, asinhf)