sysdeps/i386/elf/setjmp.S

   1 /* setjmp for i386, ELF version.
   2    Copyright (C) 1995, 1996, 1997 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Library General Public License as
   7    published by the Free Software Foundation; either version 2 of the
   8    License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Library General Public License for more details.
  14
  15    You should have received a copy of the GNU Library General Public
  16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  18    Boston, MA 02111-1307, USA.  */
  19
  20 #include <sysdep.h>
  21 #define _ASM
  22 #include <bits/setjmp.h>
  23
  24         /* We include the BSD entry points here as well but we make
  25            them weak.  */
  26 ENTRY (setjmp)
  27         .weak C_SYMBOL_NAME (setjmp)
  28         popl %eax               /* Pop return PC.  */
  29         popl %ecx               /* Pop jmp_buf argument.  */
  30         pushl $1                /* Push second argument of zero.  */
  31         pushl %ecx              /* Push back first argument.  */
  32         pushl %eax              /* Push back return PC.  */
  33         jmp __sigsetjmp
  34 END (setjmp)
  35
  36         /* Binary compatibility entry point.  */
  37 ENTRY (_setjmp)
  38         .weak C_SYMBOL_NAME (_setjmp)
  39 ENTRY (__setjmp)
  40         popl %eax               /* Pop return address.  */
  41         popl %ecx               /* Pop jmp_buf.  */
  42         pushl $0                /* Push zero argument.  */
  43         pushl %ecx              /* Push jmp_buf.  */
  44         pushl %eax              /* Push back return address.  */
  45
  46 ENTRY (__sigsetjmp)
  47         movl 4(%esp), %eax      /* User's jmp_buf in %eax.  */
  48         /* Save registers.  */
  49         movl %ebx, (JB_BX*4)(%eax)
  50         movl %esi, (JB_SI*4)(%eax)
  51         movl %edi, (JB_DI*4)(%eax)
  52         movl %ebp, (JB_BP*4)(%eax)
  53         leal 4(%esp), %ecx      /* Save SP as it will be after we return.  */
  54         movl %ecx, (JB_SP*4)(%eax)
  55         movl 0(%esp), %ecx      /* Save PC we are returning to now.  */
  56         movl %ecx, (JB_PC*4)(%eax)
  57
  58         /* Make a tail call to __sigjmp_save; it takes the same args.  */
  59 #ifdef  PIC
  60         /* We cannot use the PLT, because it requires that %ebx be set, but
  61            we can't save and restore our caller's value.  Instead, we do an
  62            indirect jump through the GOT, using for the temporary register
  63            %ecx, which is call-clobbered.  */
  64         call here
  65 here:   popl %ecx
  66         addl $_GLOBAL_OFFSET_TABLE_+[.-here], %ecx
  67         movl C_SYMBOL_NAME(__sigjmp_save@GOT)(%ecx), %ecx
  68         jmp *%ecx
  69 #else
  70         jmp __sigjmp_save
  71 #endif
  72 END (__sigsetjmp)