Memory ordering in pthread_mutex_{,timed}lock.
[glibc.git] / sysdeps / x86_64 / __longjmp.S
blob24552ece377c658e4b15f3b15981c8da369da0dd
1 /* Copyright (C) 2001,2004,2005,2006,2009 Free Software Foundation, Inc.
2    This file is part of the GNU C Library.
4    The GNU C Library is free software; you can redistribute it and/or
5    modify it under the terms of the GNU Lesser General Public
6    License as published by the Free Software Foundation; either
7    version 2.1 of the License, or (at your option) any later version.
9    The GNU C Library is distributed in the hope that it will be useful,
10    but WITHOUT ANY WARRANTY; without even the implied warranty of
11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
12    Lesser General Public License for more details.
14    You should have received a copy of the GNU Lesser General Public
15    License along with the GNU C Library; if not, write to the Free
16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
17    02111-1307 USA.  */
19 #include <sysdep.h>
20 #include <jmpbuf-offsets.h>
21 #include <asm-syntax.h>
23 /* Jump to the position specified by ENV, causing the
24    setjmp call there to return VAL, or 1 if VAL is 0.
25    void __longjmp (__jmp_buf env, int val).  */
26         .text
27 ENTRY(__longjmp)
28         /* Restore registers.  */
29         movq (JB_RSP*8)(%rdi),%r8
30         movq (JB_RBP*8)(%rdi),%r9
31         movq (JB_PC*8)(%rdi),%rdx
32 #ifdef PTR_DEMANGLE
33         PTR_DEMANGLE (%r8)
34         PTR_DEMANGLE (%r9)
35         PTR_DEMANGLE (%rdx)
36 #endif
37 #ifdef CHECK_RSP
38         CHECK_RSP (%r8)
39 #endif
40         /* We add unwind information for the target here.  */
41         cfi_def_cfa(%rdi, 0)
42         cfi_register(%rsp,%r8)
43         cfi_register(%rbp,%r9)
44         cfi_register(%rip,%rdx)
45         cfi_offset(%rbx,JB_RBX*8)
46         cfi_offset(%rbp,JB_RBP*8)
47         cfi_offset(%r12,JB_R12*8)
48         cfi_offset(%r13,JB_R13*8)
49         cfi_offset(%r14,JB_R14*8)
50         cfi_offset(%r15,JB_R15*8)
51         movq (JB_RBX*8)(%rdi),%rbx
52         movq (JB_R12*8)(%rdi),%r12
53         movq (JB_R13*8)(%rdi),%r13
54         movq (JB_R14*8)(%rdi),%r14
55         movq (JB_R15*8)(%rdi),%r15
56         /* Set return value for setjmp.  */
57         mov %esi, %eax
58         movq %r8,%rsp
59         movq %r9,%rbp
60         jmpq *%rdx
61 END (BP_SYM (__longjmp))