sysdeps/unix/sysv/linux/alpha/clone.S

   1 /* Copyright (C) 1996, 1997 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Richard Henderson <rth@tamu.edu>, 1996.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Library General Public License as
   7    published by the Free Software Foundation; either version 2 of the
   8    License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Library General Public License for more details.
  14
  15    You should have received a copy of the GNU Library General Public
  16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  18    Boston, MA 02111-1307, USA.  */
  19
  20 /* clone() is even more special than fork() as it mucks with stacks
  21    and invokes a function in the right context after its all over.  */
  22
  23 #include <sysdep.h>
  24 #define _ERRNO_H        1
  25 #include <errnos.h>
  26
  27 /* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg) */
  28
  29         .text
  30 ENTRY(__clone)
  31         .frame  sp,0,ra,0
  32 #ifdef PROF
  33         .set noat
  34         lda     AT, _mcount
  35         jsr     AT, (AT), _mcount
  36         .set at
  37 #endif
  38         .prologue 1
  39
  40         /* Sanity check arguments.  */
  41         ldiq    v0,EINVAL
  42         beq     a0,$error               /* no NULL function pointers */
  43         beq     a1,$error               /* no NULL stack pointers */
  44
  45         /* Do the system call */
  46         mov     a0,pv                   /* get fn ptr out of the way */
  47         mov     a3,t0                   /* get fn arg out of the way */
  48         mov     a2,a0
  49         ldiq    v0,__NR_clone
  50         call_pal PAL_callsys
  51
  52         bne     a3,$error
  53         beq     v0,thread_start
  54
  55         /* Successful return from the parent */
  56         ret
  57
  58         /* Something bad happened -- no child created */
  59 $error:
  60         br      gp,1f
  61 1:      ldgp    gp,0(gp)
  62         jmp     zero,__syscall_error
  63
  64         END(__clone)
  65
  66 /* Load up the arguments to the function.  Put this block of code in
  67    its own function so that we can terminate the stack trace with our
  68    debug info.  */
  69
  70         .ent thread_start
  71 thread_start:
  72         .frame fp,0,zero,0
  73         mov     zero,fp
  74         .prologue 0
  75
  76         /* Call the user's function */
  77         mov     t0,a0
  78         jsr     ra,(pv)
  79         ldgp    gp,0(ra)
  80
  81         /* Call _exit rather than doing it inline for breakpoint purposes */
  82         mov     v0,a0
  83         jsr     ra,_exit
  84
  85         /* Die horribly.  */
  86         halt
  87
  88         .end thread_start
  89
  90 weak_alias(__clone, clone)