configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37 [  --with-fp              if using floating-point hardware [default=yes]],
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(gnu-binutils, dnl
  40   --with-gnu-binutils     if using GNU binutils (as and ld),
  41             gnu_binutils=$withval, gnu_binutils=no)
  42 AC_ARG_WITH(gnu-ld, dnl
  43   --with-gnu-ld           if using GNU ld (in the binutils package),
  44             gnu_ld=$withval, gnu_ld=no)
  45 AC_ARG_WITH(gnu-as, dnl
  46   --with-gnu-as           if using GNU as (in the binutils package),
  47             gnu_as=$withval, gnu_as=no)
  48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  49 AC_ARG_WITH(elf, dnl
  50   --with-elf              if using the ELF object format,
  51             elf=$withval, elf=no)
  52
  53 AC_ARG_ENABLE(libio, dnl
  54 [  --enable-libio          build in GNU libio instead of GNU stdio],
  55               [if test $enableval = yes; then
  56                  stdio=libio
  57                else
  58                  stdio=stdio
  59                fi],
  60               stdio=default)
  61
  62 AC_ARG_ENABLE(sanity-checks, dnl
  63 [  --disable-sanity-checks really do not use threads (should not be used
  64                           except in special situations) [default=yes]],
  65               enable_sanity=$enableval, enable_sanity=yes)
  66
  67 dnl Arguments to enable or disable building the shared, profiled, and
  68 dnl -fomit-frame-pointer libraries.
  69 AC_ARG_ENABLE(shared, dnl
  70 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  71               shared=$enableval, shared=default)
  72 AC_ARG_ENABLE(profile, dnl
  73 [  --enable-profile        build profiled library [default=yes]],
  74               profile=$enableval, profile=yes)
  75 AC_ARG_ENABLE(omitfp, dnl
  76 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  77               omitfp=$enableval, omitfp=no)
  78 AC_ARG_ENABLE(bounded, dnl
  79 [  --enable-bounded        build with runtime bounds checking [default=no]],
  80               bounded=$enableval, bounded=no)
  81
  82 dnl Generic infrastructure for drop-in additions to libc.
  83 AC_ARG_ENABLE(add-ons, dnl
  84 [  --enable-add-ons=DIR... configure and build named extra directories],
  85               [add_ons=`echo "$enableval" | sed 's/,/ /g'`],
  86               [add_ons=])
  87 AC_CONFIG_SUBDIRS($add_ons)
  88 add_ons_pfx=
  89 if test x"$add_ons" != x; then
  90   for f in $add_ons; do
  91     add_ons_pfx="$add_ons_pfx $f/"
  92   done
  93 fi
  94
  95 AC_CANONICAL_HOST
  96
  97 # The way shlib-versions is used to generate soversions.mk uses a
  98 # fairly simplistic model for name recognition that can't distinguish
  99 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 100 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 101 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 102 case "$host_os" in
 103 linux*)
 104   ;;
 105 gnu*)
 106   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 107   ;;
 108 esac
 109
 110 # We keep the original values in `$config_*' and never modify them, so we
 111 # can write them unchanged into config.make.  Everything else uses
 112 # $machine, $vendor, and $os, and changes them whenever convenient.
 113 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 114
 115 # Some configurations imply other options.
 116 case "$host_os" in
 117 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 118   # These systems always use GNU tools.
 119   gnu_ld=yes gnu_as=yes ;;
 120 esac
 121 case "$host_os" in
 122 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 123 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 124   ;;
 125 gnu* | linux* | sysv4* | solaris2*)
 126   # These systems (almost) always use the ELF format.
 127   elf=yes
 128   ;;
 129 esac
 130
 131 machine=$config_machine
 132 vendor=$config_vendor
 133 os=$config_os
 134
 135 dnl We need to use [ and ] for other purposes for a while now.
 136 changequote(,)dnl
 137 # Expand the configuration machine name into a subdirectory by architecture
 138 # type and particular chip.
 139 case "$machine" in
 140 a29k | am29000) base_machine=a29k machine=a29k ;;
 141 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 142 arm*)           base_machine=arm machine=arm/$machine ;;
 143 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 144 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 145 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 146 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 147 m88???)         base_machine=m88k machine=m88k/$machine ;;
 148 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 149 mips*)          base_machine=mips machine=mips/$machine ;;
 150 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 151 sparc[6789])    base_machine=sparc machine=sparc/$machine ;;
 152 supersparc)     base_machine=sparc machine=sparc/sparc8 ;;
 153 esac
 154 changequote([,])dnl
 155 AC_SUBST(base_machine)
 156
 157 # Compute the list of sysdep directories for this configuration.
 158 # This can take a while to compute.
 159 sysdep_dir=$srcdir/sysdeps
 160 AC_MSG_CHECKING(sysdep dirs)
 161 dnl We need to use [ and ] for other purposes for a while now.
 162 changequote(,)dnl
 163 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 164 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 165
 166 case "$os" in
 167 gnu*)
 168   base_os=mach/hurd ;;
 169 netbsd* | 386bsd* | freebsd* | bsdi*)
 170   base_os=unix/bsd/bsd4.4 ;;
 171 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 172   base_os=unix/bsd ;;
 173 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 174   base_os=unix/sysv ;;
 175 solaris[2-9]*)
 176   base_os=unix/sysv/sysv4 ;;
 177 none)
 178   base_os=standalone ;;
 179 *)
 180   base_os='' ;;
 181 esac
 182
 183 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 184 tail=$os
 185 ostry=$os
 186 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 187   ostry="$ostry /$o"
 188   tail=$o
 189 done
 190 o=`echo $tail | sed 's/[0-9]*$//'`
 191 if test $o != $tail; then
 192   ostry="$ostry /$o"
 193 fi
 194 # For linux-gnu, try linux-gnu, then linux.
 195 o=`echo $tail | sed 's/-.*$//'`
 196 if test $o != $tail; then
 197   ostry="$ostry /$o"
 198 fi
 199
 200 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 201 base=
 202 tail=$base_os
 203 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 204   set $b
 205   base="$base /$1"
 206   tail="$2"
 207 done
 208
 209 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 210 mach=
 211 tail=$machine
 212 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 213   set $m
 214   # Prepend the machine's FPU directory unless --without-fp.
 215   if test "$with_fp" = yes; then
 216     mach="$mach /$1/fpu"
 217   fi
 218   mach="$mach /$1"
 219   tail="$2"
 220 done
 221
 222 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 223 changequote([,])dnl
 224
 225 # Find what sysdep directories exist.
 226 sysnames=
 227 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 228 for d in $add_ons_pfx ''; do
 229   for b in $base ''; do
 230     for m0 in $mach ''; do
 231       for v in /$vendor ''; do
 232         for o in /$ostry ''; do
 233           for m in $mach ''; do
 234             if test "$m0$b$v$o$m"; then
 235               try="${d}sysdeps$m0$b$v$o$m"
 236               test -n "$enable_debug_configure" &&
 237               echo "$0 [DEBUG]: try $try" >&2
 238               case $try in
 239                 /*) dest=$try ;;
 240                 *)  dest=$srcdir/$try ;;
 241               esac
 242               if test -d $dest; then
 243                 sysnames="$sysnames $try"
 244                 { test -n "$o" || test -n "$b"; } && os_used=t
 245                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 246               fi
 247             fi
 248           done
 249         done
 250       done
 251     done
 252   done
 253 done
 254 IFS="$ac_save_ifs"
 255
 256 if test -z "$os_used" && test "$os" != none; then
 257   AC_MSG_ERROR(Operating system $os is not supported.)
 258 fi
 259 if test -z "$machine_used" && test "$machine" != none; then
 260   AC_MSG_ERROR(The $machine is not supported.)
 261 fi
 262
 263 # We have now validated the configuration.
 264
 265
 266 # If using ELF, look for an `elf' subdirectory of each machine directory.
 267 # We prepend these rather than inserting them whereever the machine appears
 268 # because things specified by the machine's ELF ABI should override
 269 # OS-specific things, and should always be the same for any OS on the
 270 # machine (otherwise what's the point of an ABI?).
 271 if test "$elf" = yes; then
 272   elf_dirs=
 273   for d in $add_ons_pfx ''; do
 274     case $d in
 275       /*) xsrcdir= ;;
 276       *)  xsrcdir=$srcdir/ ;;
 277     esac
 278     for m in $mach; do
 279       if test -d $xsrcdir${d}sysdeps$m/elf; then
 280         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 281       fi
 282     done
 283   done
 284   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 285 fi
 286
 287
 288 # Expand the list of system names into a full list of directories
 289 # from each element's parent name and Implies file (if present).
 290 set $sysnames
 291 names=
 292 while test $# -gt 0; do
 293   name=$1
 294   shift
 295
 296   case " $names " in *" $name "*)
 297     # Already in the list.
 298     continue
 299   esac
 300
 301   # Report each name as we discover it, so there is no long pause in output.
 302   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 303
 304   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 305
 306   case $name in
 307     /*) xsrcdir= ;;
 308     *)  xsrcdir=$srcdir/ ;;
 309   esac
 310   test -n "$enable_debug_configure" &&
 311   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 312
 313   if test -f $xsrcdir$name/Implies; then
 314     # Collect more names from the `Implies' file (removing comments).
 315     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 316     implied=
 317     for x in $implied_candidate; do
 318       if test -d $xsrcdir$name_base/$x; then
 319         implied="$implied $name_base/$x";
 320       else
 321         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 322       fi
 323     done
 324   else
 325     implied=
 326   fi
 327
 328   # Add NAME to the list of names.
 329   names="$names $name"
 330
 331   # Find the parent of NAME, using the empty string if it has none.
 332 changequote(,)dnl
 333   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 334 changequote([,])dnl
 335
 336   # Add the names implied by NAME, and NAME's parent (if it has one), to
 337   # the list of names to be processed (the argument list).  We prepend the
 338   # implied names to the list and append the parent.  We want implied
 339   # directories to come before further directories inferred from the
 340   # configuration components; this ensures that for sysv4, unix/common
 341   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 342   # after sysv4).
 343   sysnames="`echo $implied $* $parent`"
 344   test -n "$sysnames" && set $sysnames
 345 done
 346
 347 # Add the default directories.
 348 sysnames="$names sysdeps/generic sysdeps/stub"
 349 AC_SUBST(sysnames)
 350 # The other names were emitted during the scan.
 351 AC_MSG_RESULT(sysdeps/generic sysdeps/stub)
 352
 353
 354 ### Locate tools.
 355
 356 AC_PROG_INSTALL
 357 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 358   # The makefiles need to use a different form to find it in $srcdir.
 359   INSTALL='$(..)./install-sh -c'
 360 fi
 361 AC_PROG_LN_S
 362 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 363
 364 AC_PROG_CC
 365 AC_CANONICAL_BUILD
 366 if test $host != $build; then
 367   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 368 fi
 369 AC_PROG_CPP
 370 AC_CHECK_TOOL(AR, ar)
 371 AC_CHECK_TOOL(RANLIB, ranlib, :)
 372
 373 AC_PATH_PROG(BASH, bash, no)
 374 if test "$BASH" != no &&
 375    $BASH -c 'test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 376   libc_cv_have_bash2=yes
 377 else
 378   libc_cv_have_bash2=no
 379 fi
 380 AC_SUBST(libc_cv_have_bash2)
 381
 382 dnl We need a ksh compatible shell for tzselect.
 383 if test "$BASH" = no; then
 384   AC_PATH_PROG(KSH, ksh, no)
 385   if test "$KSH" = no; then
 386     libc_cv_have_ksh=no
 387   else
 388     libc_cv_have_ksh=yes
 389   fi
 390 else
 391   KSH="$BASH"
 392   AC_SUBST(KSH)
 393   libc_cv_have_ksh=yes
 394 fi
 395 AC_SUBST(libc_cv_have_ksh)
 396
 397 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 398 echo '#include <stddef.h>
 399 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 400 if eval "$ac_cpp conftest.c 2>/dev/null" \
 401 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 402   libc_cv_signed_size_t=no
 403 else
 404   libc_cv_signed_size_t=yes
 405 fi
 406 rm -f conftest*])
 407 if test $libc_cv_signed_size_t = yes; then
 408   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 409   cat >> confdefs.h <<\EOF
 410 #undef __SIZE_TYPE__
 411 #define __SIZE_TYPE__ unsigned
 412 EOF
 413 fi
 414
 415 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 416 AC_TRY_COMPILE(dnl
 417 [#define __need_size_t
 418 #define __need_wchar_t
 419 #include <stddef.h>
 420 #define __need_NULL
 421 #include <stddef.h>], [size_t size; wchar_t wchar;
 422 #ifdef offsetof
 423 #error stddef.h ignored __need_*
 424 #endif
 425 if (&size == NULL || &wchar == NULL) abort ();],
 426                libc_cv_friendly_stddef=yes,
 427                libc_cv_friendly_stddef=no)])
 428 if test $libc_cv_friendly_stddef = yes; then
 429   config_vars="$config_vars
 430 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 431 fi
 432
 433 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 434                libc_cv_need_minus_P, [dnl
 435 cat > conftest.S <<EOF
 436 #include "confdefs.h"
 437 /* Nothing whatsoever.  */
 438 EOF
 439 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 440   libc_cv_need_minus_P=no
 441 else
 442   libc_cv_need_minus_P=yes
 443 fi
 444 rm -f conftest*])
 445 if test $libc_cv_need_minus_P = yes; then
 446   config_vars="$config_vars
 447 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 448 fi
 449
 450 AC_CACHE_CHECK(for assembler global-symbol directive,
 451                libc_cv_asm_global_directive, [dnl
 452 libc_cv_asm_global_directive=UNKNOWN
 453 for ac_globl in .globl .global; do
 454   cat > conftest.s <<EOF
 455 .text
 456 ${ac_globl} foo
 457 foo: .long 0
 458 EOF
 459   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 460     libc_cv_asm_global_directive=${ac_globl}
 461   fi
 462   rm -f conftest*
 463   test $libc_cv_asm_global_directive != UNKNOWN && break
 464 done])
 465 if test $libc_cv_asm_global_directive = UNKNOWN; then
 466   AC_MSG_ERROR(cannot determine asm global directive)
 467 else
 468   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 469 fi
 470
 471 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 472 cat > conftest.s <<EOF
 473 .text
 474 foo: .long 0
 475 .set glibc_conftest_frobozz,foo
 476 $libc_cv_asm_global_directive glibc_conftest_frobozz
 477 EOF
 478 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 479 # (but it doesn't work), so we must do a linking check to be sure.
 480 cat > conftest1.c <<\EOF
 481 extern int glibc_conftest_frobozz;
 482 main () { printf ("%d\n", glibc_conftest_frobozz); }
 483 EOF
 484 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 485             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 486   libc_cv_asm_set_directive=yes
 487 else
 488   libc_cv_asm_set_directive=no
 489 fi
 490 rm -f conftest*])
 491 if test $libc_cv_asm_set_directive = yes; then
 492   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 493 fi
 494
 495 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 496 [cat > conftest.s <<EOF
 497 .text
 498 _sym:
 499 .symver _sym,sym@VERS
 500 EOF
 501 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 502   libc_cv_asm_symver_directive=yes
 503 else
 504   libc_cv_asm_symver_directive=no
 505 fi
 506 rm -f conftest*])
 507 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 508 if test $libc_cv_asm_symver_directive = yes; then
 509   cat > conftest.s <<EOF
 510 .text
 511 _sym:
 512 .symver _sym,sym@VERS
 513 EOF
 514   cat > conftest.map <<EOF
 515 VERS {
 516         global: sym;
 517 };
 518 EOF
 519   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 520     if AC_TRY_COMMAND([${CC-cc} $CFLAGS --shared -o conftest.so conftest.o
 521                                         -Wl,--version-script,conftest.map]);
 522     then
 523       libc_cv_ld_version_script_option=yes
 524     else
 525       libc_cv_ld_version_script_option=no
 526     fi
 527   else
 528     libc_cv_ld_version_script_option=no
 529   fi
 530 else
 531   libc_cv_ld_version_script_option=no
 532 fi
 533 rm -f conftest*])
 534 if test $libc_cv_asm_symver_directive = yes &&
 535    test $libc_cv_ld_version_script_option = yes; then
 536   VERSIONING=yes
 537   AC_DEFINE(DO_VERSIONING)
 538 else
 539   VERSIONING=no
 540 fi
 541 AC_SUBST(VERSIONING)
 542
 543 if test $elf = yes; then
 544   AC_CACHE_CHECK(for .previous assembler directive,
 545                  libc_cv_asm_previous_directive, [dnl
 546   cat > conftest.s <<EOF
 547 .section foo_section
 548 .previous
 549 EOF
 550   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 551     libc_cv_asm_previous_directive=yes
 552   else
 553     libc_cv_asm_previous_directive=no
 554   fi
 555   rm -f conftest*])
 556   if test $libc_cv_asm_previous_directive = yes; then
 557     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 558   else
 559     AC_CACHE_CHECK(for .popsection assembler directive,
 560                    libc_cv_asm_popsection_directive, [dnl
 561     cat > conftest.s <<EOF
 562 .pushsection foo_section
 563 .popsection
 564 EOF
 565     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 566       libc_cv_asm_popsection_directive=yes
 567     else
 568       libc_cv_asm_popsection_directive=no
 569     fi
 570     rm -f conftest*])
 571     if test $libc_cv_asm_popsection_directive = yes; then
 572       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 573     fi
 574   fi
 575 fi
 576
 577 if test $elf != yes; then
 578   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 579                  [AC_TRY_COMPILE(, [asm (".section .init");
 580                                     asm (".section .fini");
 581                                     asm (".text");],
 582                                  libc_cv_have_initfini=yes,
 583                                  libc_cv_have_initfini=no)])
 584   AC_SUBST(libc_cv_have_initfini)dnl
 585   if test $libc_cv_have_initfini = yes; then
 586     AC_DEFINE(HAVE_INITFINI)
 587   fi
 588 fi
 589
 590 if test $elf = yes; then
 591   libc_cv_asm_underscores=no
 592 else
 593   AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 594                  [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 595                               libc_cv_asm_underscores=yes,
 596                               libc_cv_asm_underscores=no)])
 597 fi
 598 if test $libc_cv_asm_underscores = no; then
 599   AC_DEFINE(NO_UNDERSCORES)
 600 fi
 601
 602 if test $elf = yes; then
 603   libc_cv_weak_symbols=yes
 604   libc_cv_asm_weak_directive=yes
 605   libc_cv_asm_weakext_directive=no
 606 else
 607   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 608                  [dnl
 609 cat > conftest.s <<EOF
 610 .text
 611 ${libc_cv_asm_global_directive} foo
 612 foo: .long 0
 613 .weak foo
 614 .weak bar; bar = foo
 615 EOF
 616   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 617     libc_cv_asm_weak_directive=yes
 618   else
 619     libc_cv_asm_weak_directive=no
 620   fi
 621   rm -f conftest*])
 622
 623 if test $libc_cv_asm_weak_directive = no; then
 624   AC_CACHE_CHECK(for assembler .weakext directive,
 625                  libc_cv_asm_weakext_directive,
 626                  [dnl
 627 cat > conftest.s <<EOF
 628 .text
 629 ${libc_cv_asm_global_directive} foo
 630 foo: .long 0
 631 .weakext foo
 632 .weakext foo, bar
 633 EOF
 634   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 635     libc_cv_asm_weakext_directive=yes
 636   else
 637     libc_cv_asm_weakext_directive=no
 638   fi
 639   rm -f conftest*])
 640
 641   fi # no .weak
 642 fi # not ELF
 643
 644 if test $libc_cv_asm_weak_directive = yes; then
 645   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 646 elif test $libc_cv_asm_weakext_directive = yes; then
 647   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 648 fi
 649
 650 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 651 cat > conftest.c <<\EOF
 652 _start () {}
 653 int __eh_pc;
 654 __throw () {}
 655 EOF
 656 dnl No \ in command here because it ends up inside ''.
 657 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 658                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 659                             -o conftest conftest.c]); then
 660   libc_cv_ld_no_whole_archive=yes
 661 else
 662   libc_cv_ld_no_whole_archive=no
 663 fi
 664 rm -f conftest*])
 665 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 666
 667 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
 668 cat > conftest.c <<\EOF
 669 _start () {}
 670 int __eh_pc;
 671 __throw () {}
 672 EOF
 673 dnl No \ in command here because it ends up inside ''.
 674 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 675                             -nostdlib -nostartfiles -fno-exceptions
 676                             -o conftest conftest.c]); then
 677   libc_cv_gcc_no_exceptions=yes
 678 else
 679   libc_cv_gcc_no_exceptions=no
 680 fi
 681 rm -f conftest*])
 682 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
 683
 684 ### End of automated tests.
 685 ### Now run sysdeps configure fragments.
 686
 687 # sysdeps configure fragments may set these with files to be linked below.
 688 libc_link_dests=
 689 libc_link_sources=
 690
 691 # Iterate over all the sysdep directories we will use, running their
 692 # configure fragments, and looking for a uname implementation.
 693 uname=
 694 for dir in $sysnames; do
 695   case $dir in
 696     /*) dest=$dir ;;
 697     *)  dest=$srcdir/$dir ;;
 698   esac
 699   if test -r $dest/configure; then
 700     AC_MSG_RESULT(running configure fragment for $dest)
 701     . $dest/configure
 702   fi
 703 [
 704   if test -z "$uname"; then
 705     if test -r $sysdep_dir/$dir/uname.c ||
 706        test -r $sysdep_dir/$dir/uname.S ||
 707        { test -r $sysdep_dir/$dir/syscalls.list &&
 708          grep '^uname[  ]' $sysdep_dir/$dir/syscalls.list >/dev/null; }; then
 709       uname=$dir
 710     fi
 711   fi
 712 ]dnl
 713 done
 714
 715 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 716
 717 # If we will use the generic uname implementation, we must figure out what
 718 # it will say by examining the system, and write the results in config-name.h.
 719 if test "$uname" = generic; then
 720
 721 changequote(,)dnl
 722   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 723 changequote([,])dnl
 724   if test $uname_sysname != $config_os; then
 725     config_release=`echo $config_os | sed s/$uname_sysname//`
 726   fi
 727 dnl
 728 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 729     if test -r /vmunix; then
 730       kernel_id=`strings /vmunix | grep UNIX`
 731     elif test -r /dynix; then
 732       kernel_id=`strings /dynix | grep DYNIX`
 733     else
 734       kernel_id=
 735     fi
 736 ])dnl
 737
 738   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 739 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 740 changequote(,)dnl
 741   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 742 changequote([,])dnl
 743   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 744          != x$config_release; then
 745     # The configuration release is a substring of the kernel release.
 746     libc_cv_uname_release=$kernel_release
 747   elif test x$config_release != x; then
 748     libc_cv_uname_release=$config_release
 749   elif test x$kernel_release != x; then
 750     libc_cv_uname_release=$kernel_release
 751   else
 752     libc_cv_uname_release=unknown
 753   fi])
 754   uname_release="$libc_cv_uname_release"
 755
 756   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 757 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 758 changequote(,)dnl
 759   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 760 changequote([,])dnl
 761   if test -n "$kernel_version"; then
 762     libc_cv_uname_version="$kernel_version"
 763   else
 764     libc_cv_uname_version=unknown
 765   fi])
 766   uname_version="$libc_cv_uname_version"
 767
 768 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 769   config_uname=config-name.h:config-name.in
 770 else
 771   # For non-generic uname, we don't need to create config-name.h at all.
 772   config_uname=
 773 fi
 774
 775 AC_MSG_CHECKING(stdio selection)
 776 AC_SUBST(stdio)
 777 case $stdio in
 778 libio) AC_DEFINE(USE_IN_LIBIO) ;;
 779 default) stdio=stdio ;;
 780 esac
 781 AC_MSG_RESULT($stdio)
 782
 783 AC_SUBST(libc_cv_slibdir)
 784 AC_SUBST(libc_cv_sysconfdir)
 785 AC_SUBST(libc_cv_rootsbindir)
 786
 787 AC_SUBST(has_ldconfig)
 788
 789 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
 790 if test $gnu_ld = yes; then
 791   AC_DEFINE(HAVE_GNU_LD)
 792 fi
 793 if test $gnu_as = yes; then
 794   AC_DEFINE(HAVE_GNU_AS)
 795 fi
 796 if test $elf = yes; then
 797   AC_DEFINE(HAVE_ELF)
 798 fi
 799
 800 AC_SUBST(shared)
 801 if test $shared = default; then
 802   if test $gnu_ld = yes; then
 803     shared=$elf
 804   else
 805     # For now we do not assume shared libs are available.  In future more
 806     # tests might become available.
 807     shared=no
 808   fi
 809 fi
 810 AC_SUBST(profile)
 811 AC_SUBST(omitfp)
 812 AC_SUBST(bounded)
 813
 814 AC_SUBST(DEFINES)
 815
 816 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 817   config_makefile=
 818 else
 819   config_makefile=Makefile
 820 fi
 821
 822 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
 823 AC_SUBST(VERSION)
 824
 825 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
 826           [echo '$config_vars' >> config.make])