sysdeps/s390/s390-64/start.S

   1 /* Startup code compliant to the 64 bit S/390 ELF ABI.
   2    Copyright (C) 2001-2022 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    In addition to the permissions in the GNU Lesser General Public
  11    License, the Free Software Foundation gives you unlimited
  12    permission to link the compiled version of this file with other
  13    programs, and to distribute those programs without any restriction
  14    coming from the use of this file. (The GNU Lesser General Public
  15    License restrictions do apply in other respects; for example, they
  16    cover modification of the file, and distribution when not linked
  17    into another program.)
  18
  19    Note that people who make modified versions of this file are not
  20    obligated to grant this special exception for their modified
  21    versions; it is their choice whether to do so. The GNU Lesser
  22    General Public License gives permission to release a modified
  23    version without this exception; this exception also makes it
  24    possible to release a modified version which carries forward this
  25    exception.
  26
  27    The GNU C Library is distributed in the hope that it will be useful,
  28    but WITHOUT ANY WARRANTY; without even the implied warranty of
  29    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  30    Lesser General Public License for more details.
  31
  32    You should have received a copy of the GNU Lesser General Public
  33    License along with the GNU C Library; if not, see
  34    <https://www.gnu.org/licenses/>.  */
  35
  36 #include <sysdep.h>
  37
  38 /*
  39    This is the canonical entry point, usually the first thing in the text
  40    segment. Most registers' values are unspecified, except for:
  41
  42    %r14         Contains a function pointer to be registered with `atexit'.
  43                 This is how the dynamic linker arranges to have DT_FINI
  44                 functions called for shared libraries that have been loaded
  45                 before this code runs.
  46
  47    %r15         The stack contains the arguments and environment:
  48                 0(%r15)                 argc
  49                 8(%r15)                 argv[0]
  50                 ...
  51                 (8*argc)(%r15)          NULL
  52                 (8*(argc+1))(%r15)      envp[0]
  53                 ...
  54                                         NULL
  55 */
  56
  57         .text
  58         .globl _start
  59         .type _start,@function
  60 _start:
  61         cfi_startproc
  62         /* Mark r14 as undefined in order to stop unwinding here!  */
  63         cfi_undefined (r14)
  64         /* Load argc and argv from stack.  */
  65         la      %r4,8(%r15)             # get argv
  66         lg      %r3,0(%r15)             # get argc
  67
  68         /* Align the stack to a double word boundary.  */
  69         lghi    %r0,-16
  70         ngr     %r15,%r0
  71
  72         /* Setup a stack frame and a parameter area.  */
  73         aghi    %r15,-176               # make room on stack
  74         xc      0(8,%r15),0(%r15)       # clear back-chain
  75
  76         /* Set up arguments for __libc_start_main:
  77            main, argc, argv, envp, _init, _fini, rtld_fini, stack_end
  78            Note that envp will be determined later in __libc_start_main.
  79          */
  80         stmg    %r14,%r15,160(%r15)     # store rtld_fini/stack_end to parameter area
  81         la      %r7,160(%r15)
  82         lghi    %r6,0                   # Used to be fini.
  83         lghi    %r5,0                   # Used to be init.
  84
  85         /* Ok, now branch to the libc main routine.  */
  86 #ifdef PIC
  87 # ifdef SHARED
  88         /* Used for dynamic linked position independent executable.
  89            => Scrt1.o  */
  90         larl    %r2,main@GOTENT         # load pointer to main
  91         lg      %r2,0(%r2)
  92 # else
  93         /* Used for dynamic linked position dependent executable.
  94            => crt1.o (glibc configured without --disable-default-pie:
  95            PIC is defined)
  96            Or for static linked position independent executable.
  97            => rcrt1.o (only available if glibc configured without
  98            --disable-default-pie: PIC is defined) */
  99         larl    %r2,__wrap_main
 100 # endif
 101         brasl   %r14,__libc_start_main@plt
 102 #else
 103         /* Used for dynamic/static linked position dependent executable.
 104            => crt1.o (glibc configured with --disable-default-pie:
 105            PIC and SHARED are not defined)  */
 106         larl    %r2,main                # load pointer to main
 107         brasl   %r14,__libc_start_main
 108 #endif
 109
 110         /* Crash if __libc_start_main returns.  */
 111         .word   0
 112
 113         cfi_endproc
 114
 115 #if defined PIC && !defined SHARED
 116         /* When main is not defined in the executable but in a shared library
 117            then a wrapper is needed in crt1.o of the static-pie enabled libc,
 118            because crt1.o and rcrt1.o share code and the later must avoid the
 119            use of GOT relocations before __libc_start_main is called.  */
 120 __wrap_main:
 121         cfi_startproc
 122         larl    %r1,main@GOTENT         # load pointer to main
 123         lg      %r1,0(%r1)
 124         br      %r1
 125         cfi_endproc
 126 #endif
 127
 128         /* Define a symbol for the first piece of initialized data.  */
 129         .data
 130         .globl __data_start
 131 __data_start:
 132         .long 0
 133         .weak data_start
 134         data_start = __data_start