configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.2)dnl               dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21
  22 dnl Arguments to specify presence of other packages/features.
  23 AC_ARG_WITH(fp, dnl
  24   --with-fp               if using floating-point hardware,
  25             with_fp=$withval, with_fp=yes)
  26 AC_ARG_WITH(gnu-binutils, dnl
  27   --with-gnu-binutils     if using GNU binutils (as and ld),
  28             gnu_binutils=$withval, gnu_binutils=no)
  29 AC_ARG_WITH(gnu-ld, dnl
  30   --with-gnu-ld           if using GNU ld (in the binutils package),
  31             gnu_ld=$withval, gnu_ld=no)
  32 AC_ARG_WITH(gnu-as, dnl
  33   --with-gnu-as           if using GNU as (in the binutils package),
  34             gnu_as=$withval, gnu_as=no)
  35 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  36 AC_ARG_WITH(elf, dnl
  37   --with-elf              if using the ELF object format,
  38             elf=$withval, elf=no)
  39 AC_ARG_WITH(weak-symbols, dnl
  40   --with-weak-symbols     if weak symbols are available in as and ld,
  41             weak=$withval, weak=no)
  42
  43 dnl Arguments to enable or disable building the shared, profiled, and
  44 dnl -fomit-frame-pointer libraries.
  45 AC_ARG_ENABLE(shared, dnl
  46 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  47             shared=$enableval, shared=default)
  48 AC_ARG_ENABLE(profile, dnl
  49 [  --enable-profile        build profiled library [default=yes]],
  50             profile=$enableval, profile=yes)
  51 AC_ARG_ENABLE(omitfp, dnl
  52 [  --enable-omitfp       build undebuggable optimized library [default=no]],
  53             omitfp=$enableval, omitfp=no)
  54
  55 AC_CANONICAL_HOST
  56 # We keep the original values in `$config_*' and never modify them, so we
  57 # can write them unchanged into config.make.  Everything else uses
  58 # $machine, $vendor, and $os, and changes them whenever convenient.
  59 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
  60
  61 sysdep_dir=$srcdir/sysdeps
  62 AC_MSG_CHECKING(sysdep dirs)
  63 AC_CACHE_VAL(libc_cv_sysdirs, [dnl
  64 machine=$config_machine
  65 vendor=$config_vendor
  66 os=$config_os
  67
  68 dnl We need to use [ and ] for other purposes for a while now.
  69 changequote(,)dnl
  70 # Expand the configuration machine name into a subdirectory by architecture
  71 # type and particular chip.
  72 case "$machine" in
  73 i[345]86)
  74   machine=i386/$machine ;;
  75 sparc[6789])
  76   machine=sparc/$machine ;;
  77 m68k)
  78   machine=m68k/m68020 ;;
  79 m680?0)
  80   machine=m68k/$machine ;;
  81 m88k)
  82   machine=m88k/m88100 ;;
  83 m88???)
  84   machine=m88k/$machine ;;
  85 mips64*)
  86   machine=mips/mips64/$machine ;;
  87 mips*)
  88   machine=mips/$machine ;;
  89 esac
  90
  91 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
  92 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
  93
  94 case "$os" in
  95 gnu*)
  96   base_os=mach/hurd ;;
  97 netbsd* | 386bsd* | freebsd* | bsdi*)
  98   base_os=unix/bsd/bsd4.4 ;;
  99 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 100   base_os=unix/bsd ;;
 101 linux* | sysv* | isc* | esix* | sco* | minix* | irix4*)
 102   base_os=unix/sysv ;;
 103 solaris[2-9]*)
 104   base_os=unix/sysv/sysv4 ;;
 105 none)
 106   base_os=standalone ;;
 107 *)
 108   base_os='' ;;
 109 esac
 110
 111 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 112 tail=$os
 113 ostry=$os
 114 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 115   ostry="$ostry /$o"
 116   tail=$o
 117 done
 118 o=`echo $tail | sed 's/[0-9]*$//'`
 119 if test $o != $tail; then
 120   ostry="$ostry /$o"
 121 fi
 122
 123 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 124 base=
 125 tail=$base_os
 126 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 127   set $b
 128   base="$base /$1"
 129   tail="$2"
 130 done
 131
 132 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 133 mach=
 134 tail=$machine
 135 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 136   set $m
 137   mach="$mach /$1"
 138   tail="$2"
 139 done
 140
 141 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 142 changequote([,])dnl
 143
 144 # Find what sysdep directories exist.
 145 sysnames=
 146 for b in $base ''; do
 147   for m0 in $mach ''; do
 148     for v in /$vendor ''; do
 149       for o in /$ostry ''; do
 150         for m in $mach ''; do
 151           try="$m0$b$v$o$m"
 152           if test -d $sysdep_dir$try; then
 153             sysnames="$sysnames $try"
 154             { test -n "$o" || test -n "$b"; } && os_used=t
 155             { test -n "$m" || test -n "$m0"; } && machine_used=t
 156           fi
 157         done
 158       done
 159     done
 160   done
 161 done
 162
 163 if test -z "$os_used" && test "$os" != none; then
 164   AC_MSG_ERROR(Operating system $os is not supported.)
 165 fi
 166 if test -z "$machine_used" && test "$machine" != none; then
 167   AC_MSG_ERROR(The $machine is not supported.)
 168 fi
 169
 170 # We have now validated the configuration.
 171
 172 # Some configurations imply other options.
 173 case "$host_os" in
 174 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 175   # These systems always use GNU tools.
 176   gnu_ld=yes gnu_as=yes
 177 esac
 178 case "$host_os" in
 179 gnu*elf* | linux* | sysv4* | solaris2*)
 180   # These systems always use the ELF format.
 181   elf=yes
 182 esac
 183
 184
 185 # Remove the leading slashes.
 186 sysnames="`echo $sysnames | sed -e 's@^/@@' -e 's@ /@ @g'`"
 187
 188 # Prepend the machine's FPU directory unless --without-fp.
 189 if test "$with_fp" = yes; then
 190   fpu_dirs=
 191   for m in $mach; do
 192     if test -d $sysdep_dir$m/fpu; then
 193       fpu_dirs="$fpu_dirs $m/fpu"
 194     fi
 195   done
 196   sysnames="`echo $fpu_dirs | sed -e 's,^/,,' -e 's, /,,g'` $sysnames"
 197 fi
 198
 199 # If using ELF, prepend the machine-specific ELF ABI directory.
 200 if test "$elf" = yes; then
 201   elf_dirs=
 202   for m in $mach; do
 203     if test -d $sysdep_dir$m/elf; then
 204       elf_dirs="elf_dirs $m/elf"
 205     fi
 206   done
 207   sysnames="`echo elf_dirs | sed -e 's,^/,,' -e 's, /,,g'` $sysnames"
 208 fi
 209
 210
 211
 212 # Expand the list of system names into a full list of directories
 213 # from each element's parent name and Implies file (if present).
 214 set $sysnames
 215 while test $# -gt 0; do
 216   name=$1
 217   shift
 218
 219   if test -f $sysdep_dir/$name/Implies; then
 220     # Collect more names from the `Implies' file (removing comments).
 221     implied="`sed 's/#.*$//' < $sysdep_dir/$name/Implies`"
 222     for x in $implied; do
 223       test -d $sysdep_dir/$x || echo "Warning: $name implies nonexistent $x">&2
 224     done
 225   else
 226     implied=
 227   fi
 228
 229   # Add NAME to the list of names.
 230   names="$names $name"
 231
 232   # Find the parent of NAME, using the empty string if it has none.
 233 changequote(,)dnl
 234   parent="`echo $name | sed -n -e '/\//!q' -e 's=/[^/]*$==p'`"
 235 changequote([,])dnl
 236
 237   # Add the names implied by NAME, and NAME's parent (if it has one), to
 238   # the list of names to be processed (the argument list).  We prepend the
 239   # implied names to the list and append the parent.  We want implied
 240   # directories to come before further directories inferred from the
 241   # configuration components; this ensures that for sysv4, unix/common
 242   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 243   # after sysv4).
 244   sysnames="`echo $implied $* $parent`"
 245   test -n "$sysnames" && set $sysnames
 246 done
 247
 248 # Add the default directories.
 249 names="$names generic stub"
 250
 251 # Now uniquize the list.
 252 seen=
 253 sysnames=
 254 for name in $names; do
 255   if echo "$seen" | fgrep -x $name >/dev/null; then
 256     # Already in the list.
 257     true;
 258   else
 259     # A new one.
 260     if test -z "$seen"; then
 261       seen="$name" sysnames="$name"
 262     else
 263       seen="$seen
 264 $name"
 265       sysnames="$sysnames $name"
 266     fi
 267   fi
 268 done
 269 libc_cv_sysdirs="$sysnames"])
 270 AC_SUBST(sysnames) sysnames="$libc_cv_sysdirs"
 271 AC_MSG_RESULT(${sysnames})
 272
 273 AC_PROG_INSTALL
 274 if test "$INSTALL" = "${srcdir}/install-sh"; then
 275   # The makefiles need to use a different form to find it in $srcdir.
 276   INSTALL='$(..)./install-sh'
 277 fi
 278
 279 AC_CHECK_TOOL(CC, gcc)
 280 AC_CHECK_TOOL(AR, ar)
 281 AC_CHECK_TOOL(RANLIB, ranlib, :)
 282 AC_PROG_CPP
 283
 284 AC_MSG_CHECKING(signed size_t type)
 285 AC_CACHE_VAL(libc_cv_signed_size_t, [dnl
 286 echo '#include <stddef.h>
 287 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 288 if eval "$ac_cpp conftest.c 2>/dev/null" \
 289 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 290   libc_cv_signed_size_t=no
 291 else
 292   libc_cv_signed_size_t=yes
 293 fi
 294 rm -f conftest*])
 295 AC_MSG_RESULT($libc_cv_signed_size_t)
 296 if test $libc_cv_signed_size_t = yes; then
 297   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 298   cat >> confdefs.h <<\EOF
 299 #undef __SIZE_TYPE__
 300 #define __SIZE_TYPE__ unsigned
 301 EOF
 302 fi
 303
 304 AC_MSG_CHECKING(libc-friendly stddef.h)
 305 AC_CACHE_VAL(libc_cv_friendly_stddef, [dnl
 306 AC_TRY_COMPILE(dnl
 307 [#define __need_size_t
 308 #define __need_wchar_t
 309 #include <stddef.h>
 310 #define __need_NULL
 311 #include <stddef.h>], [size_t size; wchar_t wchar;
 312 #ifdef offsetof
 313 #error stddef.h ignored __need_*
 314 #endif
 315 if (&size == NULL || &wchar == NULL) abort ();],
 316                libc_cv_friendly_stddef=yes,
 317                libc_cv_friendly_stddef=no)])
 318 AC_MSG_RESULT($libc_cv_friendly_stddef)
 319 if test $libc_cv_friendly_stddef = yes; then
 320   config_vars="$config_vars
 321 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 322 fi
 323
 324 AC_MSG_CHECKING(whether we need to use -P to assemble .S files)
 325 AC_CACHE_VAL(libc_cv_need_minus_P, [dnl
 326 cat > conftest.S <<EOF
 327 #include "confdefs.h"
 328 /* Nothing whatsoever.  */
 329 EOF
 330 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 331   libc_cv_need_minus_P=no
 332 else
 333   libc_cv_need_minus_P=yes
 334 fi
 335 rm -f conftest*])
 336 AC_MSG_RESULT($libc_cv_need_minus_P)
 337 if test $libc_cv_need_minus_P = yes; then
 338   config_vars="$config_vars
 339 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 340 fi
 341
 342 AC_MSG_CHECKING(for .set assembler directive)
 343 AC_CACHE_VAL(libc_cv_asm_set_directive, [dnl
 344 cat > conftest.s <<\EOF
 345 .text
 346 foo: .long 0
 347 .set bar,foo
 348 EOF
 349 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 350   libc_cv_asm_set_directive=yes
 351 else
 352   libc_cv_asm_set_directive=no
 353 fi
 354 rm -f contest*])
 355 AC_MSG_RESULT($libc_cv_asm_set_directive)
 356 if test $libc_cv_asm_set_directive = yes; then
 357   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 358 fi
 359
 360
 361 # sysdeps configure fragments may set these with files to be linked below.
 362 libc_link_dests=
 363 libc_link_sources=
 364
 365 # Iterate over all the sysdep directories we will use, running their
 366 # configure fragments, and looking for a uname implementation.
 367 uname=
 368 for dir in $sysnames; do
 369   if test -r $sysdep_dir/$dir/configure; then
 370     AC_MSG_RESULT(running configure fragment for $dir)
 371     . $sysdep_dir/$dir/configure
 372   fi
 373   if test -z "$uname"; then
 374     { test -r $sysdep_dir/$dir/uname.c || test -r $sysdep_dir/$dir/uname.S; } \
 375     && uname=$dir
 376   fi
 377 done
 378
 379 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 380
 381 # If we will use the generic uname implementation, we must figure out what
 382 # it will say by examining the system, and write the results in config-name.h.
 383 if test "$uname" = generic; then
 384
 385 changequote(,)dnl
 386   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 387 changequote([,])dnl
 388   if test $uname_sysname != $config_os; then
 389     config_release=`echo $config_os | sed s/$uname_sysname//`
 390   fi
 391 dnl
 392 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 393     if test -r /vmunix; then
 394       kernel_id=`strings /vmunix | grep UNIX`
 395     elif test -r /dynix; then
 396       kernel_id=`strings /dynix | grep DYNIX`
 397     else
 398       kernel_id=
 399     fi
 400 ])dnl
 401
 402   AC_MSG_CHECKING(OS release for uname)
 403   AC_CACHE_VAL(libc_cv_uname_release, [dnl
 404 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 405 changequote(,)dnl
 406   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 407 changequote([,])dnl
 408   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 409          != x$config_release; then
 410     # The configuration release is a substring of the kernel release.
 411     libc_cv_uname_release=$kernel_release
 412   elif test x$config_release != x; then
 413     libc_cv_uname_release=$config_release
 414   elif test x$kernel_release != x; then
 415     libc_cv_uname_release=$kernel_release
 416   else
 417     libc_cv_uname_release=unknown
 418   fi])
 419   AC_MSG_RESULT($libc_cv_uname_release)
 420   uname_release="$libc_cv_uname_release"
 421
 422   AC_MSG_CHECKING(OS version for uname)
 423   AC_CACHE_VAL(libc_cv_uname_version, [dnl
 424 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 425 changequote(,)dnl
 426   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 427 changequote([,])dnl
 428   if test -n "$kernel_version"; then
 429     libc_cv_uname_version="$kernel_version"
 430   else
 431     libc_cv_uname_version=unknown
 432   fi])
 433   AC_MSG_RESULT($libc_cv_uname_version)
 434   uname_version="$libc_cv_uname_version"
 435
 436 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 437   config_uname=config-name.h:config-name.in
 438 else
 439   # For non-generic uname, we don't need to create config-name.h at all.
 440   config_uname=
 441 fi
 442
 443 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf) AC_SUBST(weak)
 444 if test $gnu_ld = yes; then
 445   AC_DEFINE(HAVE_GNU_LD)
 446 fi
 447 if test $gnu_as = yes; then
 448   AC_DEFINE(HAVE_GNU_AS)
 449 fi
 450 if test $elf = yes; then
 451   AC_DEFINE(HAVE_ELF)
 452 fi
 453 if test $weak = yes; then
 454   AC_DEFINE(HAVE_WEAK_SYMBOLS)
 455 fi
 456
 457 AC_SUBST(shared)
 458 if test $shared = default; then
 459   if test $gnu_ld = yes; then
 460     shared=$elf
 461   fi
 462 fi
 463 AC_SUBST(profile)
 464 AC_SUBST(omitfp)
 465
 466
 467 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 468   config_makefile=
 469 else
 470   config_makefile=Makefile
 471 fi
 472
 473 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
 474           [echo '$config_vars' >> config.make])